!% +language_name=Swedish
! ============================================================================ !
!      Den mörka manteln - en enkel demonstration av textäventyr på svenska
!          Denna version i Inform skriven av Roger Firth, 17 sep 99
!               I översättning av Fredrik Ramsberg 23 Mar 2004
! ============================================================================ !


Include "SweAlpha";

Constant Story      "Den mörka manteln";
Constant Headline   "^En enkel demonstration av textäventyr på svenska.^";
Constant MANUAL_PRONOUNS;
Constant MAX_SCORE  2;
Include "Parser";
Include "VerbLib";
Include "SweRout";

! ============================================================================ !
!     Alla rutiner som behövs.
! ============================================================================ !

[ DeathMessage; print "Du har förlorat"; ];

! ============================================================================ !
!     Definiera, utöka och förändra grammatiken
! ============================================================================ !

Include "SwedishG";
Verb 'häng'     * held 'på' noun       -> PutOn
                * 'upp' held 'på' noun -> PutOn;
! ============================================================================ !
!     Alla objekt i spelet
! ============================================================================ !

Object  foaje "Operahusets foajé"
  with  description
           "Du står i en stor sal, vackert dekorerad i rött och guld, med
            glittrande kristallkronor i taket. Ingången från gatan ligger
            norrut, och det finns dörröppningar åt söder och väster.",
        s_to  bar,
        w_to  kapprum,
        n_to
           "Du kom just hit, och dessutom verkar vädret därute bara bli
            sämre.",
  has   light;

Object  kapprum "Kapprum"
  with  description
           "Det syns att det har suttit krokar längs alla väggar i det här
            lilla rummet, men nu finns det bara en enda krok kvar. Utgången
            är en dörr som leder österut.",
        e_to  foaje,
  has   light;

Object  -> krok "liten mässingskrok"
  with  short_name_def "lilla mässingskroken",
        name 'liten' 'mässingskrok' 'mässingkrok' 'krok' 'lilla' 'kroken',
        description [;
            print "Det är bara en liten mässingskrok";
            if (self == parent(mantel)) ". Det hänger en mantel på den.";
            ", fastskruvad i väggen.";
            ],
  has   scenery supporter def_article;
  
Object  bar "Foajébaren"
  with  description
           "Baren, som inte alls är så fashionabel som foajén du kom in igenom,
            är helt tom. Någon verkar ha skrivit ett meddelande i sågspånet 
            på golvet.",
        n_to  foaje,
        before [;
            Go:
                if (self hasnt light && noun ~= n_obj) {
                    meddelande.number = meddelande.number + 2;
                    "Att famla runt i mörkret verkar inte vara någon vidare 
                     idé!";
                    }
            default:
                if (self hasnt light) {
                    meddelande.number = meddelande.number + 1;
                    "I mörkret? Du skulle lätt kunna slå emot något!";
                    }
            ],
  has   ~light;
  
Object  -> meddelande "meddelande"
  with  short_name_def "meddelandet",
        name 'meddelande' 'sågspån' 'sågspånet' 'golv' 'golvet',
        description [;
            if (self.number < 2) {
                score++;
                deadflag = 2;
                print "Meddelandet, prydligt skrivet i sågspånet, lyder...";
                }
            else {
                deadflag = 3;
                print "Det är fullt av fotavtryck i meddelandet, vilket gör
                  det svårt att tyda. Du kan nätt och jämt urskilja orden...";
                }
            ],
        number  0,
  has   scenery neuter;
  
Object  mantel "svart sammetsmantel"
  with  short_name_def "svarta sammetsmanteln",
        name 
           'stilig' 'stiliga' 'mörk' 'mörka' 'svart' 'svarta' 'sammet' 
           'sammeten' 'sammetsmantel' 'satin' 'satinen' 'satinmantel' 'mantel' 
           'manteln',
        description
           "En stilig mantel, gjord av svart sammet kantad med satin, och något
            våt av regnet. Den är så mörk att den nästan verkar suga
            ljus från rummet.",
        before [;
            Drop, PutOn:
                if (location == kapprum) {
                    give bar light;
                    if (action == ##PutOn && self has general) {
                        give self ~general;
                        score++;
                        }
                    }
                else
                   "Det här är kanske inte något lämpligt ställe att lägga
                    ifrån sig en snygg mantel.";
            ],
        after [;
            Take: give bar ~light;
            ],
  has   clothing general def_article;


! ============================================================================ !
!     Initialise-rutinen.
! ============================================================================ !

[ Initialise;
    location = foaje;
    move mantel to player;
    give mantel worn;
   "^^Du skyndar dig på genom den regniga novemberkvällen, och snart dyker
    operahusets välkomnande lampor upp. Överraskande nog ser du inte till
    några andra människor, men å andra sidan, vad förväntar du dig av ett
    simpelt demo-spel...?^^";
];