1 !% +language_name=Swedish
2 !~S
3 ! !SD ! Dessa är de flaggor som bör användas tillsammans med konstanten TEST_VERSION
4
5 ! Denna källkod är avsedd att kompileras med Inform 6.31, bibliotek 6/11, Swedish Inform v1.5.
6
7 ! ------------------------------------------------------------------------------
8 ! Äventyr - Ett klassiskt spel och ett typexempel på spel i Inform 6
9 !
10 ! Översatt från engelska Advent.inf, Serial 060321, release 9
11 ! ------------------------------------------------------------------------------
12
13
14 Include "SweAlpha";
15
16 ! Constant TEST_VERSION;
17
18 Constant Story "ÄVENTYR";
19 Constant Headline
20 "^Det Interaktiva Originalet^
21 Av Will Crowther (1976) och Don Woods (1977)^
22 Rekonstruerat i tre steg av:^
23 Donald Ekman, David M. Baggett (1993) och Graham Nelson (1994)^
24 Release 9 av den engelska versionen översatt till svenska av Fredrik Ramsberg (2007)^
25 [In memoriam Stephen Bishop (1820?-1857): GN]^^";
26 Serial "071029";
27 Release 1;
28
29 ! Äventyrs IFID -- see http://babel.ifarchive.org/
30 Array UUID_ARRAY string "UUID://78B5816F-2F79-CE0B-633D-6D95EC06154E//"; #Ifdef UUID_ARRAY; #Endif;
31
32
33 Constant MANUAL_PRONOUNS;
34 Constant AMUSING_PROVIDED;
35 Constant MAX_CARRIED = 7;
36 Constant MAX_SCORE = 350;
37 Constant MAX_TREASURES = 15;
38
39 #Ifdef TEST_VERSION; !!!
40 ! Sist i koden byts random ut mot en version som kan ge förutsägbara resultat
41 Replace random; !!!
42 #Endif; !!!
43
44 Include "Parser";
45 Include "VerbLib";
46 Include "SweRout";
47
48 Attribute nodwarf; ! Dvärgar kan inte gå till detta rum
49 Attribute treasure_found; ! Skatt-objekt har hittats
50 Attribute multitude; ! Används endast av RÄKNA
51
52 Global caves_closed; ! Har värdet true när grottan stängs
53 Global canyon_from; ! Ravin att återvända till
54 Global treasures_found; ! Antal hittade skatter
55 Global deaths; ! Antal dödsfall/återuppväckningar
56 Global dark_warning; ! Har värdet true efter varning om mörka hål
57 Global feefie_count; ! fee/fie/foe/foo sekvens
58
59 ! ------------------------------------------------------------------------------
60 ! Regler för skatter som ska spridas över hela spelet
61 ! ------------------------------------------------------------------------------
62
63 Class Treasure
64 with after [;
65 Take:
66 if (location == Inside_Building)
67 score = score - self.depositpoints;
68 score = score + 5;
69 if (noun hasnt treasure_found) {
70 give noun treasure_found;
71 treasures_found++;
72 score = score + 2;
73 }
74 SetGender(self); ! Se till att objektet har ett genus
75 if(self has pluralname)
76 "Tagna!";
77 if(self has neuter)
78 "Taget!";
79 "Tagen!";
80 Insert:
81 score = score - 5; ! (in case put inside the wicker cage)
82 Drop:
83 score = score - 5;
84 if (location == Inside_Building) {
85 score = score + self.depositpoints;
86 SetGender(self); ! Se till att objektet har ett genus
87 print "Deponera";
88 if(self has pluralname)
89 print "de";
90 else if(self has neuter)
91 print "t";
92 else
93 print "d";
94 " i säkert förvar.";
95 }
96 ],
97 depositpoints 10;
98
99 ! ------------------------------------------------------------------------------
100 ! Utomhusvärlden
101 ! ------------------------------------------------------------------------------
102
103 Class Room;
104
105 Class Aboveground
106 class Room
107 has light nodwarf;
108
109 Class Scenic
110 has scenery;
111
112 Aboveground At_End_Of_Road "Vid slutet av en väg"
113 with teleport_to
114 'kulle' 'kullen' At_Hill_In_Road
115 'byggnad' 'byggnaden' 'hus' 'huset' 'brunnshus' 'tegelbyggnad' Inside_Building
116 'nedströms' 'nerströms' 'kanjon' 'kanjonen' 'bäck' 'bäcken' 'dal' 'dalen' 'dalgång' 'dalgången' In_A_Valley
117 'skog' 'skogen' In_Forest_1
118 'galler' 'gallret' 'stålgaller' 'stålgallret' 'grop' 'gropen' Outside_Grate,
119 description
120 "Du står vid slutet av en väg framför en liten tegelbyggnad.
121 Runt dig är en skog.
122 En bäck rinner ut ur byggnaden och fortsätter ner i en dalgång.",
123 w_to At_Hill_In_Road,
124 u_to At_Hill_In_Road,
125 e_to Inside_Building,
126 d_to In_A_Valley,
127 s_to In_A_Valley,
128 n_to In_Forest_1,
129 in_to Inside_Building;
130
131 Scenic "brunnshus"
132 with name 'brunnshus' 'brunnshuset' 'hus' 'huset' 'tegelbyggnad'
133 'tegelbyggnaden' 'byggnad' 'byggnaden' 'liten' 'litet' 'lilla',
134 short_name_def "brunnshuset",
135 description "Det är en liten tegelbyggnad. Det verkar vara ett brunnshus.",
136 found_in At_End_Of_Road At_Hill_In_Road Inside_Building,
137 before [;
138 Enter:
139 if (location == At_Hill_In_Road && Inside_Building hasnt visited)
140 "Det är för långt bort.";
141 <<Teleport Inside_Building>>;
142 ],
143 has neuter;
144
145 Scenic Stream "bäck"
146 with name 'bäck' 'bäcken' 'vatten' 'vattnet' 'å//' 'ån' 'flod' 'floden'
147 'sjö' 'sjön' 'liten' 'litet' 'lilla' 'plaskande' 'strömmande'
148 'reservoar' 'reservoaren' 'fors' 'forsen',
149 short_name_def "bäcken",
150 found_in At_End_Of_Road In_A_Valley At_Slit_In_Streambed In_Pit
151 In_Cavern_With_Waterfall At_Reservoir Inside_Building,
152 before [;
153 Drink:
154 "Du drack från bäcken.
155 Vattnet smakar starkt av mineraler, men är inte alls oangenämt.
156 Det är extremt kallt.";
157 Take:
158 if (bottle notin player)
159 "Du har inget att bära vattnet i.";
160 <<Fill bottle>>;
161 Insert:
162 if (second == bottle) <<Fill bottle>>;
163 "Du har inget att bära vattnet i.";
164 Receive:
165 if (noun == ming_vase) {
166 remove ming_vase;
167 move shards to location;
168 score = score - 5;
169 "Den plötsliga temperaturväxlingen spräckte elegant vasen.";
170 }
171 if (noun == bottle) <<Fill bottle>>;
172 remove noun;
173 if (noun ofclass Treasure) score = score - 5;
174 "Bäcken sköljer bort ", (the) noun, ".";
175 ];
176
177 Scenic "väg"
178 with name 'väg' 'vägen' 'gata' 'gatan' 'stig' 'stigen' 'grus' 'gruset' 'grusväg' 'grusvägen',
179 description "Det är en grusväg, ingen paradgata direkt.",
180 short_name_def "vägen",
181 found_in At_End_Of_Road At_Hill_In_Road In_Forest_2;
182
183 Scenic "skog"
184 ! Tvingades dela upp name-arrayen i två delar för att den blev för stor.
185 ! Lade till en parse_name som tar hänsyn till båda arrayerna
186 with name 'skog' 'skogen' 'träd' 'träden' 'trädet' 'ek' 'eken' 'ekar' 'ekarna'
187 'asp' 'aspen' 'aspar' 'asparna' 'dunge' 'dungen' 'dungar' 'dungarna'
188 'tall' 'tallen' 'tallar' 'tallarna' 'små' 'lilla' 'gran' 'granen' 'granar' 'granarna',
189 name2 'björk' 'björken' 'björkar' 'björkarna' 'ask' 'asken' 'askar' 'askarna'
190 'skott' 'skotten' 'skottet' 'buske' 'busken' 'buskar' 'buskarna'
191 'löv' 'löven' 'bärbuske' 'bärbusken' 'bärbuskar' 'bärbuskarna'
192 'smågran' 'smågranen' 'smågranar' 'smågranarna',
193 parse_name [ wd num;
194 wd = NextWord();
195 while (WordInProperty(wd, self, name) || WordInProperty(wd, self, name2)) {
196 num++;
197 wd = NextWord();
198 }
199 return num;
200 ],
201 short_name_def "skogen",
202 description
203 "Skogen består mest av stora ekar och aspar,
204 med en och annan dunge med tall eller gran.
205 Det finns en hel del undervegetation,
206 mestadels skott av björk och asp samt olika typer av buskar.
207 Vid den här tiden på året är sikten ganska begränsad av alla löv,
208 men det är lätt att förflytta sig om man bara rundar smågranarna och bärbuskarna.",
209 found_in At_End_Of_Road At_Hill_In_Road In_A_Valley In_Forest_1 In_Forest_2,
210 has multitude;
211
212 ! ------------------------------------------------------------------------------
213
214 Aboveground At_Hill_In_Road "På en kulle på vägen"
215 with teleport_to
216 'väg' 'vägen' 'kulle' 'kullen' 'framåt' 'fortsätt' At_End_Of_Road
217 'skog' 'skogen' In_Forest_1,
218 description
219 "Du har gått uppför en kulle i skogen.
220 Vägen leder tillbaka nerför sluttningen på andra sidan kullen.
221 Längre bort står en byggnad.",
222 e_to At_End_Of_Road,
223 n_to At_End_Of_Road,
224 d_to At_End_Of_Road,
225 s_to In_Forest_1;
226
227 Scenic -> "kulle"
228 with name 'kulle' 'kullen' 'höjd' 'höjden' 'krön' 'krönet' 'sluttning' 'sluttningen',
229 short_name_def "kullen",
230 description "Det är bara en vanlig kulle.";
231
232 Scenic -> "andra sidan kullen"
233 with name 'andra' 'sidan' 'av' 'kullen',
234 short_name_def "andra sidan kullen",
235 articles "den",
236 description "Varför inte gå och se efter själv?",
237 has def_article;
238
239 ! ------------------------------------------------------------------------------
240
241 Aboveground Inside_Building "Inuti byggnad"
242 with teleport_to
243 'utsidan' At_End_Of_Road,
244 description
245 "Du är i en byggnad, ett brunnshus för en stor källa.",
246 cant_go
247 "Vattnet rinner ut genom ett par avloppsrör, ca 30 centimeter i diameter.
248 Den enda utgången är åt väst.",
249 before [;
250 Enter:
251 if (noun == Spring or SewerPipes)
252 "Vattnet rinner ut genom ett par avloppsrör, ca 30 centimeter i diameter.
253 Det vore klokt att använda dörröppningen i den västra väggen.";
254 Xyzzy:
255 if (In_Debris_Room hasnt visited) rfalse;
256 PlayerTo(In_Debris_Room);
257 rtrue;
258 Plugh:
259 if (At_Y2 hasnt visited) rfalse;
260 PlayerTo(At_Y2);
261 rtrue;
262 ],
263 w_to At_End_Of_Road,
264 out_to At_End_Of_Road,
265 in_to "Rören är för små.";
266
267 Scenic -> Spring "källa"
268 with name 'källa' 'källan' 'stor' 'stora',
269 short_name_def "källan",
270 description
271 "Vattnet rinner ut genom ett par avloppsrör, ca 30 centimeter i diameter.";
272
273 Scenic -> SewerPipes "avloppsrör"
274 with name 'par' 'avloppsrör' 'avloppsrören' 'avloppsröret' 'rör' 'rören' 'röret',
275 short_name_def "avloppsrören",
276 articles 0 0 "ett par",
277 description "För små. Den enda utgången är åt väst.",
278 has neuter pluralname;
279
280 Object -> set_of_keys "nyckelknippa"
281 with name 'nycklar' 'nycklarna' 'nyckel' 'nyckeln' 'nyckelknippa' 'nyckelknippan'
282 'knippa' 'knippan',
283 short_name_def "nyckelknippan",
284 description "Det är bara en helt vanlig nyckelknippa.",
285 initial "Det ligger en nyckelknippa på marken här.",
286 before [;
287 Count:
288 "Ett dussin nycklar eller så.";
289 ];
290
291 Object -> tasty_food "god mat"
292 with name 'mat' 'maten' 'portion' 'portionen' 'läcker' 'läckra' 'god' 'goda' 'jättegod' 'jättegoda',
293 short_name_def "goda maten",
294 articles "Den" "den" 0,
295 description "Ser verkligen gott ut!",
296 initial "Det finns god mat här.",
297 after [;
298 Eat:
299 "Jättegott!";
300 ],
301 has edible;
302
303 Object -> brass_lantern "mässingslampa"
304 with name 'lampa' 'lampan' 'lykta' 'lyktan' 'pannlampa' 'pannlampan'
305 'mässingslykta' 'mässingslyktan' 'mässingslampa' 'mässingslampan'
306 'mässinglykta' 'mässinglyktan' 'mässinglampa' 'mässinglampan'
307 'ljus' 'ljuset' 'blank' 'blanka' 'blänkande' 'glänsande',
308 short_name_def "mässingslampan",
309 when_off "Det finns en blank mässingslampa här.",
310 when_on [;
311 print "Din lampa är här, och den ger ett ";
312 if (self.power_remaining < 30)
313 print "svagt";
314 else
315 print "starkt";
316 " ljus ifrån sig.";
317 ],
318 daemon [ t;
319 if (self hasnt on) {
320 StopDaemon(self);
321 rtrue;
322 }
323 t = --(self.power_remaining);
324 if (t == 0) give self ~on ~light;
325 if (self in player || self in location) {
326 if (t == 0) {
327 print "Din lampas batterier tar slut.";
328 if (fresh_batteries notin player && location hasnt light) {
329 deadflag = 3;
330 " Du kan inte utforska grottor utan lampa.
331 Därmed verkar ditt äventyr vara över.";
332 }
333 else
334 self.replace_batteries();
335 new_line;
336 rtrue;
337 }
338 if (t == 30) {
339 print "Skenet från din lampa börjar bli svagare.";
340 if (fresh_batteries.have_been_used)
341 " Du har dessutom slut på reservbatterier.
342 Det är nog dags att tänka på refrängen.";
343 if (fresh_batteries in VendingMachine && Dead_End_14 has visited)
344 " Det är nog dags att tänka på refrängen,
345 om du nu inte kan hitta nya batterier någonstans.
346 Jag har för mig att det finns en varuautomat i labyrinten.
347 Ta med lite mynt.";
348 if (fresh_batteries notin VendingMachine or player or location)
349 " Det är nog bäst att du hämtar de där batterierna.";
350 new_line;
351 rtrue;
352 }
353 }
354 ],
355 before [;
356 Examine:
357 print "Det är en blänkade mässingslampa";
358 if (self hasnt on) ". Den är för tillfället avstängd.";
359 if (self.power_remaining < 30) " som ger ifrån sig ett svagt sken.";
360 " som ger ifrån sig ett starkt sken.";
361 Burn:
362 <<SwitchOn self>>;
363 Rub:
364 "Att gnida den elektriska lampan ger inte så mycket.
365 Inget speciellt händer i alla fall.";
366 SwitchOn:
367 if (self.power_remaining <= 0)
368 "Tyvärr verkar batterierna vara helt slut.";
369 Receive:
370 if (noun == old_batteries)
371 "De där batterierna är slut - de skulle inte göra någon som helst nytta.";
372 if (noun == fresh_batteries) {
373 self.replace_batteries();
374 rtrue;
375 }
376 "Det enda du kan sätta in i lampan är ett par nya batterier.";
377 ],
378 after [;
379 SwitchOn:
380 give self light;
381 StartDaemon(self);
382 SwitchOff:
383 give self ~light;
384 ],
385 replace_batteries [;
386 if (fresh_batteries in player or location) {
387 remove fresh_batteries;
388 fresh_batteries.have_been_used = true;
389 move old_batteries to location;
390 self.power_remaining = 2500;
391 "Jag tar mig friheten att byta ut batterierna.";
392 }
393 ],
394 power_remaining 330,
395 has switchable;
396
397 Object -> bottle "liten flaska"
398 with name 'flaska' 'flaskan' 'burk' 'burken' 'liten' 'lilla',
399 short_name_def "lilla flaskan",
400 initial "Det ligger en tom flaska här.",
401 before [;
402 LetGo:
403 if (noun in bottle)
404 "Du har redan ", (DenEllerHonom) noun, " (i flaskan).";
405 Receive:
406 if (noun == stream or Oil)
407 <<Fill self>>;
408 else
409 "Flaskan är bara gjord för att innehålla vätskor.";
410 Fill:
411 if (child(bottle) ~= nothing)
412 "Flaskan är redan full.";
413 if (stream in location || Spring in location) {
414 move water_in_the_bottle to bottle;
415 "Flaskan är nu full av vatten.";
416 }
417 if (Oil in location) {
418 move oil_in_the_bottle to bottle;
419 "Flaskan är nu full av olja.";
420 }
421 "Det finns inget att fylla flaskan med här.";
422 Empty:
423 if (child(bottle) == nothing)
424 "Flaskan är redan tom!";
425 remove child(bottle);
426 "Din flaska är nu tom och marken är nu blöt.";
427 ],
428 has def_article container open;
429
430 Object water_in_the_bottle "vatten i flaskan"
431 with name 'vatten' 'vattnet' 'på' 'i//' 'flaska' 'flaskan' 'flaskvatten' 'flaskvattnet' 'h2o',
432 short_name_def "vattnet i flaskan",
433 description "Jag tycker det ser ut som vanligt vatten.",
434 before [;
435 Drink:
436 remove water_in_the_bottle;
437 <<Drink Stream>>;
438 ],
439 has proper neuter;
440
441 Object oil_in_the_bottle "olja i flaskan"
442 with name 'olja' 'oljan' 'på' 'i//' 'flaska' 'flaskan'
443 'flaskolja' 'flaskoljan' 'smörjmedel' 'smörjmedlet' 'fett' 'fettet',
444 short_name_def "oljan i flaskan",
445 description "Jag tycker det ser ut som vanlig olja.",
446 before [;
447 Drink:
448 <<Drink Oil>>;
449 ],
450 has proper;
451
452 ! ------------------------------------------------------------------------------
453
454 Aboveground In_Forest_1 "I skogen"
455 with teleport_to
456 'dal' 'dalen' 'dalgång' 'dalgången' In_A_Valley,
457 description "Du är i en gles skog, med en djup dalgång på ena sidan.",
458 e_to In_A_Valley,
459 d_to In_A_Valley,
460 n_to In_Forest_1,
461 w_to In_Forest_1,
462 s_to In_Forest_1,
463 initial [;
464 if (random(2) == 1) PlayerTo(In_Forest_2, 1);
465 ];
466
467 Aboveground In_Forest_2 "I skogen"
468 with teleport_to
469 'kulle' 'kullen' 'väg' 'vägen' At_End_Of_Road
470 'dal' 'dalen' 'dalgång' 'dalgången' In_A_Valley,
471 description "Du är i en gles skog, nära både en dalgång och en väg.",
472 n_to At_End_Of_Road,
473 e_to In_A_Valley,
474 w_to In_A_Valley,
475 d_to In_A_Valley,
476 s_to In_Forest_1;
477
478 Aboveground In_A_Valley "I en dalgång"
479 with teleport_to
480 'uppströms' 'byggnad' 'byggnaden' 'hus' 'huset' 'brunnshus' 'tegelbyggnad' At_End_Of_Road
481 'skog' 'skogen' In_Forest_1
482 'nedströms' 'nerströms' At_Slit_In_Streambed
483 'grop' 'gropen' 'galler' 'gallret' 'stålgaller' 'stålgallret' Outside_Grate,
484 description
485 "Du är i en dalgång i skogen, bredvid en bäck som forsar fram över en stenig botten.",
486 n_to At_End_Of_Road,
487 e_to In_Forest_1,
488 w_to In_Forest_1,
489 u_to In_Forest_1,
490 s_to At_Slit_In_Streambed,
491 d_to At_Slit_In_Streambed;
492
493 Scenic -> "botten"
494 with name 'stenig' 'steniga' 'botten' 'bottnen' 'bäckens'
495 'bäckfåra' 'bäckfåran' 'fåra' 'fåran' 'bäckbotten' 'stenbotten' 'stenbottnen'
496 'kal' 'torr' 'torra' 'torkad' 'torkade' 'uttorkad' 'uttorkade' 'klippa' 'klippan',
497 short_name_def "bottnen";
498
499 ! ------------------------------------------------------------------------------
500
501 Aboveground At_Slit_In_Streambed "Vid en spricka i botten"
502 with teleport_to
503 'byggnad' 'byggnaden' 'hus' 'huset' 'brunnshus' 'tegelbyggnad' At_End_Of_Road
504 'uppströms' In_A_Valley
505 'skog' 'skogen' In_Forest_1
506 'nedströms' 'nerströms' 'torr' 'torra' 'klippa' 'klippan' 'bäckfåra' 'bäckfåran'
507 'galler' 'gallret' 'stålgaller' 'stålgallret' 'grop' 'gropen' Outside_Grate,
508 description
509 "Vid dina fötter forsar allt vatten ner genom en fem centimeter bred spricka i klippan under.
510 Nedströms består bäckfåran bara av torr klippa.",
511 n_to In_A_Valley,
512 e_to In_Forest_1,
513 w_to In_Forest_1,
514 s_to Outside_Grate,
515 d_to "Du kommer inte igenom en fem centimeter bred spricka!",
516 in_to "Du kommer inte igenom en fem centimeter bred spricka!";
517
518 Scenic -> "spricka"
519 with name 'spricka' 'sprickan' 'fem' 'cm' 'centimeter' 'halvdecimeter' 'bred',
520 short_name_def "sprickan",
521 description
522 "Det är bara en spricka i klippan, och ner genom den rinner bäcken.",
523 before [;
524 Enter:
525 "Du kommer inte igenom en fem centimeter bred spricka!";
526 ];
527
528 ! ------------------------------------------------------------------------------
529
530 Aboveground Outside_Grate "Utanför gallret"
531 with teleport_to
532 'byggnad' 'byggnaden' 'hus' 'huset' 'brunnshus' 'tegelbyggnad' At_End_Of_Road
533 'uppströms' At_Slit_In_Streambed
534 'skog' 'skogen' In_Forest_1,
535 description
536 "Du står i en fem meter djup grop med bara jord till golv.
537 I jorden sitter ett starkt stålgaller infattat i betong.
538 En uttorkad bäckfåra leder ner i gropen.",
539 e_to In_Forest_1,
540 w_to In_Forest_1,
541 s_to In_Forest_1,
542 n_to At_Slit_In_Streambed,
543 d_to [;
544 if (Grate hasnt locked && Grate hasnt open) {
545 print "(öppnar först gallret)^";
546 give Grate open;
547 }
548 return Grate;
549 ];
550
551 Scenic -> "fem meter djup grop"
552 with name 'grop' 'gropen' 'jord' 'jorden' 'jordig' 'fem' 'm//' 'meter' 'djup' 'djupa' 'grop' 'gropen',
553 short_name_def "fem meter djupa gropen",
554 description "Du står i den.",
555 has def_article;
556
557 Object -> Grate "stålgaller"
558 with name 'stål' 'stålet' 'av' 'galler' 'gallret' 'stålgaller' 'stålgallret'
559 'lås' 'låset' 'metall' 'metallen' 'metallgaller' 'metallgallret' 'stark' 'starkt' 'starka'
560 'lucka' 'luckan' 'stållucka' 'stålluckan',
561 short_name_def "stålgallret",
562 description "Det ser bara ut som ett vanligt galler infattat i betong.",
563 with_key set_of_keys,
564 door_dir [;
565 if (location == Below_The_Grate) return u_to;
566 return d_to;
567 ],
568 door_to [;
569 if (location == Below_The_Grate) return Outside_Grate;
570 return Below_The_Grate;
571 ],
572 describe [;
573 if (self has open) "^Gallret är öppet.";
574 if (self hasnt locked) "^Gallret är olåst men stängt.";
575 rtrue;
576 ],
577 found_in Below_The_Grate Outside_Grate,
578 has neuter static door openable lockable locked;
579
580 ! ------------------------------------------------------------------------------
581 ! Facilis descensus Averno...
582 ! ------------------------------------------------------------------------------
583
584 Room Below_The_Grate "Under gallret"
585 with teleport_to
586 'småsten' 'småstensgången' 'låg' 'låga' 'gång' 'gången' 'tunnel' 'tunneln' 'kryp' In_Cobble_Crawl
587 'litet' 'lilla' 'hål' 'hålet' At_Top_Of_Small_Pit
588 'skräp' 'skräpet' 'skräprum' 'skräprummet' In_Debris_Room,
589 description
590 "Du är i en liten kammare under ett meterbrett stålgaller upp mot ytan.
591 Västerut kan du krypa in i en låg gång med småsten till golv.",
592 w_to In_Cobble_Crawl,
593 in_to In_Cobble_Crawl,
594 u_to Grate,
595 has light;
596
597 Scenic "småsten"
598 with name 'småsten' 'småstenen' 'småstenar' 'småstenarna' 'sten'
599 'stenen' 'stenar' 'stenarna' 'de' 'små' 'lilla',
600 short_name_def "småstenen",
601 description "Det är bara vanlig småsten.",
602 found_in In_Cobble_Crawl In_Debris_Room Below_The_Grate,
603 has multitude pluralname proper;
604
605 ! ------------------------------------------------------------------------------
606
607 Room In_Cobble_Crawl "I småstensgången"
608 with teleport_to
609 'ytan' 'yta' 'ingenstans' 'ingång' 'ingången' Below_The_Grate
610 'litet' 'lilla' 'hål' 'hålet' At_Top_Of_Small_Pit
611 'skräp' 'skräpet' 'skräprum' 'skräprummet' In_Debris_Room,
612 description
613 "Du kryper över småsten i en låg gång.
614 Det kommer in ett svagt ljus i gångens östra ände.",
615 e_to Below_The_Grate,
616 out_to Below_The_Grate,
617 w_to In_Debris_Room,
618 in_to In_Debris_Room,
619 has light;
620
621 Object -> wicker_cage "flätad bur"
622 with name 'bur' 'buren' 'liten' 'lilla' 'flätad' 'flätade' 'av' 'vidja' 'vidjan' 'vidjor' 'vidjorna',
623 short_name_def "flätade buren",
624 description "Det är en liten bur, flätad av vidjor.",
625 initial "En liten flätad bur ligger slängd i närheten.",
626 after [;
627 Open:
628 if (little_bird notin self) rfalse;
629 print "(släpper ut ", (the) little_bird, ")^";
630 <<Release little_bird>>;
631 ],
632 has def_article container open openable transparent;
633
634 ! ------------------------------------------------------------------------------
635
636 Room In_Debris_Room "I skräprummet"
637 with teleport_to
638 'ytan' 'yta' 'ingång' 'ingången' Below_The_Grate
639 'småsten' 'småstensgången' 'låg' 'låga' 'gång' 'gången' 'tunnel' 'tunneln' 'kryp' In_Cobble_Crawl
640 'trång' 'trånga' 'ravin' 'ravinen' In_Awkward_Sloping_E_W_Canyon
641 'litet' 'lilla' 'hål' 'hålet' At_Top_Of_Small_Pit,
642 description
643 "Du är i ett skräprum fyllt med grejer som sköljts in från ytan.
644 En låg bred gång med småsten blir här helt igensatt av gyttja och skräp,
645 men en trång ravin leder uppåt och västerut.
646 ^^
647 På väggen står antecknat: ~Magiskt ord XYZZY.~",
648 e_to In_Cobble_Crawl,
649 u_to In_Awkward_Sloping_E_W_Canyon,
650 in_to In_Awkward_Sloping_E_W_Canyon,
651 w_to In_Awkward_Sloping_E_W_Canyon,
652 before [;
653 Xyzzy:
654 PlayerTo(Inside_Building);
655 rtrue;
656 ],
657 has nodwarf;
658
659 Scenic -> "skräp"
660 with name 'skräp' 'skräpet' 'grej' 'grejen' 'grejer' 'grejor' 'pryl' 'prylen' 'prylar'
661 'dy' 'dyn' 'gyttja' 'gyttjan',
662 short_name_def "skräpet",
663 description "Usch.",
664 has neuter proper;
665
666 Scenic -> "anteckning"
667 with name 'anteckning' 'anteckningen',
668 short_name_def "anteckningen",
669 description "Anteckningen lyder: ~Magiskt ord XYZZY~.";
670
671 Object -> black_rod "svart stav med en rostig stjärna i änden"
672 with name 'svart' 'svarta' 'stav' 'staven' 'med' 'en' 'den'
673 'rostig' 'rostiga' 'stjärna' 'stjärnan' 'järnstjärna' 'järnstjärnan'
674 'i//' 'änden' 'meterlång' 'meterlånga',
675 short_name_def "svarta staven med en rostig stjärna i änden",
676 description "Det är en meterlång svart stav med en rostig stjärna i ena änden.",
677 initial
678 "En meterlång svart stav med en rostig stjärna i ena änden ligger i närheten.",
679 before [;
680 Wave:
681 if (location == West_Side_Of_Fissure or On_East_Bank_Of_Fissure) {
682 if (caves_closed) "Märkligt. Inget händer.";
683 if (CrystalBridge notin nothing) {
684 remove CrystalBridge;
685 give CrystalBridge absent;
686 West_Side_Of_Fissure.e_to = nothing;
687 On_East_Bank_Of_Fissure.w_to = nothing;
688 "Kristallbron har försvunnit!";
689 }
690 else {
691 move CrystalBridge to location;
692 give CrystalBridge ~absent;
693 West_Side_Of_Fissure.e_to = CrystalBridge;
694 On_East_Bank_Of_Fissure.w_to = CrystalBridge;
695 "En kristallbro spänner nu över gapet.";
696 }
697 }
698 "Inget händer.";
699 ],
700 has def_article;
701
702 ! ------------------------------------------------------------------------------
703
704 Room In_Awkward_Sloping_E_W_Canyon "Sluttande Ö/V-ravin"
705 with teleport_to
706 'ytan' 'yta' 'ingång' 'ingången' Below_The_Grate
707 'skräp' 'skräpet' 'skräprum' 'skräprummet' In_Debris_Room
708 'litet' 'lilla' 'hål' 'hålet' At_Top_Of_Small_Pit,
709 description "Du är i en trång sluttande öst/väst-ravin.",
710 d_to In_Debris_Room,
711 e_to In_Debris_Room,
712 u_to In_Bird_Chamber,
713 w_to In_Bird_Chamber,
714 has nodwarf;
715
716 ! ------------------------------------------------------------------------------
717 ! Den lilla fågeln i sitt naturliga habitat
718 ! ------------------------------------------------------------------------------
719
720 Room In_Bird_Chamber "Oranga flodkammaren"
721 with teleport_to
722 'ytan' 'yta' 'ingång' 'ingången' Below_The_Grate
723 'skräp' 'skräpet' 'skräprum' 'skräprummet' In_Debris_Room
724 'trång' 'trånga' 'ravin' 'ravinen' In_Awkward_Sloping_E_W_Canyon
725 'litet' 'lilla' 'hål' 'hålet' 'bra' 'gång' 'gången' At_Top_Of_Small_Pit,
726 description
727 "Du är i en fantastisk kammare, tio meter hög.
728 Väggarna är frusna floder av orange sten.
729 En trång ravin och en bra gång leder ut från östra och västra sidorna av kammaren.",
730 e_to In_Awkward_Sloping_E_W_Canyon,
731 w_to At_Top_Of_Small_Pit,
732 has nodwarf;
733
734 Object -> little_bird "liten fågel"
735 with name 'munter' 'muntra' 'glad' 'glada' 'sorgsen' 'sorgsna' 'ledsen' 'ledsna' 'lilla' 'liten' 'fågel' 'fågeln',
736 short_name_def "lilla fågeln",
737 initial "En munter liten fågel sitter och sjunger här.",
738 before [;
739 Examine:
740 if (self in wicker_cage)
741 "Den lilla fågeln ser olycklig ut i buren.";
742 "Den muntra lilla fågeln sitter här och sjunger.";
743 Insert:
744 if (second == wicker_cage)
745 <<Catch self>>;
746 else
747 "Sätt inte fågeln i ", (the) second, "!";
748 Drop, Remove:
749 if (self in wicker_cage) {
750 print "(Fågeln slipper ut från buren.)^^";
751 <<Release self>>;
752 }
753 Take, Catch:
754 if (self in wicker_cage)
755 "Du har redan den lilla fågeln.
756 Om du tar ut den ur buren kommer den troligen flyga iväg från dig.";
757 if (wicker_cage notin player)
758 "Du kan fånga fågeln, men du kan inte bära den med dig.";
759 if (black_rod in player)
760 "Fågeln var orädd när du kom in,
761 men när du närmar dig blir den störd och du kan inte fånga den.";
762 move self to wicker_cage;
763 give wicker_cage ~open;
764 "Du fångar fågeln i den flätade buren.";
765 Release:
766 if (self notin wicker_cage)
767 "Fågeln sitter inte i någon bur.";
768 give wicker_cage open;
769 move self to location;
770 if (Snake in location) {
771 remove Snake;
772 "Den lilla fågeln attackerar den gröna ormen,
773 och förvånansvärt snabbt tvingar den bort ormen.";
774 }
775 if (Dragon in location) {
776 remove self;
777 "Den lilla fågeln attackerar den gröna draken,
778 och förvånansvärt snabbt bränns den till en kolbit.
779 Askan blåser bort.";
780 }
781 "Den lilla fågeln flaxar ut i friheten.";
782 ],
783 life [;
784 Give:
785 "Den är inte hungrig. (Den bara längtar efter fjordarna).
786 Dessutom misstänker jag att den skulle föredra fågelfrö.";
787 Order, Ask, Answer:
788 "Kvitter! Kviddevitt!";
789 Attack:
790 if (self in wicker_cage)
791 "Nej, lämna den stackars olyckliga fågeln i fred.";
792 remove self;
793 "Den lilla fågeln är nu död. Dess kropp försvinner.";
794 ],
795 has def_article animate;
796
797 ! ------------------------------------------------------------------------------
798
799 Room At_Top_Of_Small_Pit "Ovanför ett litet hål"
800 with teleport_to
801 'ytan' 'yta' 'ingång' 'ingången' Below_The_Grate
802 'skräp' 'skräpet' 'skräprum' 'skräprummet' In_Debris_Room
803 'gång' 'gången' In_Bird_Chamber,
804 description
805 "Vid dina fötter finns ett litet hål som andas ut spår av vit dimma.
806 En västlig gång slutar här föruom en liten spricka som fortsätter.
807 ^^
808 Grova trappsteg av sten leder ner i hålet.",
809 e_to In_Bird_Chamber,
810 w_to "Sprickan är alltför liten för att du ska kunna komma igenom den.",
811 d_to [;
812 if (large_gold_nugget in player) {
813 deadflag = 1;
814 "Du är på hålets botten med en bruten nacke.";
815 }
816 return In_Hall_Of_Mists;
817 ],
818 before [;
819 Enter:
820 if (noun == PitCrack)
821 "Sprickan är alltför liten för att du ska kunna komma igenom den.";
822 ],
823 has nodwarf;
824
825 Scenic -> "litet hål"
826 with name 'litet' 'lilla' 'hål' 'hålet',
827 short_name_def "lilla hålet",
828 description "Hålet andas ut spår av vit dimma.",
829 has def_article neuter;
830
831 Scenic -> PitCrack "spricka"
832 with name 'spricka' 'sprickan' 'liten' 'lilla' 'trång' 'trånga',
833 short_name_def "sprickan",
834 description "Sprickan är väldigt liten -- alldeles för liten för att du ska kunna komma igenom den.";
835
836 Scenic "dimma"
837 with name 'dimma' 'dimman' 'ånga' 'ångan' 'vit' 'vita'
838 'slöja' 'slöjan' 'slöjor' 'slöjorna' 'dimslöja' 'dimslöjan' 'dimslöjor' 'dimslöjorna',
839 short_name_def "dimman",
840 description
841 "Dimma är en vit ånga, vanligen av vatten, som man ser ibland i grottor.
842 Den kan dyka upp var som helst men är ofta ett tecken på ett djupt hål som leder ner till vatten.",
843 found_in
844 At_Top_Of_Small_Pit In_Hall_Of_Mists On_East_Bank_Of_Fissure
845 At_Window_On_Pit_1 At_West_End_Of_Hall_Of_Mists In_Misty_Cavern
846 In_Mirror_Canyon At_Reservoir At_Window_On_Pit_2 On_Sw_Side_Of_Chasm;
847
848 ! ------------------------------------------------------------------------------
849 ! Grottorna öppnar sig: Dimmornas Sal
850 ! ------------------------------------------------------------------------------
851
852 Room In_Hall_Of_Mists "I Dimmornas Sal"
853 with teleport_to
854 'vänster' In_Nugget_Of_Gold_Room
855 'framåt' 'fortsätt' 'sal' 'salen' On_East_Bank_Of_Fissure
856 'trappa' 'trappan' 'stentrappa' 'bergakungens' 'sal' In_Hall_Of_Mt_King
857 'y2' At_Y2,
858 description
859 "Du är i ena änden av en enorm sal som sträcker sig framåt så långt ögat når åt väst.
860 Det finns öppningar åt båda hållen.
861 En bred stentrappa leder neråt.
862 Salen är fylld av vita dimslöjor som svajar fram och tillbaka nästan som om de vore levande.
863 En kall vind blåser uppför trappan.
864 Det finns en gång vid toppen av ett schakt bakom dig.
865 ^^
866 Grova trappsteg av sten leder upp genom schaktet.",
867 initial [;
868 if (self has visited) rfalse;
869 score = score + 25;
870 ],
871 s_to In_Nugget_Of_Gold_Room,
872 w_to On_East_Bank_Of_Fissure,
873 d_to In_Hall_Of_Mt_King,
874 n_to In_Hall_Of_Mt_King,
875 u_to [;
876 if (large_gold_nugget in player) "Du kan inte klättra upp på kupolen.";
877 return At_Top_Of_Small_Pit;
878 ];
879
880 Scenic -> "bred stentrappa"
881 with name 'bred' 'breda' 'trappa' 'trappan' 'stentrappa' 'stentrappan',
882 short_name_def "breda stentrappan",
883 description "Trappan leder neråt."
884 has def_article;
885
886 Scenic -> "grova trappsteg av sten"
887 with name 'grov' 'grovt' 'grova' 'steg' 'steget' 'stegen' 'trappsteg' 'trappsteget' 'trappstegen'
888 'av' 'sten' 'stentrappa' 'stentrappan' 'stentrappsteg' 'stentrappsteget' 'stentrappstegen',
889 short_name_def "grova trappstegen av sten",
890 articles "De" "de" 0,
891 description "De grova trappstegen leder upp genom schaktet.",
892 has def_article pluralname multitude;
893
894 Scenic -> "schakt"
895 with name 'schakt' 'schaktet',
896 short_name_def "schaktet",
897 before [;
898 Examine:
899 if (large_gold_nugget in player)
900 "Jag är inte säker på att du kan komma upp med det du har med dig.";
901 "Det ser ut som att du kanske kan klättra upp genom det.";
902 Climb:
903 MovePlayer(u_obj);
904 rtrue;
905 ],
906 has neuter;
907
908 ! ------------------------------------------------------------------------------
909
910 Room In_Nugget_Of_Gold_Room "Lågt rum"
911 with teleport_to
912 'sal' 'salen' 'dimmornas' In_Hall_Of_Mists,
913 description
914 "Det här är ett lågt rum med ett meddelande slarvigt skrivet på väggen:
915 ^^
916 ~Du kommer inte få upp den för trappan~.",
917 n_to In_Hall_Of_Mists,
918 out_to In_Hall_Of_Mists;
919
920 Scenic -> "meddelande"
921 with name 'meddelande' 'meddelandet' 'slarvigt' 'slarviga' 'skrivet' 'skrivna',
922 short_name_def "meddelandet",
923 description "Meddelandet lyder ~Du kommer inte få upp den för trappan~.",
924 has neuter;
925
926 Treasure -> large_gold_nugget "stor guldklimp"
927 with name 'guld' 'guldet' 'klimp' 'klimpen' 'guldklimp' 'guldklimpen'
928 'stor' 'stora' 'tung' 'tunga',
929 short_name_def "stora guldklimpen",
930 description "Det är en stor glimmande guldklimp!",
931 initial "Det ligger en stor glimmande guldklimp här!"
932 has def_article;
933
934 ! ------------------------------------------------------------------------------
935
936 Class FissureRoom
937 class Room
938 with before [;
939 Jump:
940 if (CrystalBridge hasnt absent)
941 "Jag vill nog ändå föreslå att du går över bron istället för att hoppa.";
942 deadflag = 1;
943 "Du klarade det inte.";
944 ],
945 d_to "Klyftan är alltför skrämmande!";
946
947 FissureRoom On_East_Bank_Of_Fissure "På östra sidan av klyftan"
948 with teleport_to
949 'sal' 'salen' 'dimmornas' In_Hall_Of_Mists,
950 description
951 "Du är på östra sidan av en klyfta som går tvärs över hela salen.
952 Dimman är väldigt tjock här, och klyftan är för bred att hoppa över.",
953 e_to In_Hall_Of_Mists,
954 w_to "Klyftan är för bred.";
955
956 FissureRoom West_Side_Of_Fissure "Västra sidan av klyftan"
957 with description
958 "Du är på västra sidan av klyftan i Dimmornas Sal.",
959 w_to At_West_End_Of_Hall_Of_Mists,
960 e_to "Klyftan är för bred.",
961 n_to At_West_End_Of_Hall_Of_Mists,
962 before [;
963 Go:
964 if (location == West_Side_Of_Fissure && noun == n_obj)
965 print
966 "Du har ålat genom en mycket låg, bred gång,
967 parallell med och norr om Dimmornas Sal.^";
968 ];
969
970 Treasure -> "diamanter"
971 with name 'diamant' 'diamanten' 'diamanter' 'diamanterna' 'flera' 'av' 'hög' 'högsta' 'kvalitet',
972 short_name_def "diamanterna",
973 articles 0 0 "några",
974 description "De ser ut att vara av högsta kvalitet!",
975 initial "Det finns diamanter här!",
976 has pluralname multitude;
977
978 Object CrystalBridge "kristallbro"
979 with name 'kristallbro' 'kristallbron' 'bro' 'bron' 'av' 'kristall',
980 short_name_def "kristallbron",
981 description "Den sträcker sig över klyftan, och ger dig därmed en väg över.",
982 initial "En kristallbro sträcker sig nu över klyftan.",
983 door_dir [;
984 if (location == West_Side_Of_Fissure) return e_to;
985 return w_to;
986 ],
987 door_to [;
988 if (location == West_Side_Of_Fissure) return On_East_Bank_Of_Fissure;
989 return West_Side_Of_Fissure;
990 ],
991 found_in On_East_Bank_Of_Fissure West_Side_Of_Fissure,
992 has static door open absent;
993
994 Scenic "klyfta"
995 with name 'bred' 'breda' 'klyfta' 'klyftan',
996 short_name_def "klyftan",
997 description "Klyftan ser alldeles för bred ut för att man ska kunna hoppa över den.",
998 found_in On_East_Bank_Of_Fissure West_Side_Of_Fissure;
999
1000 ! ------------------------------------------------------------------------------
1001
1002 Room At_West_End_Of_Hall_Of_Mists "I västra änden av Dimmornas Sal"
1003 with teleport_to
1004 'liten' 'lilla' Alike_Maze_1
1005 'låg' 'bred' 'kryp' At_East_End_Of_Long_Hall,
1006 description
1007 "Du är i västra änden av Dimmornas Sal.
1008 En låg, bred gång med kryphöjd fortsätter västerut och en annan går norrut.
1009 Söderut finns en liten gång knappt två meter över golvet.",
1010 s_to Alike_Maze_1,
1011 u_to Alike_Maze_1,
1012 e_to West_Side_Of_Fissure,
1013 w_to At_East_End_Of_Long_Hall,
1014 n_to West_Side_Of_Fissure,
1015 before [;
1016 Go:
1017 if (noun == n_obj)
1018 print
1019 "Du har krupit genom en mycket låg, bred gång
1020 parallell med och norr om Dimmornas Sal.^";
1021 ];
1022
1023 ! ------------------------------------------------------------------------------
1024 ! Långa Salen väster om Dimmornas Sal
1025 ! ------------------------------------------------------------------------------
1026
1027 Room At_East_End_Of_Long_Hall "I östra änden av Långa Salen"
1028 with teleport_to
1029 'kryp' 'låg' 'låga' 'bred' 'breda' 'gång' 'gången' At_West_End_Of_Hall_Of_Mists
1030 'runt' 'runda' 'halvmetersbrett' 'hål' 'hålet' Crossover,
1031 description
1032 "Du är i östra änden av en mycket lång sal som tycks sakna sidokammare.
1033 Österut ligger en låg bred gång som sluttar uppåt.
1034 Norrut ligger ett runt halvmeterbrett hål som sluttar neråt.",
1035 e_to At_West_End_Of_Hall_Of_Mists,
1036 u_to At_West_End_Of_Hall_Of_Mists,
1037 w_to At_West_End_Of_Long_Hall,
1038 n_to Crossover,
1039 d_to Crossover;
1040
1041 ! ------------------------------------------------------------------------------
1042
1043 Room At_West_End_Of_Long_Hall "I västra änden av Långa Salen"
1044 with description
1045 "Du är i västra änden av en mycket lång, formlös sal.
1046 Salen möter här en trång nord-sydlig gång.",
1047 e_to At_East_End_Of_Long_Hall,
1048 s_to Different_Maze_1,
1049 n_to Crossover;
1050
1051 ! ------------------------------------------------------------------------------
1052
1053 Room Crossover "N/S- och Ö/V-korsning"
1054 with description
1055 "Du är i en korsning mellan en hög nord-sydlig gång och en låg öst-västlig gång.",
1056 w_to At_East_End_Of_Long_Hall,
1057 n_to Dead_End_7,
1058 e_to In_West_Side_Chamber,
1059 s_to At_West_End_Of_Long_Hall;
1060
1061 Scenic -> "korsning"
1062 with name 'korsning' 'korsningen',
1063 short_name_def "korsningen",
1064 description "Du vet lika mycket som jag just nu.";
1065
1066 ! ------------------------------------------------------------------------------
1067 ! Många återvändsgränder kommer behövas för labyrinten nedan, så
1068 ! definiera en klass:
1069 ! ------------------------------------------------------------------------------
1070
1071 Class DeadendRoom
1072 with short_name "Återvändsgränd",
1073 description "Du har nått en återvändsgränd.",
1074 cant_go "Du måste gå tillbaka samma väg som du kom.";
1075
1076 DeadendRoom Dead_End_7
1077 with s_to Crossover,
1078 out_to Crossover;
1079
1080 ! ------------------------------------------------------------------------------
1081 ! Bergakungens Sal och sidokammare
1082 ! ------------------------------------------------------------------------------
1083
1084 Room In_Hall_Of_Mt_King "Bergakungens Sal"
1085 with teleport_to
1086 'sal' 'salen' 'dimmornas' 'trappa' 'trappan' In_Hall_Of_Mists
1087 'hemlig' 'hemliga' In_Secret_E_W_Canyon,
1088 description
1089 "Du är i Bergakungens Sal, med gångar åt alla håll.",
1090 cant_go "Okej, kanske inte riktigt alla håll.",
1091 u_to In_Hall_Of_Mists,
1092 e_to In_Hall_Of_Mists,
1093 n_to Low_N_S_Passage,
1094 s_to In_South_Side_Chamber,
1095 w_to In_West_Side_Chamber,
1096 sw_to In_Secret_E_W_Canyon,
1097 before [;
1098 Go:
1099 if (Snake in self && (noun == n_obj or s_obj or w_obj ||
1100 (noun == sw_obj && random(100) <= 35)))
1101 "Du kan inte komma förbi ormen.";
1102 ];
1103
1104 Object -> Snake "orm"
1105 with name 'orm' 'ormen' 'kobra' 'stor' 'stora' 'jättestor' 'jättestora'
1106 'farlig' 'farliga' 'livsfarlig' 'livsfarliga' 'dödlig' 'dödliga'
1107 'grön' 'gröna' 'vildsint' 'vildsinta' 'vild' 'vilda'
1108 'giftig' 'giftiga',
1109 short_name_def "ormen",
1110 description "Jag skulle inte bråka med den om jag var du.",
1111 initial "En gigantisk, grön, vildsint orm blockerar vägen!",
1112 life [;
1113 Order, Ask, Answer:
1114 "Väääääs!";
1115 ThrowAt:
1116 if (noun == axe) <<Attack self>>;
1117 <<Give noun self>>;
1118 Give:
1119 if (noun == little_bird) {
1120 remove little_bird;
1121 "Ormen har nu slukat din fågel.";
1122 }
1123 "Det finns inget här som den vill äta (förutom dig då, kanske).";
1124 Attack:
1125 "Att attackera ormen är både verkningslöst och mycket farligt.";
1126 Take:
1127 deadflag = 1;
1128 "Den tar dig istället. Smask!";
1129 ],
1130 has animate;
1131
1132 ! ------------------------------------------------------------------------------
1133
1134 Room Low_N_S_Passage "Låg N/S-gång"
1135 with teleport_to
1136 'bergakungens' 'sal' 'salen' In_Hall_Of_Mt_King
1137 'y2' At_Y2
1138 'hål' 'hålet' In_Dirty_Passage,
1139 description
1140 "Du är i en låg N/S-gång vid ett hål i golvet.
1141 Hålet leder ner till en Ö/V-gång.",
1142 s_to In_Hall_Of_Mt_King,
1143 out_to In_Hall_Of_Mt_King,
1144 d_to In_Dirty_Passage,
1145 n_to At_Y2;
1146
1147 Treasure -> "silvertackor"
1148 with name 'silvertacka' 'silvertackan' 'silvertackor' 'silvertackorna'
1149 'tacka' 'tackan' 'tackor' 'tackorna' 'silver' 'silvret',
1150 short_name_def "silvertackorna",
1151 articles 0 0 "några",
1152 description "De är nog värda en förmögenhet!",
1153 initial "Det ligger silvertackor här!",
1154 has pluralname;
1155
1156 ! ------------------------------------------------------------------------------
1157
1158 Room In_South_Side_Chamber "I södra sidokammaren"
1159 with teleport_to
1160 'bergakungens' 'sal' 'salen' In_Hall_Of_Mt_King,
1161 description "Du är i den södra sidokammaren.",
1162 n_to In_Hall_Of_Mt_King,
1163 out_to In_Hall_Of_Mt_King;
1164
1165 Treasure -> "dyrbara smycken"
1166 with name 'dyrbar' 'dyrbara' 'smycke' 'smycket' 'smycken' 'smyckena' 'exquisite',
1167 short_name_def "dyrbara smyckena",
1168 articles "De" "de" "några",
1169 description "De är helt utsökta!",
1170 initial "Det ligger dyrbara smycken här!",
1171 has pluralname def_article;
1172
1173 ! ------------------------------------------------------------------------------
1174
1175 Room In_West_Side_Chamber "I västra sidokammaren"
1176 with teleport_to
1177 'bergakungens' 'sal' 'salen' In_Hall_Of_Mt_King,
1178 description
1179 "Du är i sidokammaren väster om Bergakungens Sal.
1180 En gång fortsätter västerut och uppåt här.",
1181 w_to Crossover,
1182 u_to Crossover,
1183 e_to In_Hall_Of_Mt_King,
1184 out_to In_Hall_Of_Mt_King;
1185
1186 Treasure -> rare_coins "sällsynta mynt"
1187 with name 'sällsynt' 'sällsynta' 'mynt' 'myntet' 'mynten',
1188 short_name_def "sällsynta mynten",
1189 articles "De" "de" "många",
1190 description "De är en numismatikers dröm!",
1191 initial "Det ligger många mynt här!",
1192 has multitude pluralname def_article;
1193
1194 ! ------------------------------------------------------------------------------
1195 ! Y2-klipprummet och omgivningar, lite längre ner
1196 ! ------------------------------------------------------------------------------
1197
1198 Room At_Y2 "Vid ~Y2~"
1199 with teleport_to
1200 'vägg' 'väggen' 'rasade' 'stenar' 'stenarna' Jumble_Of_Rock,
1201 description
1202 "Du är i ett stort rum, med en gång söderut,
1203 en gång västerut, och en vägg av rasade stenar österut.
1204 Det står ett stort ~Y2~ på en klippa i rummets mitt.",
1205 after [;
1206 Look:
1207 if (random(100) <= 25) print "^En ihålig röst säger, ~Plugh.~^";
1208 ],
1209 before [;
1210 Plugh:
1211 PlayerTo(Inside_Building);
1212 rtrue;
1213 Plover:
1214 if (In_Plover_Room hasnt visited) rfalse;
1215 if (egg_sized_emerald in player) {
1216 move egg_sized_emerald to In_Plover_Room;
1217 score = score - 5;
1218 }
1219 PlayerTo(In_Plover_Room);
1220 rtrue;
1221 ],
1222 s_to Low_N_S_Passage,
1223 e_to Jumble_Of_Rock,
1224 w_to At_Window_On_Pit_1;
1225
1226 Scenic -> "~Y2~-klippa"
1227 with name 'y2-klippa' 'y2-klippan' '-klippa' '-klippan' 'y2' 'klippa' 'klippan',
1228 short_name_def "~Y2~-klippan",
1229 description "Det står ett stort ~Y2~ målat på klippan.",
1230 has supporter;
1231
1232 ! ------------------------------------------------------------------------------
1233
1234 Room Jumble_Of_Rock "Bland en massa stenblock"
1235 with teleport_to
1236 'y2' At_Y2,
1237 description "Du är bland en massa stenblock, med sprickor överallt.",
1238 d_to At_Y2,
1239 u_to In_Hall_Of_Mists;
1240
1241 ! ------------------------------------------------------------------------------
1242
1243 Room At_Window_On_Pit_1 "Vid ett fönster mot ett hål"
1244 with teleport_to
1245 'y2' At_Y2,
1246 description
1247 "Du är vid ett lågt fönster med utsikt över ett enormt hål som sträcker sig uppåt utom synhåll.
1248 Ett golv är vagt skönjbart mer än femton meter ner.
1249 Spår av vit dimma täcker hålets golv, och dimman blir tjockare till höger.
1250 Märken i dammet runt fönstret kan tyda på att någon har varit här nyligen.
1251 Tvärs över hålet från dig och sju-åtta meter bort
1252 finns ett liknande fönster in till ett upplyst rum.
1253 Där ser du en mystisk figur som stirrar tillbaka på dig.",
1254 before [;
1255 WaveHands:
1256 "Den mystiska figuren vinkar tillbaka till dig!";
1257 ],
1258 cant_go "Den enda utgången är österut, tillbaka till Y2.",
1259 e_to At_Y2;
1260
1261 Class PitScenic
1262 with found_in At_Window_On_Pit_1 At_Window_On_Pit_2,
1263 has scenery;
1264
1265 PitScenic "fönster"
1266 with name 'fönster' 'fönstret' 'lågt' 'låga',
1267 short_name_def "fönstret",
1268 description "Det ser ut som ett vanligt fönster.",
1269 has openable neuter;
1270
1271 PitScenic "enormt hål"
1272 with name 'hål' 'hålet' 'djupt' 'djupa' 'stort' 'stora' 'enormt' 'enorma',
1273 short_name_def "enorma hålet",
1274 description
1275 "Det är så djupt att du bara nätt och jämt kan se golvet där nere,
1276 och hålets översta del är inte synligt alls.",
1277 has neuter def_article;
1278
1279 PitScenic "märken i dammet"
1280 with name 'märken' 'märkena' 'i//' 'damm' 'dammet',
1281 short_name_def "märkena i dammet",
1282 description "Du är tydligen inte ensam här.",
1283 has multitude pluralname;
1284
1285 PitScenic "mystisk figur"
1286 with name 'mystisk' 'mystiska' 'figur' 'figuren' 'person' 'personen' 'skum' 'skumma',
1287 short_name_def "mystiska figuren",
1288 description
1289 "Den mystiska figuren verkar försöka fånga din uppmärksamhet.",
1290 has def_article;
1291
1292 ! ------------------------------------------------------------------------------
1293
1294 Room In_Dirty_Passage "Smutsig gång"
1295 with teleport_to
1296 'låg' 'låga' On_Brink_Of_Pit
1297 'hål' 'hålet' Low_N_S_Passage
1298 'stor' 'stora' In_Dusty_Rock_Room
1299 'lapptäcket' In_Bedquilt,
1300 description
1301 "Du är i en smutsig, trasig gång.
1302 Österut finns en låg gång.
1303 Västerut finns en stor gång.
1304 Ovanför dig finns ett hål till en annan gång.",
1305 e_to On_Brink_Of_Pit,
1306 u_to Low_N_S_Passage,
1307 w_to In_Dusty_Rock_Room;
1308
1309 ! ------------------------------------------------------------------------------
1310
1311 Room On_Brink_Of_Pit "Kanten av ett hål"
1312 with teleport_to
1313 'låg' 'låga' 'gång' 'gången' In_Dirty_Passage
1314 'litet' 'lilla' 'rent' 'rena' 'hål' 'hålet' In_Pit,
1315 description
1316 "Du är vid kanten av ett litet rent hål, som man skulle kunna klättra ner i.
1317 En låg gång leder västerut.",
1318 w_to In_Dirty_Passage,
1319 d_to In_Pit,
1320 in_to In_Pit;
1321
1322 Scenic -> "litet hål"
1323 with name 'hål' 'hålet' 'litet' 'lilla' 'rent' 'rena',
1324 short_name_def "lilla hålet",
1325 description "Det ser ut som att du nog skulle kunna klättra ner i det.",
1326 before [;
1327 Climb, Enter:
1328 MovePlayer(d_obj);
1329 rtrue;
1330 ],
1331 has def_article neuter;
1332
1333 ! ------------------------------------------------------------------------------
1334
1335 Room In_Pit "I ett hål"
1336 with description
1337 "Du är på botten av ett litet hål med en bäck
1338 som kommer in i hålet och går ut ur hålet genom smala springor.",
1339 u_to On_Brink_Of_Pit,
1340 d_to "Du kommer inte igenom de smala springorna!",
1341 has nodwarf;
1342
1343 Scenic -> "smala springor"
1344 with name 'springa' 'springan' 'springor' 'springorna' 'smal' 'smala' 'små' 'liten' 'lilla',
1345 short_name_def "smala springorna",
1346 description "Springorna bildar ett komplext mönster i klippan.",
1347 has multitude pluralname def_article;
1348
1349 ! ------------------------------------------------------------------------------
1350
1351 Room In_Dusty_Rock_Room "I dammigt stenrum"
1352 with teleport_to
1353 'gång' 'gången' In_Dirty_Passage
1354 'stort' 'stora' 'hål' 'hålet' 'golv' 'golvet' At_Complex_Junction
1355 'lapptäcket' In_Bedquilt,
1356 description
1357 "Du är i ett stort rum fullt av dammiga stenar.
1358 Det är ett stort hål i golvet.
1359 Det finns sprickor överallt, och en gång som leder österut.",
1360 e_to In_Dirty_Passage,
1361 d_to At_Complex_Junction;
1362
1363 Scenic -> "dammiga stenar"
1364 with name 'sten' 'stenen' 'stenar' 'stenarna' 'klippa' 'klippan' 'klippor' 'klipporna'
1365 'dammig' 'dammiga' 'smutsig' 'smutsiga',
1366 short_name_def "dammiga stenarna",
1367 description "Det är bara stenar. (Dammiga sådana, alltså.)",
1368 before [;
1369 LookUnder, Push, Pull:
1370 "Du skulle behöva spränga dig igenom.";
1371 ],
1372 has multitude pluralname def_article;
1373
1374 ! ------------------------------------------------------------------------------
1375 ! En labyrint av slingrande trånga gångar, alla likadana...
1376 ! ------------------------------------------------------------------------------
1377
1378 Class MazeRoom
1379 with short_name "Labyrint",
1380 description "Du är i en labyrint av slingrande trånga gångar, alla likadana.",
1381 out_to "Lättare sagt än gjort.";
1382
1383 MazeRoom Alike_Maze_1
1384 with u_to At_West_End_Of_Hall_Of_Mists,
1385 n_to Alike_Maze_1,
1386 e_to Alike_Maze_2,
1387 s_to Alike_Maze_4,
1388 w_to Alike_Maze_11;
1389
1390 MazeRoom Alike_Maze_2
1391 with w_to Alike_Maze_1,
1392 s_to Alike_Maze_3,
1393 e_to Alike_Maze_4;
1394
1395 MazeRoom Alike_Maze_3
1396 with e_to Alike_Maze_2,
1397 d_to Dead_End_3,
1398 s_to Alike_Maze_6,
1399 n_to Dead_End_13;
1400
1401 MazeRoom Alike_Maze_4
1402 with w_to Alike_Maze_1,
1403 n_to Alike_Maze_2,
1404 e_to Dead_End_1,
1405 s_to Dead_End_2,
1406 u_to Alike_Maze_14,
1407 d_to Alike_Maze_14;
1408
1409 MazeRoom Alike_Maze_5
1410 with e_to Alike_Maze_6,
1411 w_to Alike_Maze_7;
1412
1413 MazeRoom Alike_Maze_6
1414 with e_to Alike_Maze_3,
1415 w_to Alike_Maze_5,
1416 d_to Alike_Maze_7,
1417 s_to Alike_Maze_8;
1418
1419 DeadendRoom Dead_End_1
1420 with w_to Alike_Maze_4,
1421 out_to Alike_Maze_4;
1422
1423 DeadendRoom Dead_End_2
1424 with w_to Alike_Maze_4,
1425 out_to Alike_Maze_4;
1426
1427 DeadendRoom Dead_End_3
1428 with u_to Alike_Maze_3,
1429 out_to Alike_Maze_3;
1430
1431 MazeRoom Alike_Maze_7
1432 with w_to Alike_Maze_5,
1433 u_to Alike_Maze_6,
1434 e_to Alike_Maze_8,
1435 s_to Alike_Maze_9;
1436
1437 MazeRoom Alike_Maze_8
1438 with w_to Alike_Maze_6,
1439 e_to Alike_Maze_7,
1440 s_to Alike_Maze_8,
1441 u_to Alike_Maze_9,
1442 n_to Alike_Maze_10,
1443 d_to Dead_End_12;
1444
1445 MazeRoom Alike_Maze_9
1446 with w_to Alike_Maze_7,
1447 n_to Alike_Maze_8,
1448 s_to Dead_End_4;
1449
1450 DeadendRoom Dead_End_4
1451 with w_to Alike_Maze_9,
1452 out_to Alike_Maze_9;
1453
1454 MazeRoom Alike_Maze_10
1455 with w_to Alike_Maze_8,
1456 n_to Alike_Maze_10,
1457 d_to Dead_End_5,
1458 e_to At_Brink_Of_Pit;
1459
1460 DeadendRoom Dead_End_5
1461 with u_to Alike_Maze_10,
1462 out_to Alike_Maze_10;
1463
1464 ! ------------------------------------------------------------------------------
1465
1466 Room At_Brink_Of_Pit "Vid kanten av ett hål"
1467 with description
1468 "Du är vid kanten av ett tio meter djupt hål med en massiv,
1469 orange pelare som sträcker sig nerför en av väggarna.
1470 Du skulle kunna klättra ner här men du skulle inte kunna ta dig upp igen.
1471 Labyrinten fortsätter på den här nivån.",
1472 d_to In_Bird_Chamber,
1473 w_to Alike_Maze_10,
1474 s_to Dead_End_6,
1475 n_to Alike_Maze_12,
1476 e_to Alike_Maze_13;
1477
1478 Scenic -> "massiv orange pelare"
1479 with name 'pelare' 'pelaren' 'massiv' 'massiva' 'orange' 'oranga' 'orangea' 'stor' 'stora'
1480 'enorm' 'enorma' 'gigantisk' 'gigantiska',
1481 short_name_def "massiva oranga pelaren",
1482 description "Det ser ut som att du skulle kunna klättra nerför den.",
1483 before [;
1484 Climb:
1485 MovePlayer(d_obj);
1486 rtrue;
1487 ],
1488 has def_article;
1489
1490 Scenic -> "hål"
1491 with name 'hål' 'hålet' 'tio' 'meter' 'djupt' 'djupa' '10' '10m',
1492 short_name_def "hålet",
1493 description "Du måste klättra mer för att få reda på mer...",
1494 before [;
1495 Climb:
1496 MovePlayer(d_obj);
1497 rtrue;
1498 ],
1499 has neuter;
1500
1501 DeadendRoom Dead_End_6
1502 with e_to At_Brink_Of_Pit,
1503 out_to At_Brink_Of_Pit;
1504
1505 ! ------------------------------------------------------------------------------
1506 ! En rad med tre viktiga korsningar, från öst till väst
1507 ! ------------------------------------------------------------------------------
1508
1509 Room At_Complex_Junction "I en komplicerad korsning"
1510 with teleport_to
1511 'rum' 'rummet' In_Dusty_Rock_Room
1512 'lapptäcket' In_Bedquilt
1513 'skalrum' 'skalrummet' In_Shell_Room,
1514 description
1515 "Du är i en komplicerad korsning.
1516 En låg krypgång norrifrån går ihop med en högre krypgång österifrån
1517 för att bilda en promenadgång som leder västerut.
1518 Det finns även ett stort rum ovanför.
1519 Luften är fuktig här.",
1520 u_to In_Dusty_Rock_Room,
1521 w_to In_Bedquilt,
1522 n_to In_Shell_Room,
1523 e_to In_Anteroom;
1524
1525 ! ------------------------------------------------------------------------------
1526
1527 Room In_Bedquilt "Lapptäcket"
1528 with teleport_to
1529 'plattrum' 'plattrummet' In_Slab_Room,
1530 description
1531 "Du är i Lapptäcket, en lång öst-västlig gång med hål överallt.
1532 För att utforska någon slumpvis vald gång, välj norr, söder, upp eller ner.",
1533 e_to At_Complex_Junction,
1534 w_to In_Swiss_Cheese_Room,
1535 s_to In_Slab_Room,
1536 u_to In_Dusty_Rock_Room,
1537 n_to At_Junction_Of_Three,
1538 d_to In_Anteroom,
1539 before [ destiny;
1540 Go:
1541 if (noun == s_obj or d_obj && random(100) <= 80) destiny = 1;
1542 if (noun == u_obj && random(100) <= 80) destiny = 1;
1543 if (noun == u_obj && random(100) <= 50) destiny = In_Secret_N_S_Canyon_1;
1544 if (noun == n_obj && random(100) <= 60) destiny = 1;
1545 if (noun == n_obj && random(100) <= 75) destiny = In_Large_Low_Room;
1546 if (destiny == 1)
1547 "Du har krupit runt i några små hål och åter hamnat i huvudgången.";
1548 if (destiny == 0) rfalse;
1549 PlayerTo(destiny);
1550 rtrue;
1551 ];
1552
1553 ! ------------------------------------------------------------------------------
1554
1555 Room In_Swiss_Cheese_Room "I Schweizerostrummet"
1556 with teleport_to
1557 'ravin' 'ravinen' In_Tall_E_W_Canyon
1558 'orientaliska' In_Oriental_Room,
1559 description
1560 "Du är i ett rum vars väggar mest liknar en Schweizerost.
1561 Det finns uppenbara utgångar åt väst, öst, nordost och nordväst.
1562 En del av rummet upptas av ett stort block av urberget.",
1563 w_to At_East_End_Of_Twopit_Room,
1564 s_to In_Tall_E_W_Canyon,
1565 ne_to In_Bedquilt,
1566 nw_to In_Oriental_Room,
1567 e_to In_Soft_Room,
1568 before [;
1569 Go:
1570 if ((noun == s_obj && random(100) <= 80) ||
1571 (noun == nw_obj && random(100) <= 50))
1572 "Du har krupit runt i några små hål och åter hamnat i huvudgången.";
1573 ];
1574
1575 Scenic -> "urbergsblock"
1576 with name 'stort' 'stora' 'block' 'blocket' 'av' 'urberg' 'urberget'
1577 'stenblock' 'stenblocket' 'urbergsblock' 'urbergsblocket'
1578 'enormt' 'enorma',
1579 short_name_def "urbergsblocket",
1580 description "Det är bara ett enormt block.",
1581 before [;
1582 LookUnder, Push, Pull, Take:
1583 "Du måste skoja.";
1584 ],
1585 has neuter;
1586
1587 ! ------------------------------------------------------------------------------
1588 ! Arean runt Tvåhålsrummet
1589 ! ------------------------------------------------------------------------------
1590 ! Möjliga höjder för växten:
1591 ! ------------------------------------------------------------------------------
1592
1593 Constant TINY_P = 0;
1594 Constant TALL_P = 1;
1595 Constant HUGE_P = 2;
1596
1597 Room At_West_End_Of_Twopit_Room "I Tvågroprummets västra ände"
1598 with teleport_to
1599 'platta' 'plattan' 'plattrum' 'plattrummet' In_Slab_Room
1600 'grop' 'gropen' In_West_Pit,
1601 description
1602 "Du är i Tvågroprummets västra ände.
1603 Det finns ett stort hål i väggen ovanför gropen i den här änden av rummet.",
1604 e_to At_East_End_Of_Twopit_Room,
1605 w_to In_Slab_Room,
1606 d_to In_West_Pit,
1607 u_to "Det sitter för långt upp för att du ska kunna nå det.",
1608 before [;
1609 Enter:
1610 if (noun == HoleAbovePit_1) "Det sitter för långt upp för att du ska kunna nå det.";
1611 ];
1612
1613 Object PlantStickingUp "bönstjälk"
1614 with name 'växt' 'växten' 'bönstjälk' 'bönstjälken' 'stjälk' 'stjälken'
1615 'gigantisk' 'gigantiska' 'liten' 'lilla' 'stor' 'stora'
1616 'fyra' 'meter' 'hög' 'höga' '4//' '4m' 'fyrameters' 'fyrmeters'
1617 'klen' 'klena' 'mumlande' 'mullrande',
1618 short_name_def "bönstjälken",
1619 describe [;
1620 if (Plant.height == TALL_P)
1621 "Översta delen av en fyra meter hög bönstjälk sticker upp ur den västra gropen.";
1622 "En enorm bönstjälk växer upp ur den västra gropen och upp till hålet i väggen.";
1623 ],
1624 before [;
1625 Examine:
1626 RunRoutines(self, describe);
1627 rtrue;
1628 Climb:
1629 if (Plant.height == HUGE_P) <<Climb Plant>>;
1630 ],
1631 found_in At_West_End_Of_Twopit_Room At_East_End_Of_Twopit_Room,
1632 has absent static;
1633
1634 Scenic HoleAbovePit_1 "hål ovanför gropen"
1635 with name 'hål' 'hålet' 'stort' 'stora' 'ovanför' 'grop' 'gropen',
1636 short_name_def "hålet ovanför gropen",
1637 description
1638 "Hålet sitter i väggen ovanför gropen i den här änden av rummet.",
1639 found_in In_West_Pit At_West_End_Of_Twopit_Room,
1640 has neuter;
1641
1642 ! ------------------------------------------------------------------------------
1643
1644 Room In_West_Pit "I västra gropen"
1645 with description
1646 "Du är på botten av den västra gropen i Tvågroprummet.
1647 Det finns ett stort hål i väggen sju-åtta meter ovanför dig.",
1648 before [;
1649 Climb:
1650 if (noun == Plant) rfalse;
1651 if (Plant.height == TINY_P)
1652 "Det finns inget att klättra på här.
1653 Använd ~upp~ eller ~ut~ för att lämna gropen.";
1654 ],
1655 u_to At_West_End_Of_Twopit_Room,
1656 out_to At_West_End_Of_Twopit_Room,
1657 has nodwarf;
1658
1659 Object -> Plant "växt"
1660 with name 'växt' 'växten' 'bönstjälk' 'bönstjälken' 'stjälk' 'stjälken'
1661 'gigantisk' 'gigantiska' 'liten' 'lilla' 'stor' 'stora'
1662 'fyra' 'meter' 'hög' 'höga' '4//' '4m' 'fyrameters' 'fyrmeters'
1663 'klen' 'klena' 'mumlande' 'mullrande',
1664 short_name_def "växten",
1665 describe [;
1666 switch (self.height) {
1667 TINY_P:
1668 "Det står en klen liten växt i gropen, och den mumlar ~Vatten, vatten, ...~";
1669 TALL_P:
1670 "En fyra meter hög bönstjälk sträcker sig upp ur hålet, och den mullrar ~Vatten!! Vatten!!~";
1671 HUGE_P:
1672 "En gigantisk bönstjälk sträcker sig hela vägen upp till hålet.";
1673 }
1674 ],
1675 before [;
1676 Climb:
1677 switch (self.height) {
1678 TINY_P:
1679 "Det är bara en liten växt!";
1680 TALL_P:
1681 print
1682 "Du har klättrat uppför växten och ut ur hålet.^";
1683 PlayerTo(At_West_End_Of_Twopit_Room);
1684 rtrue;
1685 HUGE_P:
1686 print
1687 "Du klättrar uppför växten och skyndar dig in genom hålet högst där uppe.^";
1688 PlayerTo(In_Narrow_Corridor);
1689 rtrue;
1690 }
1691 Take:
1692 "Växten har otroligt djupa rötter och kan inte dras loss.";
1693 Water:
1694 if (bottle notin player)
1695 "Du har inget att vattna växten med.";
1696 switch (child(bottle)) {
1697 nothing:
1698 "Flaskan är tom.";
1699 oil_in_the_bottle:
1700 remove oil_in_the_bottle;
1701 "Växten skakar indignerat av oljan från sina blad och frågar: ~Vatten?~";
1702 }
1703 remove water_in_the_bottle;
1704 switch ((self.height)++) {
1705 TINY_P:
1706 print
1707 "Växten får plötsligt en vannsinnig tillväxt under några sekunder.^^";
1708 give PlantStickingUp ~absent;
1709 TALL_P:
1710 print
1711 "Växten växer explosivt, och fyller nu nästan helt botten av gropen.^^";
1712 HUGE_P:
1713 print
1714 "Du har övervattnat växten! Den skrumpnar bort. Den, den...^^";
1715 give PlantStickingUp absent;
1716 remove PlantStickingUp;
1717 self.height = TINY_P;
1718 }
1719 <<Examine self>>;
1720 Oil:
1721 <<Water self>>;
1722 Examine:
1723 self.describe();
1724 rtrue;
1725 ],
1726 height TINY_P;
1727
1728 ! ------------------------------------------------------------------------------
1729
1730 Room At_East_End_Of_Twopit_Room "I Tvågroprummets östra ände"
1731 with teleport_to
1732 'grop' 'gropen' In_East_Pit,
1733 description
1734 "Du är i Tvågroprummets östra ände.
1735 Golvet här utgörs av en massa tunna stenplattor som gör det lätt att klättra ner i groparna.
1736 En gång leder förbi groparna och förbinder gångarna från öster och väster.
1737 Det finns hål lite överallt,
1738 men det enda stora hålet sitter på väggen rakt ovanför den västra gropen där du inte kan nå det.",
1739 e_to In_Swiss_Cheese_Room,
1740 w_to At_West_End_Of_Twopit_Room,
1741 d_to In_East_Pit;
1742
1743 Scenic -> "tunna stenplattor"
1744 with name 'tunn' 'tunna' 'stenplatta' 'stenplattan' 'stenplattor' 'stenplattorna'
1745 'sten' 'stenen' 'stenar' 'stenarna' 'platta' 'plattan' 'plattor' 'plattorna',
1746 short_name_def "tunna stenplattorna",
1747 articles "De" "de" "en massa",
1748 description "De bildar nästan en naturlig trappa ner i gropen.",
1749 before [;
1750 LookUnder, Push, Pull, Take:
1751 "Du måste skoja. Du skulle behöva spränga bort dem.";
1752 ],
1753 has multitude def_article pluralname;
1754
1755 ! ------------------------------------------------------------------------------
1756
1757 Room In_East_Pit "I östra gropen"
1758 with description
1759 "Du är på botten av den östra gropen i Tvågroprummet.
1760 I ett hörn finns en liten oljepöl.",
1761 u_to At_East_End_Of_Twopit_Room,
1762 out_to At_East_End_Of_Twopit_Room,
1763 has nodwarf;
1764
1765 Scenic -> Oil "oljepöl"
1766 with name 'liten' 'lilla' 'olja' 'oljan' 'pöl' 'pölen' 'oljepöl' 'oljepölen',
1767 short_name_def "oljepölen",
1768 description "Det ser ut som vanlig olja.",
1769 before [;
1770 Drink:
1771 "Absolut inte.";
1772 Take:
1773 if (bottle notin player)
1774 "Du har inget att ha oljan i.";
1775 <<Fill bottle>>;
1776 Insert:
1777 if (second == bottle) <<Fill bottle>>;
1778 "Du har inget att bära oljan i.";
1779 ];
1780
1781 Scenic "hålet ovanför gropen"
1782 with name 'hål' 'hålet' 'stort' 'stora' 'ovanför' 'över' 'grop' 'gropen',
1783 description "Hålet sitter i väggen ovanför dig.",
1784 found_in In_East_Pit At_East_End_Of_Twopit_Room
1785 has proper;
1786
1787 ! ------------------------------------------------------------------------------
1788
1789 Room In_Slab_Room "Plattrummet"
1790 with description
1791 "Du är i en stor, låg, rund kammare
1792 vars golv är en enorm platta som fallit från taket (plattrummet).
1793 Österut och västerut har det tidigare funnits stora gångar, men de är nu fyllda av stenblock.
1794 Låga, små gångar leder norrut och söderut, och den södra böjer kvickt av västerut, runt stenblocken.",
1795 s_to At_West_End_Of_Twopit_Room,
1796 u_to In_Secret_N_S_Canyon_0,
1797 n_to In_Bedquilt;
1798
1799 Scenic -> "stenplatta"
1800 with name 'platta' 'stenplatta' 'enorm' 'stor' 'plattan' 'stenplattan' 'enorma' 'stora',
1801 short_name_def "stenplattan",
1802 description "Den är nu golvet här.",
1803 before [;
1804 LookUnder, Push, Pull, Take:
1805 "Du måste skoja.";
1806 ];
1807
1808 Scenic -> "stenblock"
1809 with name 'sten' 'stenen' 'stenar' 'stenarna' 'block' 'blocket' 'blocken'
1810 'stenblock' 'stenblocket' 'stenblocken',
1811 short_name_def "stenblocken",
1812 description "De är bara vanlig stenblock.",
1813 has multitude pluralname;
1814
1815 ! ------------------------------------------------------------------------------
1816 ! Ett litet nätverk av raviner, huvudsakligen Hemliga
1817 ! ------------------------------------------------------------------------------
1818
1819 Room In_Secret_N_S_Canyon_0 "Hemlig N/S-ravin"
1820 with teleport_to
1821 'plattrum' 'plattrummet' In_Slab_Room
1822 'reservoar' 'reservoaren' At_Reservoir,
1823 description
1824 "Du är i en hemlig N/S-ravin ovanför ett stort rum.",
1825 d_to In_Slab_Room,
1826 s_to In_Secret_Canyon,
1827 n_to In_Mirror_Canyon,
1828 before [;
1829 Go:
1830 if (noun == s_obj) canyon_from = self;
1831 ];
1832
1833 Room In_Secret_N_S_Canyon_1 "Hemlig N/S-ravin"
1834 with teleport_to
1835 'ganska' 'stor' 'stora' 'gång' 'gången' 'lapptäcket' In_Bedquilt,
1836 description
1837 "Du är i en hemlig N/S-ravin ovanför en ganska stor gång.",
1838 n_to At_Junction_Of_Three,
1839 d_to In_Bedquilt,
1840 s_to Atop_Stalactite;
1841
1842 Room At_Junction_Of_Three "Korsningen mellan tre hemliga raviner"
1843 with description
1844 "Du är i en hemlig ravin i korsningen mellan tre hemliga raviner, vilka går mot nord, syd och sydost.
1845 Den norra är lika hög som de två andra tillsammans.",
1846 se_to In_Bedquilt,
1847 s_to In_Secret_N_S_Canyon_1,
1848 n_to At_Window_On_Pit_2;
1849
1850 Room In_Large_Low_Room "Stort lågt rum"
1851 with teleport_to
1852 'lapptäcket' In_Bedquilt
1853 'orientaliska' In_Oriental_Room,
1854 description
1855 "Du är i ett stort lågt rum. Krypgångar leder norrut, sydost och sydväst.",
1856 sw_to In_Sloping_Corridor,
1857 se_to In_Oriental_Room,
1858 n_to Dead_End_Crawl;
1859
1860 Room Dead_End_Crawl "Återvändskrypgång"
1861 with teleport_to
1862 'kryp' In_Large_Low_Room,
1863 description "Det här är en återvändskrypgång.",
1864 s_to In_Large_Low_Room,
1865 out_to In_Large_Low_Room;
1866
1867 Room In_Secret_E_W_Canyon "Hemlig Ö/V-ravin ovanför trång ravin"
1868 with description
1869 "Du är i en hemlig ravin som här löper Ö/V.
1870 Den korsar en mycket trång ravin fem meter ner.
1871 Om du går ner kan du få svårt att ta sig upp igen.",
1872 e_to In_Hall_Of_Mt_King,
1873 w_to In_Secret_Canyon,
1874 before [;
1875 Go:
1876 if (noun == w_obj) canyon_from = self;
1877 ],
1878 d_to In_N_S_Canyon;
1879
1880 Room In_N_S_Canyon "N/S-ravin"
1881 with description "Du är på en bred plats i en väldigt trång N/S-ravin.",
1882 s_to Canyon_Dead_End,
1883 n_to In_Tall_E_W_Canyon;
1884
1885 Room Canyon_Dead_End "Återvändsravin"
1886 with description "Ravinen blir här alltför trång för att man ska kunna fortsätta söderut.",
1887 n_to In_N_S_Canyon;
1888
1889 Room In_Tall_E_W_Canyon "I hög Ö/V-ravin"
1890 with teleport_to
1891 'kryp' 'låg' 'låga' 'trång' 'trånga' 'krypgång' 'krypgången' In_Swiss_Cheese_Room,
1892 description
1893 "Du är i en hög Ö/V-ravin. En låg, trång krypgång går en meter norrut
1894 och verkar sedan öppnas upp.",
1895 e_to In_N_S_Canyon,
1896 w_to Dead_End_8,
1897 n_to In_Swiss_Cheese_Room;
1898
1899 ! ------------------------------------------------------------------------------
1900
1901 Room Atop_Stalactite "Ovanför en stalaktit"
1902 with description
1903 "En stor stalaktit sträcker sig från taket och nästan ända ner till golvet under.
1904 Du skulle kunna klättra nerför den och hoppa den sista biten till golvet,
1905 men då skulle du inte kunna nå den för att klättra upp igen.",
1906 n_to In_Secret_N_S_Canyon_1,
1907 d_to [;
1908 if (random(100) <= 40) return Alike_Maze_6;
1909 if (random(100) <= 50) return Alike_Maze_9;
1910 return Alike_Maze_4;
1911 ],
1912 before [;
1913 Jump, Climb:
1914 <<Go d_obj>>;
1915 ];
1916
1917 Scenic -> "stalaktit"
1918 with name 'stalaktit' 'stalaktiten' 'stalagtit' 'stalagtiten'
1919 'stor' 'stora' 'bred' 'breda' 'tjock' 'tjocka',
1920 short_name_def "stalaktiten",
1921 description
1922 "Du skulle troligen kunna klättra nerför den, men du kan glömma att komma upp igen.",
1923 before [;
1924 LookUnder, Push, Take:
1925 "Skärp dig.";
1926 ];
1927
1928 ! ------------------------------------------------------------------------------
1929 ! Här var det drakar
1930 ! ------------------------------------------------------------------------------
1931
1932 Room In_Secret_Canyon "Hemlig ravin"
1933 with description
1934 "Du är i en hemlig ravin som har utgångar mot norr och öster.",
1935 e_to [;
1936 if (canyon_from == In_Secret_E_W_Canyon) return canyon_from;
1937 if (Dragon in location)
1938 "Draken ser rätt farlig ut. Det är nog säkrast att inte försöka ta sig förbi.";
1939 return In_Secret_E_W_Canyon;
1940 ],
1941 n_to [;
1942 if (canyon_from == In_Secret_N_S_Canyon_0) return canyon_from;
1943 if (Dragon in location)
1944 "Draken ser rätt farlig ut. Det är nog säkrast att inte försöka ta sig förbi.";
1945 return In_Secret_N_S_Canyon_0;
1946 ],
1947 out_to [;
1948 return canyon_from;
1949 ],
1950 before [;
1951 if (action == ##Yes && Dragon.is_being_attacked) {
1952 remove Dragon;
1953 move DragonCorpse to location;
1954 Dragon.is_being_attacked = false;
1955 "Grattis! Du har just förgjort en drake med med dina bara händer!
1956 (Otroligt, eller hur?)";
1957 }
1958 if (action == ##No && Dragon.is_being_attacked) {
1959 Dragon.is_being_attacked = false;
1960 "Skulle inte tro det.";
1961 }
1962 Dragon.is_being_attacked = false;
1963 ];
1964
1965 Object -> Dragon "drake"
1966 with name 'drake' 'draken' 'monster' 'monstret' 'best' 'besten' 'ödla' 'ödlan'
1967 'enorm' 'enorma' 'gigantisk' 'gigantiska' 'grön' 'gröna'
1968 'vildsint' 'vildsinta' 'fjällig' 'fjälliga' 'farlig' 'farliga',
1969 short_name_def "draken",
1970 description "Jag skulle inte bråka med den om jag var du.",
1971 initial "En enorm, grön, vildsint drake blockerar vägen!",
1972 life [;
1973 Attack:
1974 self.is_being_attacked = true;
1975 "Med vad? Dina bara händer?";
1976 Give:
1977 "Draken är obeveklig.";
1978 ThrowAt:
1979 if (noun ~= axe)
1980 "Till och med dina bara händer skulle nog vara bättre än ",(DenEllerHonom) noun,"!";
1981 move axe to location;
1982 "Yxan studsar på drakens tjocka fjäll.";
1983 ],
1984 is_being_attacked false,
1985 has animate uter;
1986
1987 Treasure -> "persisk matta"
1988 with name 'matta' 'mattan' 'persisk' 'persiska' 'fin' 'fina' 'drakens',
1989 short_name_def "persiska mattan",
1990 describe [;
1991 if (Dragon in location)
1992 "Draken ligger utsträckt på den persiska mattan!";
1993 "Den persiska mattan ligger utrullad på golvet här.";
1994 ],
1995 before [;
1996 Take:
1997 if (Dragon in location)
1998 "Du måste få draken att flytta på sig först!";
1999 ],
2000 depositpoints 14,
2001 has def_article;
2002
2003 Object DragonCorpse "drakens kropp"
2004 with name 'drakens' 'kropp' 'kroppen' 'av' 'en' 'lik' 'liket' 'as' 'aset' 'död' 'döda' 'drake' 'draken',
2005 initial "Kroppen av en enorm, grön, död drake ligger vid ena sidan.",
2006 before [;
2007 Attack:
2008 "Du har redan gjort tillräckligt med skada!";
2009 ],
2010 has static proper;
2011
2012 ! ------------------------------------------------------------------------------
2013 ! Och mer av likadana-labyrinten
2014 ! ------------------------------------------------------------------------------
2015
2016 DeadendRoom Dead_End_8
2017 with description "Ravinen leder in i en massa klippblock -- återvändsgränd.",
2018 s_to In_Tall_E_W_Canyon,
2019 out_to In_Tall_E_W_Canyon;
2020
2021 MazeRoom Alike_Maze_11
2022 with n_to Alike_Maze_1,
2023 w_to Alike_Maze_11,
2024 s_to Alike_Maze_11,
2025 e_to Dead_End_9,
2026 ne_to Dead_End_10;
2027
2028 DeadendRoom Dead_End_9
2029 with w_to Alike_Maze_11,
2030 out_to Alike_Maze_11;
2031
2032 DeadendRoom Dead_End_10
2033 with s_to Alike_Maze_3,
2034 out_to Alike_Maze_3;
2035
2036 MazeRoom Alike_Maze_12
2037 with s_to At_Brink_Of_Pit,
2038 e_to Alike_Maze_13,
2039 w_to Dead_End_11;
2040
2041 MazeRoom Alike_Maze_13
2042 with n_to At_Brink_Of_Pit,
2043 w_to Alike_Maze_12,
2044 nw_to Dead_End_13;
2045
2046 DeadendRoom Dead_End_11
2047 with e_to Alike_Maze_12,
2048 out_to Alike_Maze_12;
2049
2050 DeadendRoom Dead_End_12
2051 with u_to Alike_Maze_8,
2052 out_to Alike_Maze_8;
2053
2054 MazeRoom Alike_Maze_14
2055 with u_to Alike_Maze_4,
2056 d_to Alike_Maze_4;
2057
2058 DeadendRoom Dead_End_13
2059 class Room
2060 with se_to Alike_Maze_13,
2061 out_to Alike_Maze_13,
2062 description "Det här är piratens återvändsgränd.",
2063 initial [;
2064 StopDaemon(Pirate);
2065 if (treasure_chest in self && treasure_chest hasnt moved)
2066 "Du har hittat piratens skattkista!";
2067 ],
2068 has nodwarf;
2069
2070 Treasure -> treasure_chest "skattkista"
2071 with name 'kista' 'kistan' 'låda' 'lådan' 'skatt' 'skatten'
2072 'skattkista' 'skattkistan' 'rikedomar' 'rikedomarna'
2073 'piratens' 'piratskatt' 'piratskatten',
2074 short_name_def "skattkistan",
2075 description
2076 "Det är piratens skattkista, fylld med rikedomar av alla de slag!",
2077 initial "Piratens skattkista är här!",
2078 depositpoints 12;
2079
2080 ! ------------------------------------------------------------------------------
2081 ! Ovanför bönstjälken: det gigantiska rummet och vattenfallet
2082 ! ------------------------------------------------------------------------------
2083
2084 Room In_Narrow_Corridor "I en smal korridor"
2085 with teleport_to
2086 'gigantiskt' 'gigantiska' In_Giant_Room,
2087 description
2088 "Du är i en lång, smal korridor som sträcker sig utom synhåll västerut.
2089 I den östra änden finns ett hål genom vilket du kan se en mängd löv.",
2090 d_to In_West_Pit,
2091 w_to In_Giant_Room,
2092 e_to In_West_Pit,
2093 before [;
2094 Jump:
2095 deadflag = 1;
2096 "Du ramlar och bryter nacken!";
2097 ];
2098
2099 Scenic -> "löv"
2100 with name 'löv' 'lövet' 'löven' 'växt' 'växten' 'träd' 'trädet'
2101 'stjälk' 'stjälken' 'bönstjälk' 'bönstjälken' 'mängd' 'mängden',
2102 short_name_def "löven",
2103 articles 0 0 "en mängd",
2104 description
2105 "Löven verkar vara fästa vid bönstjälken som du klättrade på för att komma hit.",
2106 before [;
2107 Count:
2108 "69,105."; ! (Jag tackar Rene Schnoor som räknade dem)
2109 ],
2110 has pluralname;
2111
2112 ! ------------------------------------------------------------------------------
2113
2114 Room At_Steep_Incline "Brant sluttning ovanför ett stort rum"
2115 with teleport_to
2116 'magnifik' 'magnifika' 'grotta' 'grottan' 'vattenfall' 'gång' 'gången' In_Cavern_With_Waterfall,
2117 description
2118 "Du är högst uppe på en brant sluttning ovanför ett stort rum.
2119 Du skulle kunna klättra ner här, men du skulle inte kunna klättra upp igen.
2120 En gång leder tillbaka norrut.",
2121 n_to In_Cavern_With_Waterfall,
2122 d_to In_Large_Low_Room;
2123
2124 ! ------------------------------------------------------------------------------
2125
2126 Room In_Giant_Room "Det gigantiska rummet"
2127 with description
2128 "Du är i det gigantiska rummet.
2129 Taket är för högt upp för att kunna ses i ljuset av din lampa.
2130 Stora gångar leder österut, norrut och söderut.
2131 På västra väggen står den handskrivna inskriptionen ~Fee fie foe foo~ [sic].",
2132 s_to In_Narrow_Corridor,
2133 e_to At_Recent_Cave_In,
2134 n_to In_Immense_N_S_Passage;
2135
2136 Scenic -> "handskriven inskription"
2137 with name 'inskription' 'inskriptionen' 'text'
2138 'skriven' 'skrivna' 'handskriven' 'handskrivna',
2139 short_name_def "handskrivna inskriptionen",
2140 description "Det står ~Fee fie foe foo [sic]~.",
2141 has def_article;
2142
2143 Treasure -> golden_eggs "bo med gyllene ägg"
2144 with name 'ägg' 'ägget' 'äggen' 'bo' 'boet' 'med' 'gyllene' 'vackert' 'vackra' 'guldägg' 'guldäggen',
2145 short_name_def "boet med gyllene ägg",
2146 description "Boet är fyllt med vackra, gyllene ägg!",
2147 initial "Det finns ett stort bo här, fullt av gyllene ägg!",
2148 depositpoints 14,
2149 has multitude neuter;
2150
2151 ! ------------------------------------------------------------------------------
2152
2153 Room At_Recent_Cave_In "Nyligen inträffat ras"
2154 with teleport_to
2155 'gigantiska' In_Giant_Room,
2156 description "Gången blockeras här av ett nyligen inträffat ras.",
2157 s_to In_Giant_Room,
2158 out_to In_Giant_Room;
2159
2160 ! ------------------------------------------------------------------------------
2161
2162 Room In_Immense_N_S_Passage "Jättelik N/S-gång"
2163 with teleport_to
2164 'gigantiska' 'gång' 'gången' In_Giant_Room,
2165 description "Du är i ena änden av en jättelik nord/syd-gång.",
2166 s_to In_Giant_Room,
2167 n_to [;
2168 if (RustyDoor has locked) <<Open RustyDoor>>;
2169 if (RustyDoor hasnt open) {
2170 give RustyDoor open;
2171 print "(bänder först upp dörren)^";
2172 }
2173 return RustyDoor;
2174 ];
2175
2176 Object -> RustyDoor "rostig dörr"
2177 with name 'dörr' 'dörren' 'gångjärn' 'gångjärnet' 'gångjärnen'
2178 'massiv' 'massiva' 'rostig' 'rostiga' 'järndörr' 'järndörren',
2179 short_name_def "rostiga dörren",
2180 description "Det är bara en stor järndörr.",
2181 when_closed "Vägen norrut blockeras av en massiv, rostig järndörr.",
2182 when_open "Vägen norrut går genom en massiv, rostig järndörr.",
2183 door_to In_Cavern_With_Waterfall,
2184 door_dir n_to,
2185 before [;
2186 Open:
2187 if (self has locked)
2188 "Gångjärnen är ordentligt rostiga nu och rör sig inte en millimeter.";
2189 Close:
2190 if (self has open)
2191 "Med tanke på hur mycket jobb det var att öppna dörren,
2192 skulle jag föreslå att du inte stänger den igen.";
2193 "Inga problem -- den är redan stängd.";
2194 Oil:
2195 if (bottle in player && oil_in_the_bottle in bottle) {
2196 remove oil_in_the_bottle;
2197 give self ~locked openable;
2198 "Oljan har smort upp gångjärnen så att dörren nu kan röra sig,
2199 även om den fortfarande är ganska trög.";
2200 }
2201 else
2202 "Du har inget att olja in den med.";
2203 Water:
2204 if (bottle in player && water_in_the_bottle in bottle) {
2205 remove water_in_the_bottle;
2206 give self locked ~open;
2207 "Gångjärnen är ordentligt rostiga nu och rör sig inte en millimeter.";
2208 }
2209 else
2210 "Du har inget att vattna den med.";
2211 ],
2212 after [;
2213 Open:
2214 "Dörren öppnar sig medan kaskader av rostflagor skakar loss.";
2215 ],
2216 has static door locked def_article;
2217
2218 ! ------------------------------------------------------------------------------
2219
2220 Room In_Cavern_With_Waterfall "I en grotta med ett vattenfall"
2221 with teleport_to
2222 'gigantiska' In_Giant_Room,
2223 description
2224 "Du är i en magnifik grotta med en fors,
2225 som far ut i ett glittrande vattenfall och ner i en
2226 dånande virvel i en damm som försvinner genom ett hål i golvet.
2227 Gångar går ut mot söder och väster.",
2228 s_to In_Immense_N_S_Passage,
2229 out_to In_Immense_N_S_Passage,
2230 w_to At_Steep_Incline;
2231
2232 Scenic -> "vattenfall"
2233 with name 'vattenfall' 'vattenfallet' 'dånande' 'virvel' 'virveln'
2234 'glittrande' 'virvlande',
2235 short_name_def "vattenfallet",
2236 description "Skulle inte vilja åka ner där i en tunna!",
2237 has neuter;
2238
2239 Treasure -> trident "juvelbeströdd treudd"
2240 with name 'treudd' 'treudden' 'juvelbeströdd' 'juvelbeströdda' 'juvelprydd'
2241 'juvelprydda' 'sagolik' 'sagolika' 'juvel' 'juveler',
2242 short_name_def "juvelbeströdda treudden",
2243 description "Treudden är täckt av sagolika juveler!",
2244 initial "Det ligger en juvelprydd treudd här!",
2245 depositpoints 14,
2246 has def_article;
2247
2248 ! ------------------------------------------------------------------------------
2249 ! Grottorna runt Lapptäcket
2250 ! ------------------------------------------------------------------------------
2251
2252 Room In_Soft_Room "I mjuka rummet"
2253 with description
2254 "Du är i mjuka rummet.
2255 Väggarna är täckta med tunga draperier, golvet med en tjock luggmatta.
2256 Mossa täcker taket.",
2257 w_to In_Swiss_Cheese_Room,
2258 out_to In_Swiss_Cheese_Room;
2259
2260 Scenic -> "matta"
2261 with name 'matta' 'mattan' 'luggmatta' 'luggmattan'
2262 'tung' 'tunga' 'tjock' 'tjocka',
2263 short_name_def "mattan",
2264 description "Mattan är riktigt flott.";
2265
2266 Scenic -> "draperier"
2267 with name 'draperi' 'draperiet' 'draperier' 'draperierna'
2268 'tung' 'tunga' 'tjock' 'tjocka',
2269 short_name_def "draperierna",
2270 description "De verkar absorbera ljud väldigt väl.",
2271 before [;
2272 Take:
2273 "Gå inte runt och förstör hela stället!";
2274 LookUnder, Search:
2275 "Du hittar inget intressant bakom draperierna.";
2276 ],
2277 has pluralname;
2278
2279 Scenic -> "mossa"
2280 with name 'mossa' 'mossan' 'typisk' 'typiska' 'standardmossa' 'standardmossan',
2281 short_name_def "mossan",
2282 description "Det ser ut som typisk standardmossa.",
2283 before [;
2284 Take:
2285 "Den faller sönder i dina händer.";
2286 ],
2287 has edible proper;
2288
2289 Object -> velvet_pillow "sammetskudde"
2290 with name 'kudde' 'kudden' 'sammet' 'sammeten' 'sammetskudde' 'sammetskudden'
2291 'liten' 'lilla',
2292 short_name_def "sammetskudden",
2293 description "Det är bara en liten sammetskudde.",
2294 initial "En liten sammetskudde ligger på golvet.";
2295
2296 ! ------------------------------------------------------------------------------
2297
2298 Room In_Oriental_Room "Orientaliska rummet"
2299 with teleport_to
2300 'krypgång' 'krypgången' 'kryp' In_Large_Low_Room
2301 'dimmig' 'dimmiga' 'grotta' 'grottan' In_Misty_Cavern,
2302 description
2303 "Det här är det orientaliska rummet.
2304 Uråldriga orientaliska grottmålningar täcker väggarna.
2305 En lätt sluttande gång går uppåt norrut, en annan gång går sydost,
2306 och en krypgång leder västerut.",
2307 w_to In_Large_Low_Room,
2308 se_to In_Swiss_Cheese_Room,
2309 u_to In_Misty_Cavern,
2310 n_to In_Misty_Cavern;
2311
2312 Scenic -> "uråldriga orientaliska målningar"
2313 with name 'målning' 'målningen' 'målningar' 'målningarna'
2314 'teckning' 'teckningen' 'teckningar' 'teckningarna'
2315 'konst' 'konsten' 'grottmålning' 'grottmålningen'
2316 'grottmålningar' 'grottmålningarna' 'uråldrig' 'uråldriga'
2317 'antik' 'antika' 'orientalisk' 'orientaliska',
2318 short_name_def "uråldriga orientaliska målningarna",
2319 description "De verkar föreställa människor och djur.",
2320 has multitude pluralname def_article;
2321
2322 Treasure -> ming_vase "Mingvas"
2323 with name 'vas' 'vasen' 'mingvas' 'mingvasen' 'ömtålig' 'ömtåliga'
2324 'dyrbar' 'dyrbara' 'elegant' 'eleganta',
2325 short_name_def "Mingvasen",
2326 description "Det är en elegant, dyrbar Mingvas!",
2327 after [;
2328 Drop:
2329 if (velvet_pillow in location) {
2330 print "(landar elegant på sammetskudden)^";
2331 rfalse;
2332 }
2333 remove ming_vase;
2334 move shards to location;
2335 "Mingvasen landar med en elegant krasch.";
2336 ],
2337 before [;
2338 Attack:
2339 remove ming_vase;
2340 move shards to location;
2341 "Du har tagit vasen och
2342 elegant kastat den till marken.";
2343 Receive:
2344 "Vasen är alltför ömtålig för att användas som behållare.";
2345 ],
2346 depositpoints 14;
2347
2348 Object shards "värdelösa krukskärvor"
2349 with name 'värdelös' 'värdelösa' 'skärva' 'skärvan' 'skärvor' 'skärvorna'
2350 'krukskärva' 'krukskärvan' 'krukskärvor' 'krukskärvorna'
2351 'rester' 'resterna' 'av' 'en' 'vas' 'vasen',
2352 short_name_def "värdelösa krukskärvorna",
2353 description
2354 "Det ser ut att vara resterna av vad som en gång var en vacker vas.
2355 Antagligen var det någon klant som tappade den.",
2356 initial "Golvet är fullt av värdelösa krukskärvor.",
2357 has multitude pluralname def_article;
2358
2359 ! ------------------------------------------------------------------------------
2360
2361 Room In_Misty_Cavern "Dimmig grotta"
2362 with teleport_to
2363 'orientaliska' In_Oriental_Room,
2364 description
2365 "Du följer en bred stig runt den yttre kanten av en stor grotta.
2366 Långt nedanför dig, genom en tung vit dimma, hörs märkliga plaskande läten.
2367 Dimman stiger upp genom en spricka i taket.
2368 Stigen leder ut från grottan åt söder och väster.",
2369 s_to In_Oriental_Room,
2370 w_to In_Alcove;
2371
2372 Scenic -> "spricka"
2373 with name 'spricka' 'sprickan' 'i//' 'tak' 'taket',
2374 short_name_def "sprickan",
2375 description "Du kan inte komma nära nog för att se så mycket detaljer.";
2376
2377 ! ------------------------------------------------------------------------------
2378 ! Spovar och pyramider
2379 ! ------------------------------------------------------------------------------
2380
2381 Room In_Alcove "Alkov"
2382 with teleport_to
2383 'dimmig' 'dimmiga' 'grotta' 'grottan' In_Misty_Cavern,
2384 description
2385 "Du är i en alkov.
2386 A liten stig åt nordväst verkar bli bredare efter en kort bit.
2387 En extremt trång tunnel leder österut.
2388 Det ser ut att vara en mycket trång passage.
2389 Ett kusligt ljus syns i andra änden.",
2390 nw_to In_Misty_Cavern,
2391 e_to [ j;
2392 j = children(player);
2393 if (j == 0 || (j == 1 && egg_sized_emerald in player))
2394 return In_Plover_Room;
2395 "Något som du bär är för stort för att komma igenom tunneln med dig.
2396 Du bör nog lista dina tillhörigheter och släppa något.";
2397 ];
2398
2399 ! ------------------------------------------------------------------------------
2400
2401 Room In_Plover_Room "Spovrummet"
2402 with teleport_to
2403 'mörk' 'mörkt' 'mörka' 'mörker' 'mörkret' 'korridor' 'korridoren' In_Dark_Room,
2404 description
2405 "Du är i en liten kammare upplyst av ett kusligt grönt ljus.
2406 En extremt smal tunnel leder västerut.
2407 En mörk korridor leder nordöst.",
2408 ne_to In_Dark_Room,
2409 w_to [ j;
2410 j = children(player);
2411 if (j == 0 || (j == 1 && egg_sized_emerald in player))
2412 return In_Alcove;
2413 "Något som du bär är för stort för att komma igenom tunneln med dig.
2414 Du bör nog lista dina tillhörigheter och släppa något.";
2415 ],
2416 before [;
2417 Plover:
2418 if (egg_sized_emerald in player) {
2419 move egg_sized_emerald to In_Plover_Room;
2420 score = score - 5;
2421 }
2422 PlayerTo(At_Y2);
2423 rtrue;
2424 Go:
2425 if (noun == out_obj)
2426 <<Go w_obj>>;
2427 ],
2428 has light;
2429
2430 Treasure -> egg_sized_emerald "smaragd stor som ett spovägg"
2431 with name 'smaragd' 'smaragden' 'stor' 'stora' 'som' 'ett' 'spovägg'
2432 'spovägget' 'ägg' 'ägget' 'en' 'spovs',
2433 short_name_def "stora smaragden",
2434 description "Spovar lägger, för övrigt, väldigt stora ägg.",
2435 initial "Det ligger en smaragd här, stor som ett spovägg!",
2436 depositpoints 14,
2437 has def_article;
2438
2439 ! ------------------------------------------------------------------------------
2440
2441 Room In_Dark_Room "Det mörka rummet"
2442 with description
2443 "Du är i Mörkrummet. Enda utgången är en korridor som leder söderut.",
2444 s_to In_Plover_Room,
2445 out_to In_Plover_Room,
2446 has nodwarf;
2447
2448 Object -> "stentavla"
2449 with name 'tavla' 'tavlan' 'massiv' 'massiva' 'stentavla' 'stentavlan',
2450 short_name_def "stentavlan",
2451 initial
2452 "En massiv stentavla insatt i väggen bär texten:
2453 ~Grattis till att ha bringat ljus till Mörkrummet!~",
2454 has static;
2455
2456 Treasure -> "platinapyramid"
2457 with name 'platinapyramid' 'platinapyramiden' 'pyramid' 'pyramiden'
2458 'platina' 'platinan' 'pyramidisk' 'pyramidiska',
2459 short_name_def "platinapyramiden",
2460 description "Platinapyramidens sidor är 20 centimeter långa!",
2461 initial "Det ligger en platinapyramid här, med 20 centimeter långa sidor!",
2462 depositpoints 14;
2463
2464 ! ------------------------------------------------------------------------------
2465 ! Norr om den komplicerade korsningen: En lång upp/ner-korridor
2466 ! ------------------------------------------------------------------------------
2467
2468 Room In_Arched_Hall "Sal med valvtak"
2469 with teleport_to
2470 'skalrum' 'skalrummet' In_Shell_Room,
2471 description
2472 "Du är i en sal med valvtak.
2473 En korallgång har tidigare gått uppåt och österut härifrån, men den blockeras nu av skräp.
2474 Luften här luktar havsvatten.",
2475 d_to In_Shell_Room;
2476
2477 ! ------------------------------------------------------------------------------
2478
2479 Room In_Shell_Room "Skalrummet"
2480 with teleport_to
2481 'sal' 'salen' 'valvtak' 'valvtaket' 'valvsal' 'valvsalen' In_Arched_Hall,
2482 description
2483 "Du är i ett stort rum utmejslat ur bergrunden.
2484 På golvet och väggarna sitter massor av skalbitar fast i stenen.
2485 En grund gång fortsätter neråt, och en något brantare leder upp.
2486 En låg krypgång kommer in söderifrån.",
2487 u_to In_Arched_Hall,
2488 d_to In_Ragged_Corridor,
2489 s_to [;
2490 if (giant_bivalve in player) {
2491 if (giant_bivalve has open)
2492 "Du kan inte få in det här en och en halvmeters ostronet genom den där lilla gången.";
2493 else
2494 "Du kan inte få in den här en och en halvmeters musslan genom den där lilla gången.";
2495 }
2496 return At_Complex_Junction;
2497 ];
2498
2499 Object -> giant_bivalve "jättemussla"
2500 with name 'jättemussla' 'jättemusslan' 'mussla' 'musslan'
2501 'ostron' 'ostronet' 'jätteostron' 'jätteostronet'
2502 'gigantisk' 'gigantiskt' 'gigantiska'
2503 'tvåskalig' 'tvåskaligt' 'tvåskaliga' 'blötdjur' 'blötdjuret',
2504 short_name [;
2505 if (self.has_been_opened) {
2506 print "jätteostron";
2507 if(indef_mode==false)
2508 print "et";
2509 } else {
2510 print "jättemussla";
2511 if(indef_mode==false)
2512 print "n";
2513 }
2514 rtrue;
2515 ],
2516 describe [;
2517 if (self.has_been_opened)
2518 "Det finns ett gigantiskt ostron här, med skalet hårt stängt.";
2519 "Det finns en gigantisk mussla här, med skalet hårt stängt.";
2520 ],
2521 before [;
2522 Examine:
2523 if (location == At_Ne_End or At_Sw_End)
2524 "Intressant.
2525 Något verkar stå skrivet på ostronets undersida:
2526 ^^
2527 ~Det är något mystiskt med det här stället,
2528 som har gjort att en av de förbannelser jag alltid känt till nu har en ny effekt.~";
2529 "Ett gigantiskt tvåskaligt blötdjur av något slag.";
2530 Open:
2531 "Du är inte stark nog för att öppna musslan med dina bara händer.";
2532 Unlock:
2533 if (second ~= trident) {
2534 SetGender(second);
2535 print (The) second, " är inte stark";
2536 if(second has pluralname) print "a";
2537 else if(second has neuter) print "t";
2538 " nog för att öppna musslan.";
2539 }
2540 if (self.has_been_opened)
2541 "Ostronet öppnas med ett gnissel, och inuti syns inget annat än ostron.
2542 Det stängs genast igen.";
2543 self.has_been_opened = true;
2544 move pearl to In_A_Cul_De_Sac;
2545 SetGender(self, neuter);
2546 "En glimrande pärla faller ut ur musslan och rullar iväg.
2547 Jösses, det här måste faktiskt vara ett ostron.
2548 (Jag har aldrig varit något vidare på att identifiera tvåskaliga blötdjur.)
2549 Vad det än är, så har det nu åter stängts.";
2550 Attack:
2551 "Skalet är mycket starkt och är ogenomträngligt för attacker.";
2552 ],
2553 has_been_opened false,
2554 has uter;
2555
2556 Treasure pearl "glimrande pärla"
2557 with name 'pärla' 'pärlan' 'glimrande' 'skimrande' 'glimmande' 'otrolig' 'otroliga' 'otroligt' 'stor' 'stora',
2558 short_name_def "glimrande pärlan",
2559 description "Den är otroligt stor!",
2560 initial "Vid ena sidan ligger en glimrande pärla!",
2561 depositpoints 14,
2562 has def_article;
2563
2564 ! ------------------------------------------------------------------------------
2565
2566 Room In_Ragged_Corridor "Ojämn korridor"
2567 with teleport_to
2568 'skalrum' 'skalrummet' In_Shell_Room,
2569 description "Du är i en lång sluttande korridor med ojämna, vassa väggar.",
2570 u_to In_Shell_Room,
2571 d_to In_A_Cul_De_Sac;
2572
2573 Room In_A_Cul_De_Sac "I slutet av en gång"
2574 with teleport_to
2575 'skalrum' 'skalrummet' In_Shell_Room,
2576 description "Du är i slutet av en två och en halv meter bred gång.",
2577 u_to In_Ragged_Corridor,
2578 out_to In_Ragged_Corridor;
2579
2580 ! ------------------------------------------------------------------------------
2581 ! Witt's End / Slut på uppslag : Grottbyggnation pågår
2582 ! ------------------------------------------------------------------------------
2583
2584 Room In_Anteroom "I entrén"
2585 with description
2586 "Du är i en entré med ett märkligt, böljande golv.
2587 Golvet ser ut som början på ett gigantisk, uppslagen bok som fortsätter in i
2588 en stor gång österut.
2589 Små gångar går västerut och uppåt.
2590 Det syns tydliga spår av att någon nyligen har grävt här.",
2591 u_to At_Complex_Junction,
2592 w_to In_Bedquilt,
2593 e_to At_Witts_End;
2594
2595 Object -> "skylt"
2596 with name 'skylt' 'skylten' 'karlsson' 'karlssons' 'karlsson^s' 'byggab' 'bygg' 'ab'
2597 'grottbyggnation' 'varningsskylt' 'varningsskylten' 'om' 'med' 'av' 'från',
2598 short_name_def "skylten",
2599 initial
2600 "På en skylt som hänger fritt i luften står det:
2601 ~Grottbyggnation pågår bortom denna punkt.
2602 Fortsätt på egen risk. Målsmän ansvarar för sina barn. [Karlssons Bygg AB]~",
2603 before [;
2604 Take:
2605 "Den hänger långt ovanför ditt huvud.";
2606 ],
2607 has static;
2608
2609
2610 Object -> "ganska nya nummer av ~Speleolognytt~"
2611 with name 'ganska' 'nya' 'nytt' 'nummer' 'numret' 'numren' 'av' 'speleolognytt'
2612 'tidning' 'tidningen' 'tidningar' 'tidningarna'
2613 'magasin' 'magasinet' 'magasinen',
2614 short_name_def "ganska nya numren av ~Speleolognytt~",
2615 description "Jag är rädd att tidningarna är skrivna på dvärgiska.",
2616 initial "Det ligger några ganska nya nummer av tidningen ~Speleolognytt~ här.",
2617 after [;
2618 Take:
2619 if (location == At_Witts_End) score--;
2620 Drop:
2621 if (location == At_Witts_End) {
2622 score++;
2623 "Ja, nu är det visst helt slut på uppslag.";
2624 }
2625 ],
2626 has multitude pluralname def_article;
2627
2628 Scenic "uppslag"
2629 with name 'uppslag' 'uppslaget' 'bokuppslag' 'bokuppslaget'
2630 'uppslagen' 'uppslagna' 'bok' 'boken'
2631 'böljande' 'golv' 'golvet',
2632 short_name_def "uppslaget",
2633 description "Golvet påminner om en uppslagen bok till formen. Du ser dock ingen text.",
2634 found_in In_Anteroom At_Witts_end,
2635 has neuter;
2636
2637
2638 ! ------------------------------------------------------------------------------
2639
2640 Room At_Witts_End "Slut på uppslag"
2641 with description
2642 "Du är i ett stort rum där golvet är format som en uppslagen bok. Uppslaget
2643 började i rummet väster om detta, men det är ändå svårt att avgöra vilken
2644 gång som leder dit. Gångar leder åt *alla* håll.",
2645 w_to
2646 "Du har krupit runt i några små hål
2647 men stoppades av en passage där taket nyligen rasat in.
2648 Du är nu tillbaka i huvudgången.",
2649 before [;
2650 Go:
2651 if (noun ~= w_obj && random(100) <= 95)
2652 "Du har krupit runt i några små hål och kommit tillbaka
2653 till huvudgången.";
2654 PlayerTo(In_Anteroom);
2655 rtrue;
2656 ];
2657
2658 ! ------------------------------------------------------------------------------
2659 ! Norr om de hemliga ravinerna, på andra sidan hålet
2660 ! ------------------------------------------------------------------------------
2661
2662 Room In_Mirror_Canyon "I spegelravinen"
2663 with teleport_to
2664 'reservoar' 'reservoaren' At_Reservoir,
2665 description
2666 "Du är i en nord/syd-ravin, cirka sju meter bred.
2667 Golvet är täckt av en vit dimma som glider in norrifrån.
2668 Väggarna sträcker sig uppåt, minst 30 meter höga.
2669 Upphängd i något som sitter långt, långt upp, och som du inte kan se,
2670 svävar en enorm tvåsidig spegel, parallellt med och mitt emellan ravinens väggar.
2671 ^^
2672 Ett litet fönster sitter i vardera väggen, cirka femton meter från golvet.",
2673 s_to In_Secret_N_S_Canyon_0,
2674 n_to At_Reservoir;
2675
2676 Object -> "upphängd spegel"
2677 with name 'spegel' 'spegeln' 'massiv' 'massiva' 'enorm' 'enorma' 'hängande'
2678 'upphängd' 'upphängda' 'svävande' 'som' 'svävar' 'dvärgarnas'
2679 'tvåsidig' 'tvåsidiga',
2680 short_name_def "upphängda spegeln",
2681 description
2682 "Spegeln har säkert hängts här för dvärgarnas skull.
2683 Som du vet är de extremt fåfänga.",
2684 initial
2685 "Spegeln har säkert hängts här för dvärgarnas skull.
2686 Som du vet är de extremt fåfänga.",
2687 before [;
2688 Attack, Remove:
2689 "Du kan inte nå den härifrån.";
2690 ],
2691 has static def_article;
2692
2693 ! ------------------------------------------------------------------------------
2694
2695 Room At_Window_On_Pit_2 "Vid ett fönster mot ett hål"
2696 with description
2697 "Du är vid ett lågt fönster med utsikt över ett enormt hål som sträcker sig uppåt utom synhåll.
2698 Ett golv är vagt skönjbart mer än femton meter ner.
2699 Spår av vit dimma täcker hålets golv, och dimman blir tjockare till vänster.
2700 Märken i dammet runt fönstret kan tyda på att någon har varit här nyligen.
2701 Tvärs över hålet från dig och sju-åtta meter bort
2702 finns ett liknande fönster in till ett upplyst rum.
2703 Där ser du en mystisk figur som stirrar tillbaka på dig.",
2704 w_to At_Junction_Of_Three,
2705 cant_go "Den enda utgången är västerut, tillbaka till korsningen.",
2706 before [;
2707 Jump:
2708 deadflag = 1;
2709 "Du hoppar och bryter nacken!";
2710 WaveHands:
2711 "Den mystiska figuren vinkar tillbaka till dig!";
2712 ];
2713
2714 ! ------------------------------------------------------------------------------
2715
2716 Room At_Reservoir "Vid Reservoar"
2717 with description
2718 "Du är vid kanten av en stor underjordisk reservoar.
2719 Ett ogenomskinligt moln av vit dimma fyller rummet och stiger snabbt uppåt.
2720 Sjön fylls på av en fors som kommer ut ur ett hål i väggen några meter över ditt huvud
2721 och landar ljudligt i vattnet någonstans i dimman.
2722 Den enda utgången leder tillbaka söderut.",
2723 s_to In_Mirror_Canyon,
2724 out_to In_Mirror_Canyon,
2725 before [;
2726 Swim:
2727 "Vattnet är iskallt, och du skulle snart frysa ihjäl.";
2728 ];
2729
2730 ! ------------------------------------------------------------------------------
2731 ! Gapet och trollbron
2732 ! ------------------------------------------------------------------------------
2733
2734 Room In_Sloping_Corridor "Sluttande korridor"
2735 with description
2736 "Du är i en lång slingrande korridor som sluttar utom synhåll åt båda hållen.",
2737 d_to In_Large_Low_Room,
2738 u_to On_Sw_Side_Of_Chasm,
2739 cant_go "Korridoren sluttar brant upp och ner.";
2740
2741 Room On_Sw_Side_Of_Chasm "På sydvästsidan av ett gap"
2742 with description
2743 "Du är på ena sidan av ett brett, djupt gap.
2744 En tung vit dimma som stiger upp nerifrån gör att man inte kan se något alls av den andra sidan.
2745 En gång åt sydväst leder bort från gapet, in i en slingrande korridor.",
2746 ne_to CrossRicketyBridge,
2747 sw_to In_Sloping_Corridor,
2748 d_to In_Sloping_Corridor,
2749 cant_go "Gången slingrar iväg åt sydväst.",
2750 before [;
2751 Jump:
2752 if (RicketyBridge in self)
2753 "Med all respekt vill jag ändå föreslå att du går över bron istället för att hoppa.";
2754 deadflag = 1;
2755 "Du klarade det inte.";
2756 ];
2757
2758 [ CrossRicketyBridge;
2759 if (Troll.has_caught_treasure || Troll in nothing) {
2760 Troll.has_caught_treasure = false;
2761 if (Bear.is_following_you) {
2762 remove Bear;
2763 remove self;
2764 give Wreckage ~absent;
2765 remove RicketyBridge;
2766 give RicketyBridge absent;
2767 StopDaemon(Bear);
2768 deadflag = 1;
2769 "Just som du når den andra sidan knakar det till, och bron bågnar av belastningen när
2770 björnen, som fortfarande följde efter dig, går upp på bron.
2771 Du griper desperat efter något att hålla tag i,
2772 men när bron kollapsar tappar du fotfästet och faller ner i gapet.";
2773 }
2774 return RicketyBridge;
2775 }
2776 if (Troll in location) "Trollet vägrar släppa förbi dig.";
2777 move Troll to location;
2778 "Trollet kommer ut ur skuggorna under bron, kliver fram och blockerar din väg.";
2779 ];
2780
2781 Object -> RicketyBridge "ranglig bro"
2782 with name 'bro' 'bron' 'ranglig' 'rangliga' 'instabil' 'instabila'
2783 'ostadig' 'ostadiga' 'ostabil' 'ostabila' 'vinglig' 'vingliga'
2784 'rank' 'ranka' 'rep' 'repet' 'repen' 'repbro' 'repbron'
2785 'träbro' 'träbron',
2786 short_name_def "rangliga bron",
2787 description "Det ser ut som en vanlig, om än ostadig, bro.",
2788 describe [;
2789 print
2790 "En ranglig träbro går ut över gapet och försvinner in i dimman.
2791 ^^
2792 På bron sitter en skylt med texten ~Stopp! Betala trollet!~^";
2793 if (Troll notin location)
2794 "Trollet syns inte till någonstans.";
2795 rtrue;
2796 ],
2797 door_dir [;
2798 if (location == On_Sw_Side_Of_Chasm) return ne_to;
2799 return sw_to;
2800 ],
2801 door_to [;
2802 if (location == On_Sw_Side_Of_Chasm) return On_Ne_Side_Of_Chasm;
2803 return On_Sw_Side_Of_Chasm;
2804 ],
2805 found_in On_Sw_Side_Of_Chasm On_Ne_Side_Of_Chasm,
2806 has static door open def_article;
2807
2808 Object -> -> Troll "burdust troll"
2809 with name 'troll' 'trollet' 'burdus' 'burdust' 'burdusa',
2810 short_name_def "burdusa trollet",
2811 description
2812 "Troll är nära släkt med stenar och har lika hård hud som noshörningar.",
2813 initial
2814 "Ett burdust troll står vid bron
2815 och insisterar på att du kastar en skatt till honom innan du får passera.",
2816 life [;
2817 Attack:
2818 "Trollet skrattar till åt ditt patetiska försök att skada honom.";
2819 ThrowAt, Give:
2820 if (noun ofclass Treasure) {
2821 remove noun;
2822 move self to RicketyBridge;
2823 self.has_caught_treasure = true;
2824 score = score - 5;
2825 "Trollet fångar din skatt och springer iväg utom synhåll.";
2826 }
2827 if (noun == tasty_food)
2828 "Frosseri är inte en av trollets laster. Det är däremot girighet.";
2829 print "Trollet fångar smidigt ", (the) noun,
2830 ", undersöker ",(DenEllerHonom) noun," noggrannt, och kastar tillbaka ",(DenEllerHonom) noun,":
2831 ~Gott hantverk, men ",(DenEllerHan) noun," är inte värdefull";
2832 if(noun has pluralname)
2833 print "a";
2834 else if(noun has neuter)
2835 print "t";
2836 " nog.~";
2837 Order:
2838 "Fet chans.";
2839 Answer, Ask:
2840 "Troll är inget vidare på att konversera.";
2841 ],
2842 has_caught_treasure false,
2843 has animate neuter def_article;
2844
2845 Object Wreckage "brovrak"
2846 with name 'vrak' 'vraket' 'bro' 'bron' 'brovrak' 'brovraket' 'av' 'trollbron'
2847 'död' 'döda' 'björn' 'björnen',
2848 short_name_def "vraket av trollbron",
2849 initial
2850 "Om man tittar ner i gapet syns vraket av trollbron (och en död björn)
2851 nere på botten.",
2852 before [;
2853 "Vraket är för långt ner.";
2854 ],
2855 found_in On_Sw_Side_Of_Chasm On_Ne_Side_Of_Chasm,
2856 has static absent neuter;
2857
2858 ! ------------------------------------------------------------------------------
2859
2860 Room On_Ne_Side_Of_Chasm "På nordöstra sidan av ett gap"
2861 with teleport_to
2862 'förgrening' At_Fork_In_Path
2863 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View
2864 'kalt' 'kala' In_Front_Of_Barren_Room,
2865 description
2866 "Du är på bortre sidan av gapet.
2867 En gång mot nordost leder bort från gapet på den här sidan.",
2868 sw_to CrossRicketyBridge,
2869 ne_to In_Corridor,
2870 before [;
2871 Jump:
2872 if (RicketyBridge in self)
2873 "Med all respekt vill jag ändå föreslå att du går över bron istället för att hoppa.";
2874 deadflag = 1;
2875 "Du klarade det inte.";
2876 ],
2877 has nodwarf;
2878
2879 Room In_Corridor "I en korridor"
2880 with teleport_to
2881 'förgrening' At_Fork_In_Path
2882 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View,
2883 description
2884 "Du är i en lång öst/väst-korridor.
2885 Ett svagt dånande ljud hörs långt borta.",
2886 w_to On_Ne_Side_Of_Chasm,
2887 e_to At_Fork_In_Path,
2888 has nodwarf;
2889
2890 ! ------------------------------------------------------------------------------
2891 ! Vulkanen
2892 ! ------------------------------------------------------------------------------
2893
2894 Room At_Fork_In_Path "Vid förgrening i vägen"
2895 with teleport_to
2896 'vänster' At_Junction_With_Warm_Walls
2897 'höger' In_Limestone_Passage
2898 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View,
2899 description
2900 "Vägen förgrenas här. Den vänstra grenen leder nordost.
2901 Ett dämpat dån verkar tillta i styrka åt det hållet.
2902 Den högra grenen leder sydost nerför en lätt sluttning.
2903 Huvudkorridoren kommer in västerifrån.",
2904 w_to In_Corridor,
2905 ne_to At_Junction_With_Warm_Walls,
2906 se_to In_Limestone_Passage,
2907 d_to In_Limestone_Passage,
2908 has nodwarf;
2909
2910 ! ------------------------------------------------------------------------------
2911
2912 Room At_Junction_With_Warm_Walls "Vid en korsning med varma väggar"
2913 with teleport_to
2914 'förgrening' At_Fork_In_Path
2915 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View
2916 'kryp' 'krypgång' 'kammare' 'kammaren' 'stenbumlingkammare' In_Chamber_Of_Boulders,
2917 description
2918 "Väggarna är väldigt varma här.
2919 Norrifrån hörs ett intensivt muller,
2920 så högt att hela grottan tycks skaka.
2921 En annan gång leder söderut, och en låg krypgång går österut.",
2922 s_to At_Fork_In_Path,
2923 n_to At_Breath_Taking_View,
2924 e_to In_Chamber_Of_Boulders,
2925 has nodwarf;
2926
2927 ! ------------------------------------------------------------------------------
2928
2929 Room At_Breath_Taking_View "Vid andlöst vacker vy"
2930 with teleport_to
2931 'förgrening' At_Fork_In_Path
2932 'mörk' 'mörka' 'illavarslande' 'gång' 'gången' At_Junction_With_Warm_Walls,
2933 description
2934 "Du står på kanten till en andlöst vacker vy.
2935 Långt nedanför dig ligger en aktiv vulkan, ur vilken stora klumpar av flytande lava sprutar ut,
2936 för att sedan åter falla tillbaka ner i djupet.
2937 Den glödande stenen fyller varje vrå av klipprummet med en blodröd glans,
2938 som ger allt ett kusligt, makabert utseende.
2939 Luften är fylld av pulserande gnistor av aska och en tung doft av svavel.
2940 Väggarna är brännheta,
2941 och mullret från vulkanen dränker alla andra ljud.
2942 I det sargade taket långt ovanför dig
2943 sitter myriader av förvrängda formationer av ren vit alabaster,
2944 som sprider det skumma ljuset och bildar hotfulla vålnader på väggarna.
2945 Vid ena sidan är en djup svacka, fylld med ett bisarrt kaos av illa tilltygade klippblock
2946 som ser ut att ha skapats av djävulen själv.
2947 En intensiv flod av eld strömmar ut från vulkanens djup,
2948 bränner sin väg genom svackan, och störtar sedan ner i ett bottenlöst hål långt bort till vänster om dig.
2949 Till höger om dig sprutar en massiv gejser av överhettad ånga oavbrutet upp
2950 från en kal ö, i en svavelsjö som bubblar olycksbådande.
2951 Väggen längst till höger flammar av en egen sorts glöd,
2952 vilket ger ännu mer infernalisk prakt till den redan helvetiska vyn.
2953 En mörk, illavarslande gång leder söderut.",
2954 s_to At_Junction_With_Warm_Walls,
2955 out_to At_Junction_With_Warm_Walls,
2956 d_to "Larva dig inte!",
2957 before [;
2958 Jump:
2959 <<Go d_obj>>;
2960 ],
2961 has light;
2962
2963 Scenic -> "aktiv vulkan"
2964 with name 'vulkan' 'vulkanen' 'glödande' 'aktiv' 'aktiva' 'djup' 'djupet'
2965 'blodröd' 'blodröda' 'glans' 'glansen' 'från' 'röd' 'röda'
2966 'kuslig' 'kusligt' 'kusliga' 'makaber' 'makabert' 'makabra' 'utseende' 'utseendet',
2967 short_name_def "aktiva vulkanen",
2968 description
2969 "Stora klumpar av flytande lava sprutar ut ur vulkanen,
2970 för att sedan åter falla tillbaka ner i djupet.
2971 Den glödande stenen fyller varje vrå av klipprummet med en blodröd glans,
2972 som ger allt ett kusligt, makabert utseende.",
2973 has def_article;
2974
2975 Scenic -> "gnistor av aska"
2976 with name 'gnista' 'gnistan' 'gnistor' 'gnistorna' 'av' 'aska' 'askan'
2977 'luft' 'luften' 'pulserande',
2978 short_name_def "gnistorna av aska",
2979 articles 0 0 "massor av",
2980 description
2981 "Gnistorna är för långt bort för att du ska kunna ta dig en närmare titt på dem.",
2982 has multitude pluralname;
2983
2984 Scenic -> "sargat tak"
2985 with name 'sargat' 'sargade' 'tak' 'taket' 'myriad' 'myriader' 'myriaderna' 'av'
2986 'förvrängd' 'förvrängda' 'formation' 'formationer' 'ren' 'rena' 'vit' 'vita'
2987 'alabaster' 'skumt' 'skumma' 'ljus' 'ljuset' 'hotfull' 'hotfulla'
2988 'vålnad' 'vålnader' 'på' 'väggen' 'väggarna',
2989 short_name_def "sargade taket",
2990 description
2991 "I det sargade taket långt ovanför dig
2992 sitter myriader av förvrängda formationer av ren vit alabaster,
2993 som sprider det skumma ljuset och bildar hotfulla vålnader på väggarna.",
2994 has def_article neuter;
2995
2996 Scenic -> "djup svacka"
2997 with name 'djup' 'djupa' 'svacka' 'svackan' 'bisarr' 'bisarrt' 'bisarra'
2998 'kaos' 'kaoset' 'av' 'illa' 'tilltygat' 'tilltygade' 'klippblock'
2999 'klippblocket' 'klippblocken' 'sten' 'stenen' 'stenar' 'stenarna',
3000 short_name_def "djupa svackan",
3001 description
3002 "Svackan är fylld med ett bisarrt kaos av illa tilltygade klippblock
3003 som ser ut att ha skapats av djävulen själv.",
3004 has def_article;
3005
3006 Scenic -> "flod av eld"
3007 with name 'flod' 'floden' 'av' 'eld' 'elden' 'bottenlöst' 'bottenlösa' 'hål' 'hålet',
3008 short_name_def "floden av eld",
3009 description
3010 "Floden av eld strömmar ut från vulkanens djup,
3011 bränner sin väg genom svackan, och störtar sedan ner i ett bottenlöst hål långt bort till vänster om dig.",
3012 has def_article;
3013
3014 Scenic -> "massiv gejser"
3015 with name 'massiv' 'massiva' 'gejser' 'gejsern' 'av' 'överhettad' 'överhettade'
3016 'ånga' 'ångan' 'kal' 'kala' 'ö//' 'ön' 'svavelsjö' 'svavelsjön' 'sjö' 'sjön'
3017 'som' 'bubblar' 'bubblande',
3018 short_name_def "massiva gejsern",
3019 description
3020 "Gejsern av överhettad ånga sprutar oavbrutet upp
3021 från en kal ö, mitt i en svavelsjö som bubblar olycksbådande.",
3022 has def_article;
3023
3024 ! ------------------------------------------------------------------------------
3025
3026 Room In_Chamber_Of_Boulders "I stenbumlingkammaren"
3027 with teleport_to
3028 'kryp' 'krypgång' 'krypgången' At_Junction_With_Warm_Walls
3029 'förgrening' At_Fork_In_Path
3030 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View,
3031 description
3032 "Du är i en liten kammare fylld med stora stenbumlingar.
3033 Väggarna är väldigt varma, vilket gör att luften i rummet är nästintill förlamande het.
3034 Enda utgången är en krypgång västerut. Det hörs ett lågt muller därifrån.",
3035 w_to At_Junction_With_Warm_Walls,
3036 out_to At_Junction_With_Warm_Walls,
3037 has nodwarf;
3038
3039 Scenic -> "stenbumlingar"
3040 with name 'stenbumling' 'stenbumlingen' 'stenbumlingar' 'stenbumlingarna'
3041 'bumling' 'bumlingen' 'bumlingar' 'bumlingarna' 'sten' 'stenen'
3042 'stenar' 'stenarna' 'klippa' 'klippan' 'klippor' 'klipporna'
3043 'klippblock' 'klippblocket' 'klippblocken',
3044 short_name_def "stenbumlingarna",
3045 description "Det är bara vanliga stenbumlingar. De är varma.",
3046 before [;
3047 LookUnder, Push, Pull:
3048 "Du skulle behöva spränga bort dem.";
3049 ],
3050 has multitude pluralname;
3051
3052 Treasure -> "ovanliga kryddor"
3053 with name 'exotisk' 'exotiska' 'ovanlig' 'ovanliga'
3054 'krydda' 'kryddan' 'kryddor' 'kryddorna',
3055 short_name_def "ovanliga kryddorna",
3056 articles "De" "de" "en samling",
3057 before [;
3058 Smell, Examine:
3059 "De luktar underbart exotiskt!";
3060 ],
3061 depositpoints 14,
3062 has multitude pluralname;
3063
3064 ! ------------------------------------------------------------------------------
3065
3066 Room In_Limestone_Passage "I kalkstensgång"
3067 with teleport_to
3068 'kalt' 'kala' In_Front_Of_Barren_Room
3069 'förgrening' At_Fork_In_Path
3070 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View,
3071 description
3072 "Du går längs en lätt sluttande nord/syd-gång
3073 med märkliga kalkstensformationer längs väggarna.",
3074 n_to At_Fork_In_Path,
3075 u_to At_Fork_In_Path,
3076 s_to In_Front_Of_Barren_Room,
3077 d_to In_Front_Of_Barren_Room,
3078 has nodwarf;
3079
3080 Scenic -> "kalkstensformationer"
3081 with name 'formation' 'formationen' 'formationer' 'formationerna' 'form' 'formen' 'former' 'formerna'
3082 'kalksten' 'kalkstenen' 'kalkstenar' 'kalkstenarna'
3083 'kalkstensformation' 'kalkstensformationen' 'kalkstensformationer' 'kalkstensformationerna'
3084 'med' 'riktigt' 'udda',
3085 short_name_def "kalkstensformationerna",
3086 description
3087 "Ibland ser du kalkstenar med riktigt udda former som får dig att stanna upp.",
3088 has multitude pluralname;
3089
3090 ! ------------------------------------------------------------------------------
3091 ! Om du går ner till skogen idag...
3092 ! ------------------------------------------------------------------------------
3093
3094 Room In_Front_Of_Barren_Room "Vid ingången till ett kalt rum"
3095 with teleport_to
3096 'kalt' 'kala' In_Barren_Room
3097 'förgrening' At_Fork_In_Path
3098 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View,
3099 description
3100 "Du står vid ingången till ett stort, kalt rum.
3101 På en skylt ovanför ingången står det: ~Varning! Björn i rummet!~",
3102 w_to In_Limestone_Passage,
3103 u_to In_Limestone_Passage,
3104 e_to In_Barren_Room,
3105 in_to In_Barren_Room,
3106 has nodwarf;
3107
3108 Scenic -> "varningsskylt"
3109 with name 'skylt' 'skylten' 'varningsskylt' 'varningsskylten'
3110 'kalt' 'kala' 'rum' 'rummet' 'varning' 'varningen'
3111 'ovanför' 'ingång' 'ingången',
3112 short_name_def "varningsskylten",
3113 description "På skylten står det: ~Varning! Björn i rummet!~";
3114
3115 ! ------------------------------------------------------------------------------
3116
3117 Room In_Barren_Room "I ett kalt rum"
3118 with teleport_to
3119 'förgrening' At_Fork_In_Path
3120 'andlöst' 'vacker' 'vackra' 'vy' 'vyn' At_Breath_Taking_View,
3121 description
3122 "Du är i ett kalt rum.
3123 Rummets mitt är helt tomt förutom lite damm.
3124 Avtryck i dammet leder bort mot den bortre änden av rummet.
3125 Den enda utgången är den väg du kom in.",
3126 w_to In_Front_Of_Barren_Room,
3127 out_to In_Front_Of_Barren_Room,
3128 has nodwarf;
3129
3130 Scenic -> "damm"
3131 with name 'damm' 'dammet' 'avtryck' 'avtrycket' 'avtrycken',
3132 short_name_def "dammet",
3133 articles 0 0 "lite",
3134 description "Det ser bara ut som vanligt damm.",
3135 has neuter;
3136
3137 Object -> Bear "stor grottbjörn"
3138 with name 'björn' 'björnen' 'grottbjörn' 'grottbjörnen' 'stor' 'stora'
3139 'tam' 'tama' 'vildsint' 'vildsinta' 'lugn' 'lugna' 'vänlig' 'vänliga'
3140 'vänskaplig' 'vänskapliga',
3141 short_name_def "stora grottbjörnen",
3142 describe [;
3143 if (self.is_following_you)
3144 "En mycket stor, tam björn följer efter dig.";
3145 if (self.is_friendly == false)
3146 "En vildsint grottbjörn stirrar på dig från andra sidan rummet!";
3147 if (location == In_Barren_Room)
3148 "En lugn grottbjörn sitter snällt i ett hörn.";
3149 "En björn med nöjd uppsyn vandrar omkring i närheten.";
3150 ],
3151 life [;
3152 Attack:
3153 if (axe in player) <<ThrowAt axe self>>;
3154 if (self.is_friendly)
3155 "Björnen blir förvirrad; han vill bara vara din vän.";
3156 "Med vad? Dina bara händer? Mot hans *björnhänder*??";
3157 ThrowAt:
3158 if (noun ~= axe) <<Give noun self>>;
3159 if (self.is_friendly)
3160 "Björnen blir förvirrad; han vill bara vara din vän.";
3161 move axe to location;
3162 axe.is_near_bear = true;
3163 "Yxan missar och landar nära björnen, där du inte kan få tag på den.";
3164 Give:
3165 if (noun == tasty_food) {
3166 axe.is_near_bear = false;
3167 remove tasty_food;
3168 self.is_friendly = true;
3169 "Björnen kastar girigt i sig maten. När han är klar verkar han mycket lugnare
3170 och till och med ganska vänskaplig.";
3171 }
3172 if (self.is_friendly)
3173 "Björnen verkar inte särskilt intresserad av ditt erbjudande.";
3174 "Hoppsan -- ditt erbjudande gör bara björnen argare!";
3175 Order, Ask, Answer:
3176 "Det här är en björn med mycket liten hjärna.";
3177 ],
3178 before [;
3179 Examine:
3180 print "Björnen är otroligt stor, ";
3181 if (self.is_friendly) "men verkar vänligt inställd.";
3182 "och verkar väldigt vildsint!";
3183 Take, Catch:
3184 if (self.is_friendly == false) "Du måste skoja!";
3185 if (golden_chain has locked)
3186 "Björnen sitter fortfarande fastkedjad i väggen.";
3187 self.is_following_you = true;
3188 StartDaemon(self);
3189 "Okej, björnen följer nu efter dig.";
3190 Drop, Release:
3191 if (self.is_following_you == false) "Va?";
3192 self.is_following_you = false;
3193 StopDaemon(self);
3194 if (Troll in location) {
3195 remove Troll;
3196 "Björnen lufsar fram mot trollet, som ger till ett skrik och springer iväg.
3197 Björnen ger snart upp jakten och kommer tillbaka.";
3198 }
3199 "Björnen lunkar iväg från dig.";
3200 ],
3201 daemon [;
3202 if (location == thedark) rfalse;
3203 if (self in location) {
3204 if (location == At_Breath_Taking_View)
3205 "^Björnen ryter av glädje.";
3206 rfalse;
3207 }
3208 move self to location;
3209 "^Björnen lufsar efter dig.";
3210 ],
3211 is_following_you false,
3212 is_friendly false,
3213 has animate def_article;
3214
3215 Treasure -> golden_chain "guldkedja"
3216 with name 'kedja' 'kedjan' 'guldkedja' 'guldkedjan' 'länk' 'länken'
3217 'länkar' 'länkarna' 'solid' 'solitt' 'solida' 'guld' 'guldet'
3218 'gyllene' 'tjock' 'tjocka' 'rent' 'rena' 'renaste' 'av',
3219 short_name_def "guldkedjan",
3220 description "Kedjan har tjocka länkar av rent guld!",
3221 describe [;
3222 if (self has locked)
3223 "Björnen hålls fast av en kedja av rent guld.";
3224 "En kedja av rent guld ligger ihoprullad på marken!";
3225 ],
3226 with_key set_of_keys,
3227 before [;
3228 Take:
3229 if (self has locked) {
3230 if (Bear.is_friendly) "Den är fastlåst i den vänskapliga björnen.";
3231 "Den är fastlåst i den vildsinta björnen!";
3232 }
3233 Unlock:
3234 if (Bear.is_friendly == false)
3235 "Du kan omöjligt komma förbi björnen och komma åt att låsa upp kedjan,
3236 och det är nog lika bra det.";
3237 Lock:
3238 if (self hasnt locked) "Mekanismen går inte i lås igen.";
3239 ],
3240 after [;
3241 Unlock:
3242 "Du låser upp kedjan och släpper lös den tama björnen.";
3243 ],
3244 depositpoints 14,
3245 has lockable locked;
3246
3247 ! ------------------------------------------------------------------------------
3248 ! Den olika labyrinten
3249 ! ------------------------------------------------------------------------------
3250
3251 Class DiffmazeRoom
3252 with short_name "Labyrint";
3253
3254 DiffmazeRoom Different_Maze_1
3255 with description "Du är i en labyrint av slingrande trånga gångar, alla olika.",
3256 s_to Different_Maze_3,
3257 sw_to Different_Maze_4,
3258 ne_to Different_Maze_5,
3259 se_to Different_Maze_6,
3260 u_to Different_Maze_7,
3261 nw_to Different_Maze_8,
3262 e_to Different_Maze_9,
3263 w_to Different_Maze_10,
3264 n_to Different_Maze_11,
3265 d_to At_West_End_Of_Long_Hall;
3266
3267 DiffmazeRoom Different_Maze_2
3268 with description "Du är i en trång labyrint av slingrande gångar, alla olika.",
3269 sw_to Different_Maze_3,
3270 n_to Different_Maze_4,
3271 e_to Different_Maze_5,
3272 nw_to Different_Maze_6,
3273 se_to Different_Maze_7,
3274 ne_to Different_Maze_8,
3275 w_to Different_Maze_9,
3276 d_to Different_Maze_10,
3277 u_to Different_Maze_11,
3278 s_to Dead_End_14;
3279
3280 DiffmazeRoom Different_Maze_3
3281 with description "Du är i en labyrint av slingriga trånga gångar, alla olika.",
3282 w_to Different_Maze_1,
3283 se_to Different_Maze_4,
3284 nw_to Different_Maze_5,
3285 sw_to Different_Maze_6,
3286 ne_to Different_Maze_7,
3287 u_to Different_Maze_8,
3288 d_to Different_Maze_9,
3289 n_to Different_Maze_10,
3290 s_to Different_Maze_11,
3291 e_to Different_Maze_2;
3292
3293 DiffmazeRoom Different_Maze_4
3294 with description "Du är i en trång labyrint av slingrande gångar, alla olika.",
3295 nw_to Different_Maze_1,
3296 u_to Different_Maze_3,
3297 n_to Different_Maze_5,
3298 s_to Different_Maze_6,
3299 w_to Different_Maze_7,
3300 sw_to Different_Maze_8,
3301 ne_to Different_Maze_9,
3302 e_to Different_Maze_10,
3303 d_to Different_Maze_11,
3304 se_to Different_Maze_2;
3305
3306 DiffmazeRoom Different_Maze_5
3307 with description "Du är i en slingrig labyrint av trånga gångar, alla olika.",
3308 u_to Different_Maze_1,
3309 d_to Different_Maze_3,
3310 w_to Different_Maze_4,
3311 ne_to Different_Maze_6,
3312 sw_to Different_Maze_7,
3313 e_to Different_Maze_8,
3314 n_to Different_Maze_9,
3315 nw_to Different_Maze_10,
3316 se_to Different_Maze_11,
3317 s_to Different_Maze_2;
3318
3319 DiffmazeRoom Different_Maze_6
3320 with description "Du är i en slingrig trång labyrint av gångar, alla olika.",
3321 ne_to Different_Maze_1,
3322 n_to Different_Maze_3,
3323 nw_to Different_Maze_4,
3324 se_to Different_Maze_5,
3325 e_to Different_Maze_7,
3326 d_to Different_Maze_8,
3327 s_to Different_Maze_9,
3328 u_to Different_Maze_10,
3329 w_to Different_Maze_11,
3330 sw_to Different_Maze_2;
3331
3332 DiffmazeRoom Different_Maze_7
3333 with description "Du är i en slingrande trång labyrint av gångar, alla olika.",
3334 n_to Different_Maze_1,
3335 se_to Different_Maze_3,
3336 d_to Different_Maze_4,
3337 s_to Different_Maze_5,
3338 e_to Different_Maze_6,
3339 w_to Different_Maze_8,
3340 sw_to Different_Maze_9,
3341 ne_to Different_Maze_10,
3342 nw_to Different_Maze_11,
3343 u_to Different_Maze_2;
3344
3345 DiffmazeRoom Different_Maze_8
3346 with description "Du är i en slingrande labyrint av trånga gångar, alla olika.",
3347 e_to Different_Maze_1,
3348 w_to Different_Maze_3,
3349 u_to Different_Maze_4,
3350 sw_to Different_Maze_5,
3351 d_to Different_Maze_6,
3352 s_to Different_Maze_7,
3353 nw_to Different_Maze_9,
3354 se_to Different_Maze_10,
3355 ne_to Different_Maze_11,
3356 n_to Different_Maze_2;
3357
3358 DiffmazeRoom Different_Maze_9
3359 with description "Du är i en trång slingrande labyrint av gångar, alla olika.",
3360 se_to Different_Maze_1,
3361 ne_to Different_Maze_3,
3362 s_to Different_Maze_4,
3363 d_to Different_Maze_5,
3364 u_to Different_Maze_6,
3365 nw_to Different_Maze_7,
3366 n_to Different_Maze_8,
3367 sw_to Different_Maze_10,
3368 e_to Different_Maze_11,
3369 w_to Different_Maze_2;
3370
3371 DiffmazeRoom Different_Maze_10
3372 with description "Du är i en labyrint av trånga slingriga gångar, alla olika.",
3373 d_to Different_Maze_1,
3374 e_to Different_Maze_3,
3375 ne_to Different_Maze_4,
3376 u_to Different_Maze_5,
3377 w_to Different_Maze_6,
3378 n_to Different_Maze_7,
3379 s_to Different_Maze_8,
3380 se_to Different_Maze_9,
3381 sw_to Different_Maze_11,
3382 nw_to Different_Maze_2;
3383
3384 DiffmazeRoom Different_Maze_11
3385 with description "Du är i en labyrint av trånga slingrande gångar, alla olika.",
3386 sw_to Different_Maze_1,
3387 nw_to Different_Maze_3,
3388 e_to Different_Maze_4,
3389 w_to Different_Maze_5,
3390 n_to Different_Maze_6,
3391 d_to Different_Maze_7,
3392 se_to Different_Maze_8,
3393 u_to Different_Maze_9,
3394 s_to Different_Maze_10,
3395 ne_to Different_Maze_2;
3396
3397 ! ------------------------------------------------------------------------------
3398
3399 DeadendRoom Dead_End_14
3400 class Room
3401 with short_name "Återvändsgränd, nära varuautomat",
3402 description
3403 "Du har nått en återvändsgränd. Det står en stor varuautomat här.
3404 ^^
3405 Hmmm... Någon har skrivit ett meddelande i dammet, med sirlig handstil.",
3406 n_to Different_Maze_2,
3407 out_to Different_Maze_2,
3408 has nodwarf;
3409
3410 Scenic -> "meddelande i dammet"
3411 with name 'meddelande' 'meddelandet' 'i//' 'damm' 'dammet' 'skrift' 'skriften' 'sirlig'
3412 'sirliga' 'handstil' 'handstilen',
3413 short_name_def "meddelandet i dammet",
3414 description
3415 "Meddelandet lyder: ~Det här är inte den labyrint där piraten lämnar
3416 sin skattkista.~",
3417 has neuter;
3418
3419 Scenic -> VendingMachine "varuautomat"
3420 with name 'varuautomat' 'varuautomaten' 'automat' 'automaten'
3421 'maskin' 'maskinen' 'springa' 'springan'
3422 'myntspringa' 'myntspringan' 'stor' 'stora'
3423 'batteri' 'batteriet' 'batterier' 'batterierna',
3424 short_name_def "varuautomaten",
3425 description
3426 "Instruktionerna på varuautomaten lyder:
3427 ~Lägg i mynt för att få färska batterier.~",
3428 before [;
3429 Receive:
3430 if (noun == rare_coins) {
3431 move fresh_batteries to location;
3432 remove rare_coins;
3433 "Strax efter att du lagt i mynten i myntspringan,
3434 kommer ett gnisslande läte från varuautomaten, och en uppsättning färska batterier faller ner vid dina fötter.";
3435 }
3436 "Automaten verkar vara gjord för att ta emot mynt.";
3437 Attack:
3438 "Automaten är väldigt gedigen och överlever din attack utan att få så mycket som en skråma.";
3439 LookUnder:
3440 "Du hittar inget under automaten";
3441 Search:
3442 "Du kan inte komma in i automaten.";
3443 Take:
3444 "Varuautomaten är alldeles för tung för att du ska kunna flytta den.";
3445 ];
3446
3447 Object fresh_batteries "färska batterier" VendingMachine
3448 with name 'batteri' 'batteriet' 'batterier' 'batterierna'
3449 'färsk' 'färskt' 'färska' 'fräsch' 'fräscht' 'fräscha'
3450 'laddat' 'laddade' 'fulladdat' 'fulladdade' 'nytt' 'nya',
3451 short_name_def "färska batterierna",
3452 description
3453 "De ser ut som vanliga batterier. (En blodisande stämma säger ~Gott om kräm!~)",
3454 initial "Det ligger färska batterier här.",
3455 before [;
3456 Count:
3457 "Ett par.";
3458 ],
3459 have_been_used false,
3460 has def_article pluralname;
3461
3462 Object old_batteries "urladdade batterier"
3463 with name 'batteri' 'batteriet' 'batterier' 'batterierna'
3464 'urladdat' 'urladdade' 'tomt' 'tomma' 'slutkört' 'slutkörda'
3465 'dött' 'döda' 'stendött' 'stendöda',
3466 short_name_def "urladdade batterierna",
3467 description
3468 "De ser ut som vanliga batterier.",
3469 initial "Några urladdade batterier ligger slängda i närheten.",
3470 before [;
3471 Count:
3472 "Ett par.";
3473 ];
3474
3475 ! ------------------------------------------------------------------------------
3476 ! Dvärgar!
3477 ! ------------------------------------------------------------------------------
3478
3479 Object dwarf "hotfull liten dvärg"
3480 with name 'dvärg' 'dvärgen' 'hotfull' 'hotfulla' 'hotfulle'
3481 'otäck' 'otäcke' 'otäcka' 'liten' 'lille' 'lilla'
3482 'elak' 'elake' 'elaka',
3483 short_name_def "hotfulla lilla dvärgen",
3484 description
3485 "Det är nog ingen bra idé att komma alltför nära.
3486 Lillkillen är rätt aggressiv, om man säger så.",
3487 initial "En hotfull liten dvärg gömmer sig i skuggorna.",
3488 number 5,
3489 daemon [;
3490 if (location == thedark) return;
3491 if (self.number == 0) {
3492 StopDaemon(self);
3493 return;
3494 }
3495 if (parent(self) == nothing) {
3496 if (location has nodwarf || location has light) return;
3497 if (random(100) <= self.number) {
3498 if (Bear in location || Troll in location) return;
3499 new_line;
3500 if (Dragon in location) {
3501 self.number--;
3502 "En dvärg dyker upp, men draken ger av en eldkvast som fullständigt förbränner honom.";
3503 }
3504 move self to location;
3505 "En hotfull liten dvärg kommer ut ur skuggorna!";
3506 }
3507 return;
3508 }
3509 if (parent(self) ~= location) {
3510 if (location == thedark) return;
3511 if (location has nodwarf || location has light) return;
3512 if (random(100) <= 96 && parent(self) ~= In_Mirror_Canyon) {
3513 move self to location;
3514 print "^Dvärgen smyger efter dig...^";
3515 }
3516 else {
3517 remove self;
3518 return;
3519 }
3520 }
3521 if (random(100) <= 75) {
3522 new_line;
3523 if (self.has_thrown_axe == false) {
3524 move axe to location;
3525 self.has_thrown_axe = true;
3526 remove self;
3527 "Dvärgen kastar en otäck liten yxa mot dig, missar,
3528 svär, och springer iväg.";
3529 }
3530 if (location == In_Mirror_Canyon)
3531 "Dvärgen beundrar sig själv i spegeln.";
3532 print "Dvärgen kastar en otäck liten kniv mot dig, ";
3533 if (random(1000) <= 95) {
3534 deadflag = 1;
3535 "och träffar!";
3536 }
3537 "men missar!";
3538 }
3539 if (random(3) == 1) {
3540 remove self;
3541 "^Dvärgen tröttnar, och glider iväg.";
3542 }
3543 ],
3544 before [;
3545 Kick:
3546 "Du kickar dvärgen tvärs över rummet. Han svär, ställer sig upp och borstar av sig.
3547 Nu är han argare än nånsin!";
3548 ],
3549 life [;
3550 ThrowAt:
3551 if (noun == axe) {
3552 if (random(3) ~= 1) {
3553 remove self;
3554 move axe to location;
3555 self.number--;
3556 "Du dödade en liten dvärg! Kroppen försvinner i ett moln av oljig svart rök.";
3557 }
3558 move axe to location;
3559 "Miss! Den lilla dvärgen duckar undan yxan.";
3560 }
3561 <<Give noun second>>;
3562 Give:
3563 if (noun == tasty_food)
3564 "Tokstolle, dvärgar äter bara kol! Nu har du gjort honom *riktigt* arg!";
3565 "Dvärgen är inte det minsta intresserad av ditt erbjudande. (Anledningen är,
3566 kanske, att om han dödar dig får han ändå allt du har.)";
3567 Attack:
3568 "Inte med dina bara händer. Inte en chans.";
3569 ],
3570 has_thrown_axe false,
3571 has animate def_article male;
3572
3573 Object axe "dvärgyxa"
3574 with name 'yxa' 'yxan' 'liten' 'lilla' 'dvärgyxa' 'dvärgyxan'
3575 'dvärgayxa' 'dvärgayxan' 'dvärgisk' 'dvärgiska',
3576 short_name_def "dvärgyxan",
3577 description "Det är bara en liten yxa.",
3578 initial "Det ligger en liten yxa här.",
3579 before [;
3580 if (~~self.is_near_bear) rfalse;
3581 Examine:
3582 "Den ligger bredvid björnen.";
3583 Take:
3584 "Inte en chans. Den ligger bredvid den vildsinta björnen, på knappt en ramlängds avstånd från döden.";
3585 ],
3586 is_near_bear false;
3587
3588 ! ------------------------------------------------------------------------------
3589 ! Två möten med pirater
3590 ! ------------------------------------------------------------------------------
3591
3592 Object pirate
3593 with daemon [ obj booty_nearby;
3594 if (random(100) > 2 || location == thedark or In_Secret_Canyon ||
3595 location has light || location has nodwarf) return;
3596 if (dwarf in location)
3597 "^En skäggig pirat dyker upp, får syn på dvärgen och springer iväg.";
3598 objectloop (obj ofclass Treasure && obj in player or location)
3599 booty_nearby = true;
3600 if (booty_nearby == false) {
3601 if (self.has_been_spotted) return;
3602 self.has_been_spotted = true;
3603 if (self.has_stolen_something) StopDaemon(self);
3604 "^Du hör svaga prasslande ljud från mörkret bakom dig.
3605 När du vänder dig om får du syn på en skäggig pirat.
3606 Han bär en stor kista.
3607 ^^
3608 ~Krevader och kanoner!~ skriker han, ~Han har sett mig!
3609 Bäst jag drar till labyrinten och gömmer kista min!~
3610 ^^
3611 Med dessa ord försvinner han in i skumrasket.";
3612 }
3613 if (self.has_stolen_something) return;
3614 self.has_stolen_something = true;
3615 if (self.has_been_spotted) StopDaemon(self);
3616 objectloop (obj ofclass Treasure && obj in player or location) {
3617 if (obj in player) score = score - 5;
3618 move obj to Dead_End_13;
3619 }
3620 "^Ut från skuggorna bakom dig hoppar en skäggig pirat!
3621 ~He, he~, skrockar han, ~Jag tar bara allt det här bytet och gömmer undan det
3622 i kista min långt in i labyrinten!~
3623 Han sliter åt sig din skatt och försvinner in i skumrasket.";
3624 ],
3625 has_stolen_something false,
3626 has_been_spotted false;
3627
3628 ! ----------------------------------------------------------------------------
3629 ! Grottsystemet stänger nu...
3630 ! ----------------------------------------------------------------------------
3631
3632 Object cave_closer
3633 with daemon [;
3634 if (treasures_found < MAX_TREASURES) return;
3635 StopDaemon(self);
3636 caves_closed = true;
3637 score = score + 25;
3638 remove CrystalBridge;
3639 give Grate locked ~open;
3640 remove set_of_keys;
3641 StopDaemon(dwarf);
3642 StopDaemon(pirate);
3643 remove Troll;
3644 remove Bear;
3645 remove Dragon;
3646 StartTimer(endgame_timer, 25);
3647 "En blodisande stämma ekar fram mellan grottväggarna: ~Grottsystemet
3648 stänger snart. Alla äventyrare måste genast bege sig till utgången vid huvudkontoret.~";
3649 ];
3650
3651 Object endgame_timer
3652 with time_left 0,
3653 time_out [;
3654 score = score + 10;
3655 while (child(player)) remove child(player);
3656 move bottle to At_Ne_End;
3657 if (child(bottle)) remove child(bottle);
3658 move giant_bivalve to At_Ne_End;
3659 move brass_lantern to At_Ne_End;
3660 move black_rod to At_Ne_End;
3661 move little_bird to At_Sw_End;
3662 move velvet_pillow to At_Sw_End;
3663 print
3664 "^Den blodisande stämman förkunnar: ~Grottsystemet är nu stängt.~
3665 När ekona har dött ut, kommer en stark ljusblixt som förblindar dig
3666 (och en liten puff av orange rök). . .
3667 ^^
3668 När dina ögon hämtat sig så att du kan fokusera igen, ser du dig omkring...^";
3669 PlayerTo(At_Ne_End);
3670 ];
3671
3672 ! ------------------------------------------------------------------------------
3673 ! Slutspelet
3674 ! ------------------------------------------------------------------------------
3675
3676 Room At_Ne_End "Nordöstra änden av lagret"
3677 with description
3678 "Du är i nordöstra änden av ett makalöst stort rum, till och med större än det gigantiska rummet.
3679 Det verkar vara ett lager för programmet ~Äventyr~.
3680 Stora facklor högt uppe ovanför dig indränker rummet i ett rökigt gult ljus.
3681 Utspritt runt dig ser du en hög med flaskor (alla tomma),
3682 en odling av unga bönstjälkar som mumlar tyst, en ostronbank,
3683 ett knippe svarta stavar med rostiga stjärnor i ena änden, samt en samling mässingslampor.
3684 Vid ena sidan ligger en massa dvärgar på golvet och snarkar högljutt.
3685 På en skylt intill står att läsa: ~Stör inte dvärgarna!~",
3686 sw_to At_Sw_End,
3687 has light;
3688
3689 Object -> "enorm spegel"
3690 with name 'spegel' 'spegeln' 'enorm' 'enorma' 'gigantisk' 'gigantiska' 'stor' 'stora'
3691 'jättestor' 'jättestora' 'upphängd' 'upphängda' 'hängande',
3692 short_name_def "enorma spegeln",
3693 description "Det ser ut som en vanlig, om än enorm, spegel.",
3694 initial
3695 "En gigantisk spegel hänger på ena väggen, och sträcker sig till andra änden av rummet,
3696 där allsköns objekt skymtar långt bort.",
3697 before [;
3698 Attack:
3699 print
3700 "Du ger spegeln ett kraftigt slag,
3701 varvid den faller sönder i en myraid små bitar.^^";
3702 SleepingDwarves.wake_up();
3703 rtrue;
3704 ],
3705 found_in At_Ne_End At_Sw_End,
3706 has static def_article;
3707
3708 Scenic -> "samling äventyrsspelsmateriel"
3709 ! Tvingades dela upp name-arrayen i tre delar för att den blev för stor.
3710 ! Lade till en parse_name som tar hänsyn till alla tre arrayerna
3711 with name 'hög' 'högen' 'med' 'flaska' 'flaskan' 'flaskor' 'flaskorna'
3712 'bönstjälk' 'bönstjälken' 'bönstjälkar' 'bönstjälkarna'
3713 'ung' 'unga' 'mumlande' 'tyst' 'tysta'
3714 'ostronbank' 'ostronbanken' 'ostron' 'ostronet' 'ostronen'
3715 'svart' 'svarta' 'stav' 'staven' 'stavar' 'stavarna',
3716 name2 'med' 'en' 'den' 'rostig' 'rostiga' 'stjärna' 'stjärnan' 'stjärnor' 'stjärnorna'
3717 'i//' 'ena' 'änden' 'samling' 'samlingen' 'av'
3718 'mässingslampa' 'mässingslampan' 'mässingslampor' 'mässingslamporna'
3719 'grejer' 'grejerna' 'grejor' 'grejorna' 'skräp' 'skräpet' 'prylar' 'prylarna'
3720 'materiel' 'materielet' 'material' 'materialet',
3721 name3 'fackla' 'facklan' 'facklor' 'facklorna' 'objekt' 'objektet' 'objekten'
3722 'äventyrsspelsmateriel' 'äventyrsspelsmaterielen'
3723 'äventyrsspelsmaterial' 'äventyrsspelsmaterialet'
3724 'lager' 'lagret' 'makalöst' 'stort' 'stora' 'allsköns' 'knippe' 'knippet',
3725 parse_name [ wd num;
3726 wd = NextWord();
3727 while (WordInProperty(wd, self, name) || WordInProperty(wd, self, name2) || WordInProperty(wd, self, name3)) {
3728 num++;
3729 wd = NextWord();
3730 }
3731 return num;
3732 ],
3733 short_name_def "samlingen av äventyrsspelsmateriel",
3734 description
3735 "Du har redan sett allt härinne, fast i andra sammanhang.",
3736 before [;
3737 Take:
3738 "När du inser att om du skulle ta prylarna här skulle du förstöra spelet för framtida spelare,
3739 väljer du att lämna ~Äventyr~-materielen där den är.";
3740 ];
3741
3742 Scenic -> SleepingDwarves "sovande dvärgar"
3743 with name 'dvärg' 'dvärgen' 'dvärgar' 'dvärgarna' 'sovande' 'snarkande'
3744 'slumrande' 'vilande' 'otäck' 'otäcke' 'otäcka' 'arg' 'arge' 'arga',
3745 short_name_def "sovande dvärgarna",
3746 articles "De" "de" "hundratals arga",
3747 description "Jag skulle inte störa dvärgarna om jag var du.",
3748 before [;
3749 Take:
3750 "Vad då, allihop?";
3751 ],
3752 life [;
3753 WakeOther:
3754 print
3755 "Du ruskar om den närmaste dvärgen, som vaknar sur,
3756 tar en titt på dig, svär, och griper efter sin yxa.^^";
3757 self.wake_up();
3758 rtrue;
3759 Attack:
3760 self.wake_up();
3761 rtrue;
3762 ],
3763 wake_up [;
3764 deadflag = 1;
3765 "Det resulterande tumultet har väckt dvärgarna.
3766 Det finns nu dussintals hotfulla små dvärgar i rummet med dig!
3767 De flesta av dem kastar knivar mot dig. Allihop får tag på dig!";
3768 ],
3769 has animate multitude;
3770
3771 ! ------------------------------------------------------------------------------
3772
3773 Room At_Sw_End "Sydvästra änden av lagret"
3774 with description
3775 "Du är i sydvästra änden av lagret.
3776 Vid ena sidan finns en grop full med vildsinta gröna ormar.
3777 Vid andra sidan står en rad med små flätade korgar, med en liten snyftande fågel i varje.
3778 I ett hörn ligger ett knippe svarta stavar med rostiga märken i ena änden.
3779 Ett stort antal sammetskuddar ligger utspridda på golvet.
3780 En enorm spegel fortsätter mot nordost.
3781 Vid dina fötter är ett stort stålgaller, med en skylt bredvid där det står:
3782 ~SKATTKAMMARE. Nycklar på huvudkontoret.~",
3783 d_to RepositoryGrate,
3784 ne_to At_Ne_End,
3785 has light;
3786
3787 Object -> RepositoryGrate "stålgaller"
3788 with name 'vanligt' 'vanliga' 'stålgaller' 'stålgallret' 'galler' 'gallret',
3789 short_name_def "stålgallret",
3790 description "Det ser bara ut som ett vanligt stålgaller.",
3791 when_open "Gallret är öppet.",
3792 when_closed "Gallret är stängt.",
3793 door_dir d_to,
3794 door_to Outside_Grate,
3795 with_key nothing,
3796 has static door locked openable neuter;
3797
3798 Scenic -> "samling äventyrsspelsmateriel"
3799 ! Tvingades dela upp name-arrayen i tre delar för att den blev för stor.
3800 ! Lade till en parse_name som tar hänsyn till alla tre arrayerna
3801 with name 'grop' 'gropen' 'vildsint' 'vildsinta' 'grön' 'gröna'
3802 'orm' 'ormen' 'ormar' 'ormarna' 'flätad' 'flätade' 'korg' 'korgar'
3803 'med' 'en' 'liten' 'små' 'snyftande' 'fågel' 'fågeln' 'fåglar' 'fåglarna'
3804 'i//' 'varje',
3805 name2 'samling' 'samlingen' 'av'
3806 'kudde' 'kudden' 'kuddar' 'kuddarna'
3807 'sammetskudde' 'sammetskudden' 'sammetskuddar' 'sammetskuddarna',
3808 name3 'grejer' 'grejerna' 'grejor' 'grejorna'
3809 'skräp' 'skräpet' 'prylar' 'prylarna'
3810 'materiel' 'materielet' 'material' 'materialet'
3811 'äventyrsspelsmateriel' 'äventyrsspelsmaterielen'
3812 'äventyrsspelsmaterial' 'äventyrsspelsmaterialet'
3813 'lager' 'lagret' 'makalöst' 'stort' 'stora' 'allsköns',
3814 parse_name [ wd num;
3815 wd = NextWord();
3816 while (WordInProperty(wd, self, name) || WordInProperty(wd, self, name2) || WordInProperty(wd, self, name3)) {
3817 num++;
3818 wd = NextWord();
3819 }
3820 return num;
3821 ],
3822 short_name_def "samlingen av äventyrsspelsmateriel",
3823 description
3824 "Du har redan sett allt härinne, fast i andra sammanhang.",
3825 before [;
3826 Take:
3827 "När du inser att om du skulle ta prylarna här skulle du förstöra spelet för framtida spelare,
3828 väljer du att lämna ~Äventyr~-materielen där den är.";
3829 ];
3830
3831 Object -> black_mark_rod "svart stav med ett rostigt märke i ena änden"
3832 with name 'svart' 'svarta' 'stav' 'staven' 'med' 'det' 'ett'
3833 'rostig' 'rostigt' 'rostiga' 'märke' 'märket' 'i//'
3834 'meterlång' 'meterlånga' 'explosiv' 'explosiva'
3835 'dynamit' 'dynamiten' 'smällare' 'smällaren'
3836 'ena' 'änden',
3837 short_name_def "svarta staven med ett rostigt märke i ena änden",
3838 description "Det är en meterlång svart stav med ett rostigt märke i ena änden.",
3839 initial
3840 "En meterlång svart stav med ett rostigt märke i ena änden ligger i närheten.",
3841 before [;
3842 Wave:
3843 "Inget händer.";
3844 ],
3845 has def_article;
3846
3847 ! ------------------------------------------------------------------------------
3848 ! Några rutiner som anropas av biblioteket
3849 ! ------------------------------------------------------------------------------
3850
3851 [ Initialise;
3852 location = At_End_Of_Road;
3853 score = 36;
3854 StartDaemon(dwarf);
3855 StartDaemon(pirate);
3856 StartDaemon(cave_closer);
3857 "^^^^^Välkommen till Äventyr!^
3858 (Skriv HJÄLP, eller bara H, för instruktioner och information.)^^";
3859 ];
3860
3861 [ PrintRank;
3862 print ", vilket ger dig titeln ";
3863 if (score >= 348) "Stormästare!";
3864 if (score >= 330) "Mästare av första graden.";
3865 if (score >= 300) "Mästare av andra graden.";
3866 if (score >= 200) "Juniormästare.";
3867 if (score >= 130) "Erkänt duktig äventyrare.";
3868 if (score >= 100) "Erfaren äventyrare.";
3869 if (score >= 35) "Äventyrare.";
3870 if (score >= 10) "Nybörjare.";
3871 "Amatör.";
3872 ];
3873
3874 [ DarkToDark;
3875 if (dark_warning == false) {
3876 dark_warning = true;
3877 "Det är nu kolsvart. Om du fortsätter kommer du troligen falla ner i ett hål.";
3878 }
3879 if (random(4) == 1) {
3880 deadflag = 1;
3881 "Du föll ner i ett hål och bröt varenda ben i kroppen!";
3882 }
3883 rfalse;
3884 ];
3885
3886 [ UnknownVerb word;
3887 if (WordInProperty(word, location, teleport_to)) {
3888 verb_wordnum = 0;
3889 return 'gå till';
3890 }
3891 rfalse;
3892 ];
3893
3894 ! ------------------------------------------------------------------------------
3895 ! Återupplivning
3896 ! ------------------------------------------------------------------------------
3897
3898 [ AfterLife o;
3899 if (deadflag == 3) {
3900 deadflag = 1;
3901 rfalse;
3902 }
3903 print "^^";
3904 if (caves_closed)
3905 "Det verkar inte bättre än att du är död. Tja, eftersom det ändå är så nära stängningsdags,
3906 så tror jag vi tar och sätter punkt där.";
3907 switch (deaths) {
3908 0:
3909 print
3910 "Hoppsan, du har visst gått och dött.
3911 Jag kan kanske hjälpa dig, men jag har egentligen aldrig gjort det här förut.
3912 Vill du att jag ska försöka återuppliva dig?^^";
3913 1:
3914 print
3915 "Hör du klumpeduns, nu har du gjort det igen!
3916 Jag vet inte hur många gånger jag fixar att göra om det här.
3917 Vill du att jag ska försöka återuppliva dig igen?^^";
3918 2:
3919 print
3920 "Nu har du verkligen ställt till det! Jag har slut på orange rök!
3921 Förväntar du dig på allvar att jag ska försöka mig på en återupplivning utan orange rök?^^";
3922 }
3923 print "> ";
3924 if (YesOrNo() == false) {
3925 switch (deaths) {
3926 0: "Då så.";
3927 1: "Det är nog ett klokt val.";
3928 2: "Jag trodde väl inte det heller!";
3929 }
3930 }
3931 switch (deaths) {
3932 0:
3933 print
3934 "Okej. Men skyll inte på mig om något går fe......
3935 ^^^^
3936 --- PUFF!! ---
3937 ^^
3938 Du omsveps av ett moln av orange rök.
3939 Du hostar och kippar efter andan när du stapplar ut från röken och upptäcker att du är...^";
3940 1:
3941 print
3942 "Okej, var gjorde jag nu av min oranga rök?.... >PUFF!<
3943 ^^
3944 Allt försvinner i ett tjockt moln av orange rök.^";
3945 2:
3946 "Okej, om du nu är så smart, så fixa det själv då! Jag sticker!";
3947 }
3948 deaths++;
3949 score = score - 10;
3950 if (location ~= thedark) {
3951 while (child(player)) {
3952 o = child(player);
3953 move o to location;
3954 if (o ofclass Treasure) score = score - 5;
3955 }
3956 }
3957 else {
3958 while (child(player)) {
3959 o = child(player);
3960 move o to real_location;
3961 if (o ofclass Treasure) score = score - 5;
3962 }
3963 }
3964 move brass_lantern to At_End_Of_Road;
3965 give brass_lantern ~on ~light;
3966 remove dwarf;
3967 deadflag = 0;
3968 PlayerTo(Inside_Building);
3969 ];
3970
3971 ! ------------------------------------------------------------------------------
3972 ! Meny-baserad hjälp (Egentligen inte en del av spelet)
3973 ! ------------------------------------------------------------------------------
3974
3975 [ HelpMenu;
3976 if (menu_item == 0) {
3977 item_width = 5;
3978 item_name = "Om Äventyr";
3979 if (deadflag == 2) return 5;
3980 else return 4;
3981 }
3982 if (menu_item == 1) {
3983 item_width = 7;
3984 item_name = "Instruktioner";
3985 }
3986 if (menu_item == 2) {
3987 item_width = 4;
3988 item_name = "Historia";
3989 }
3990 if (menu_item == 3) {
3991 item_width = 6;
3992 item_name = "Autenticitet";
3993 }
3994 if (menu_item == 4) {
3995 item_width = 13;
3996 item_name = "Den svenska översättningen";
3997 }
3998 if (menu_item == 5) {
3999 item_width = 8;
4000 item_name = "Visste du att...";
4001 }
4002 ];
4003
4004 [ HelpInfo;
4005 if (menu_item == 1) {
4006 print
4007 "Jag känner till platser, handlingar och objekt.
4008 Du kan styra mig med kommandon som bildar kompletta meningar.
4009 För förflyttning, prova kommandon som ~gå in~ ~öster~, ~väster~, ~norr~, ~söder~,
4010 ~upp~, ~ner~, ~gå in i byggnaden~, ~klättra på stolpen~, etc.^^";
4011 print
4012 "Jag känner till en del speciella objekt, som en svart stav som ligger gömd i grottan.
4013 Dessa objekt kan manipuleras genom att använda vissa av de handlingsord jag känner till.
4014 Oftast behöver du ange ett verb följt av ett objekt
4015 (tillsammans med beskrivande adjektiv när så önskas),
4016 men ibland kan jag gissa vilket objekt som menas med ledning av verbet.
4017 Om du undrar vilka objekt du bär med dig, kan du skriva ~lista mina saker~,
4018 eller kortare, bara ~lista~.
4019 En del objekt har sidoeffekter; staven skrämmer t ex fågeln.^^";
4020 print
4021 "Många kommandon har förkortningar.
4022 T ex kan du skriva ~l~ istället för ~lista~, ~t~ för titta,
4023 ~n~ för ~norr~, ~nv~ för nordväst etc. Några speciella förkortningar
4024 är ~x objekt~ för ~undersök objekt~,~g~ för ~igen~ (dvs gör om samma sak som förra draget),
4025 och ~z~ för ~vänta~.^^";
4026 print
4027 "De flesta spelare som har svårt att förflytta sig i spelet behöver bara prova lite andra ord.
4028 De flesta som misslyckas med att manipulera ett objekt, försöker göra
4029 något som ligger utanför deras (eller min!) förmåga och bör försöka hitta ett helt nytt angreppssätt.^^";
4030 print
4031 "Notera att grottgångar svänger mycket, och att man går norrut när man går ut ur ett rum
4032 garanterar inte att man kommer in i nästa rum söderifrån.^^";
4033 print
4034 "Om du vill sluta spela, skriv ~sluta~.
4035 För att spara ditt äventyr så att du kan fortsätta senare, skriv ~spara~,
4036 och för att ladda in ett sparat spel, skriv ~hämta~.
4037 För att ta tillbaka ditt senaste drag, skriv ~ångra~.
4038 För att se hur bra det går för dig, skriv ~poäng~.
4039 För att få full poäng för en skatt måste du lägga den i säkerhet i byggnaden,
4040 men du får en del av poängen bara genom att hitta den.
4041 Du förlorar poäng om du dör, eller avslutar spelet, men det förstnämnda kostar mer.
4042 Du får också poäng för hur stor del (om någon) av grottsystemet som du lyckats utforska;
4043 framför allt finns det en stor bonus bara för att man lyckats ta sig in
4044 (för att skilja nybörjarna från resten),
4045 och det finns andra sätt att avgöra om du kommit igenom
4046 några av de grymmare sektionerna.^^";
4047 print
4048 "Om du tror att du hittat alla skatterna, fortsätt bara utforska ett tag.
4049 Om inget intressant händer, så har du inte hittat alla än.
4050 Om något intressant *händer*, så betyder det att du får en bonus
4051 och har en chans att ro hem mycket mer poäng i Mästarsektionen.^^";
4052 "Lycka till!";
4053 }
4054 if (menu_item == 2) {
4055 print
4056 "Den kanske första äventyraren var en mulattslav, Stephen Bishop, född ca 1820:
4057 'liten, smidig och väldigt vacker'; en 'snabb, modig, entusiastisk' guide
4058 till grottsystemet Mammoth Cave i Kentucky-karsten.
4059 Grottsystemets historia är en märklig miniatyr av amerikansk historia.
4060 Dess upptäckt finns förklarad i en legend som dateras till 1790-talet;
4061 det sägs att en jägare, John Houchin, följde en skadad björn till en stor grop
4062 nära floden Green River och snubblade på ingången.
4063 Ingången var full av fladdermöss och vid kriget 1812 samlades mycket guano där,
4064 vilket löstes i nitrat-tunnor för att bilda salpeter till kruttillverkningen.
4065 Efter kriget föll priserna; men grottsystemet blev en liten sidoattraktion när en dissekerad
4066 indianmumie hittades i närheten, sittandes upprätt i en kista av sten, omgiven av talismaner.
4067 1815 fördes Hjorthov, som hon kallades efter en av amuletterna,
4068 bort av en cirkus, och hon drog publik över hela Amerika
4069 (en turné som i mångt och mycket påminner om Don McLeans låt 'The Legend of Andrew McCrew').
4070 Hon hamnade tillslut på Smithsonianmuséet men på 1820-talet kallades grottsystemet
4071 för ett av världens underverk, mycket tack vare hennes postuma ansträngningar.^^";
4072 print
4073 "Vid artonhundratalets början var europeiska grottsystem stora turistattraktioner,
4074 men nästan ingen besökte Mammoth-systemet, hur mycket 'underverk' det än var.
4075 Inte var det särskilt stort heller, på den tiden (Namnet var ett minne av guanosamlarna,
4076 som skröt om sina ~mammutfynd~ av guano).
4077 1838 köpte Stephen Bishops ägare grottsystemet.
4078 Stephen, som han (i egenskap av slav) alltid kallades, var en mycket speciell man:
4079 han var självlärd i latin och grekiska, och blev känd som 'högste härskare' över sitt underjordiska rike.
4080 Han utforskade och namngav en stor del av grottsystemet på sin fritid, och dubblerade den kända kartan på ett år.
4081 Den särprägel som namnen i Mammoth-systemet bär -- till hälften hemgjorda amerikanska, till hälften klassiska --
4082 började med Stephen: Floden Styx, Snöbollsrummet, Lilla fladdermusavenyn, Jättekupolen.
4083 Stephen hittade märkliga blinda fiskar, ormar, tysta gräshoppor, kvarlevor av grottbjörnar
4084 (vilda, lekfulla djur, en och en halv meter långa och dryga metern höga, som dog ut
4085 vid slutet av den senaste istiden), hundratals år gamla indianska arbeten i gipskristaller, och mer och mer grottor.
4086 Hans karta från 1842, ritade helt från minnet, var fortfarande i bruk fyrtio år senare.^^";
4087 print
4088 "Som turistattraktion (och, eftersom Stephens ägare var en filantrop,
4089 under en kort period ett sanatorium för tuberkulos, pga en hopplös medicinsk teori)
4090 kom grottsystemet att omsätta mycket pengar: under decennier bytte närliggande grottor
4091 ägare och det var massor av tvister om vem som hade laglig rätt till de olika grottorna.
4092 Ett annat bolag öppnade Great Onyx Cave 1912, tvärs över dalen Houchins Valley,
4093 i berget Flint Ridge.
4094 På 1920-talet var Kentuckys grottkrig i full gång.
4095 Rivaliserande ägare slussade turister till sina egna grottor med hjälp av falska poliser, anställde lustigkurrar
4096 för att sabotera varandras guidade turer, brände ner biljettkiosker,
4097 publicerade baktalande och falska annonser.
4098 Utforskning av grottor blev så farligt och hemligt at USA:s regering till slut ingrep 1941,
4099 gjorde en stor del av området till nationalpark och förbjöd i princip all utforskning av grottor.
4100 Guldrushen av turister höll ändå på att avta.^^";
4101 print
4102 "Övertygade om att Mammoth-grottorna och Flint Ridge-grottorna alla hängde ihop i en enorm kedja,
4103 prövade utforskare olika hemliga ingångar under flera år, och fick till slut officiellt stöd.
4104 Under 1960-talet befanns alla gångar ut från Flint Ridge -- knepiga, vattenfyllda tunnlar
4105 -- sluta i frustrerande stenras.
4106 En 'trådsmal' fysiker, Patricia Crowther, gjorde genombrottet 1972
4107 när hon kom igenom passagen Tight Spot och hittade en gyttjig gång:
4108 det var en gömd väg in i Mammoth-grottorna.^^";
4109 print
4110 "I enlighet med hans ägares testamente, befriades Stephen Bishop 1856,
4111 då grottsystemet bl a innehöll inte mindre än 226 avenyer, 47 kupoler, 23 gropar och 8 vattenfall.
4112 Han dog ett år senare, innan han kunde köpa sin fru och sin son.
4113 På 1970-talet hittade man Crowthers gyttjiga passage på hans karta.^^";
4114 print
4115 "Mammoth är ett enormt grottsystem, och dess fulla utbredning är fortfarande ämne för spekulationer.
4116 (uppskattningar ligger mellan 500 och 800 km).
4117 Trots att det här spelet ofta har kallats ~Colossal Cave~,
4118 så är det i själva verket en simulering av området Bedquilt Cave (Lapptäcksgrottan).
4119 Här är Will Crowthers egen historia om hur spelet kom till:^^";
4120 print
4121 "~Jag hade hållit på med ett icke datorbaserat rollspel som hette Dungeons and Dragons
4122 vid den tidpunkten, och jag hade även aktivt utforskat grottor --
4123 mestadels Mammoth Cave i Kentucky.
4124 Plötsligt befann jag mig i en skiljsmässa, och det var slitsamt på flera sätt.
4125 Det jobbigaste var att jag saknade barnen.
4126 Jag hade också slutat utforska grottor, eftersom det inte kändes roligt längre,
4127 så jag bestämde mig för att, på skoj, skriva ett program som var ett återskapande
4128 i fantasin av min grottutforskning, och även skulle vara ett spel för barnen,
4129 och kanske vissa aspekter av Dungeons and Dragons-spelet som jag hade spelat.^^";
4130 print
4131 "~Min idé var att det skulle vara ett datorspel som inte skulle vara skrämmande
4132 för folk utan datorvana, och det var en av anledningarna till att jag gjorde
4133 så att spelaren styr spelet genom att skriva naturligt språk, istället för mer standardiserade kommandon.
4134 Mina barn tyckte det var väldigt roligt.~
4135 [Citerad i ~Genesis II: Creation and Recreation with Computers~, Dale Peterson (1983).]^^";
4136 print
4137 "Crowthers ursprungliga FORTRAN-program hade kanske fem skatter eller så, men ingen formell poängräkning.
4138 Utmaningen låg egentligen i att utforska, även om det fanns motstånd från t ex ormen.
4139 Precis som det verkliga Bedquilt-området, har Crowthers simulering en karta med ungefär fyra
4140 olika djupnivåer och är rik på geologiska detaljer.
4141 Ett bra exempel är den oranga pelaren som går ner till Oranga flodrummet
4142 (där fågeln bor): den verkliga pelaren är av orange travertin,
4143 ett vackert mineral som återfinns i våt kalksten.^^";
4144 print
4145 "Spelets språk är fullproppat med referenser till grottutforskning, till 'kupoler' och 'krypgångar'.
4146 Ett 'plattrum', t ex, är en mycket gammal grotta vars tak har börjat brytas sönder
4147 till skarpa skärvor som ligger utspridda över golvet i en märklig hög.
4148 Programmets användande av ordet 'rum' för alla möjliga sorters grottor och platser
4149 verkar lite slarvigt, men det är utbrett bland grottutforskare
4150 går så långt tillbaka som till Stephen Bishop: så äventyrsspelens användning av ordet 'rum'
4151 i betydelsen 'plats' kan till och med härstamma från honom.^^";
4152 print
4153 "Spelet tog det avgörande steget mot problemlösning när Don Woods, en Stanford-student,
4154 avlusade spelet och byggde ut det.
4155 Han tripplade antalet skatter och lade till de icke-geografiska zonerna:
4156 allt från trollbron och framåt, samt de flesta förmaken på Lapptäcksnivån.
4157 Det finns många imitationer och utvidgningar av det ursprungliga spelet Adventure (Äventyr),
4158 och de är allihop i princip baserade på Woods 350-poängsversion.
4159 (Många onödigt utbyggda, förstörda eller förbättrade -- det beror på hur man ser på saken --
4160 versioner av spelet cirkulerar på Internet, och det mest användbara sättet at identifiera dem
4161 är med hjälp av den maximala poängen man kan få.
4162 Det finns många versioner med ca 400 till 600 poäng, och en som går upp till 1000.
4163 Woods själv fortsätter släppa nya versioner av sitt spel;
4164 de flesta av de andra som utökat spelet saknar hans talang.)^^";
4165 print
4166 "Trots att spelet har gått ifrån ren simulation, så är det mycket som fortfarande är realistiskt.
4167 Även verkliga grottutforskare vänder tillbaka när deras karbidlampor börjar falna;
4168 det finns verkligen mystiska märkningar och initialer på grottväggarna, en del gjorda av guanosamlarna,
4169 en del av Bishop, en del av 1920-talets utforskare.
4170 Självklart finns det inte en aktiv vulkan i centrala Kentucky, lika lite som det finns drakar och dvärgar.
4171 Men till och med dessa påhitt är, på sätt och vis, hämtat från historien:
4172 liksom de flesta tidiga rollspel, har 'Äventyr' hämtat mycket inspiration från J.R.R. Tolkiens
4173 'Bilbo', och resan genom bergen och Moria i 'Sagan om ringen'
4174 (kanske den del av hela trilogin som är mest dramatisk och har bäst atmosfär).
4175 Tolkien själv, den mest framgångsrikare mytskaparen under hela nittonhundratalet,
4176 arbetade med isländska, finska och walesiska sagor som förebilder.^^";
4177 print
4178 "1977 hade 'Adventure' börjat spridas i allt vidare cirklar, bland annat av Digitals användargrupp DECUS:
4179 det tog över lunchraster och helger var det än hamnade... men det är en annan historia.
4180 (Tracy Kidders fascinerande bok 'En dators födelse', om en arbetsgrupp som utvecklar stordatorer,
4181 sedd ur en journalists perspektiv, fångar det hela bra.)^^";
4182 "Det här är en tredjehands- eller fjärdehandskopia: från Will Crowthers original
4183 till Donald Woods 350-poängsversion till Donald Ekmans PC-portning till
4184 David M. Baggets utmärkta TADS-version (1993), till denna version.
4185 Därtill är den sedan översatt till svenska.^^";
4186 }
4187 if (menu_item == 3) {
4188
4189 print "(Den här texten är skriven av Graham Nelson, så ~jag~ refererar till Graham)^^";
4190 print
4191 "Den här portningen ligger ganska nära originalet.
4192 Problemen, sakerna och platserna i Woods ursprungliga 350-poängsversion är exakt desamma som här.^^";
4193 print
4194 "Jag har lagt till några hjälpsamma meddelanden, såsom ~Detta är en återvändsgränd.~, här och där:
4195 och återinför några ~ursprunglig position~-meddelanden för objekt, såsom det (ganska lama)
4196 ^^ Det finns god mat här.^^
4197 från källkodsfiler som säkerligen är tidiga men från oklar källa.
4198 De verkar passa bra in i den övriga texten.^^";
4199 print
4200 "Poängsystemet är original, förutom att man inte längre tappar fyra poäng för att man slutar
4201 (eftersom man inte får se sin poäng när man avslutar ett Inform-spel så spelar det ingen roll)
4202 och, mer kontroversiellt, ger jag fem poäng för varje skatt man för tillfället bär på, såsom vissa tidiga 80-talsportningar gjorde.
4203 Titlarna man får baserat på sig poäng har fått sig en översyn.
4204 Den enda märkbara regeländringen är att man inte kan använda magiska ord
4205 förrän man har varit på de platser som de leder till.^^";
4206 print
4207 "Dvärgarna har enklare rörelsemönster, men å andra sidan har jag lagt till
4208 ett mindre antal meddelanden för att få dem att interagera bättre med resten av spelet.
4209 Sannolikheterna är som i originalspelet.^^";
4210 print
4211 "I originalet kunde man skriva namnet på ett rum för att komma till det:
4212 för att hålla koden liten har jag utelämnat denna finess, men tycker samtidigt det är synd att den saknas.
4213 [RF: Den här finessen är inlagd i Release 9 [FR: dvs den engelska version som den svenska versionen är direkt baserad på.].]^^";
4214 print
4215 "Själva texten har behållits intakt nästan överallt, men jag har rättat några
4216 stavfel och grammatikfel (samt ändrat några ytterst missvisande och kryptiska kommentarer).
4217 Instruktionerna har ändrats lite grann (av uppenbara skäl) men är i stort sett som originalets.^^";
4218 "En bra källa för detaljer är David Baggetts källkod, som cirkulerar på Internet.";
4219 }
4220 if (menu_item == 4) {
4221 print "Den svenska översättningen försöker vara så trogen originalet som möjligt, men i vissa lägen
4222 har jag varit tvungen att göra ändrigar för att det alls ska bli begripligt på svenska.^^";
4223
4224 print "I ett avseende har jag avsiktligt gått ifrån den engelska Inform-versionen, och det gäller
4225 ~teleportering~. I originalet kunde man ta sig till vissa närliggande platser genom att
4226 skriva ett nyckelord ur namnet på dem, eller ett ord som beskriver vilken väg man vill ta.
4227 Direkt i början kan man t ex skriva ~skogen~ så hamnar man i skogen, och i vissa rum
4228 kan man skriva ~framåt~ för att gå vidare till nästa rum. Den engelska Informversionen
4229 hade utökat detta till att man kunde teleportera sig till alla rum man besökt. Då jag
4230 tyckte att det förstörde vissa problem och inte var i linje med vad Crowther (och senare Woods)
4231 avsett med teleporteringen, så återställde jag i princip originalets kommandon och räckvidd
4232 för teleportering.^^";
4233
4234 print "Den svenska versionen av spelet använder förstås de svenska tecknen å, ä och ö, och förväntar sig
4235 även att spelare använder dessa tecken vid inmatning. Tyvärr finns det Zkods-tolkar
4236 som har problem att hantera dessa tecken, särskilt vid inmatning, och det finns
4237 förstås även spelare som sitter i andra länder, där det kan vara knepigt att få fram
4238 de svenska tecknen på tangentbordet.
4239 Därför finns ett specialkommando: ~transkription~. Skriver man
4240 ~transkription~ kan man därefter använda aa istället för å, ae istället för ä
4241 och oe istället för ö. Om man behöver skriva en sådan bokstavskombination
4242 som *inte* ska bytas ut mot ett svenskt tecken, skriver man bara ett utropstecken
4243 före, som t ex: ~slaa paa b!oet~ tolkas som ~slå på boet~. Skriver man ~transkription visa~
4244 får man ett meddelande varje gång transkriptionsfunktionen griper in. Slutligen kan man skriva
4245 ~transkription av~ för att stänga av funktionen.^^";
4246
4247 print "Det finns några andra kommandon som är standard för Informspel på svenska och som kan vara
4248 bra att känna till:^^";
4249 style fixed;
4250 print "kort/normalt/långt Bestämmer utskriftsläge, dvs när rumsbeskrivningar ska visas^";
4251 print " (aldrig, vid första besöket, alltid)^
4252 börja om Startar om spelet^
4253 sluta Avslutar spelet^
4254 pronomen Listar vad ~den~, ~det~ osv refererar till^
4255 full poäng Listar exakt vad man fått poäng för^
4256 meddelanden på/av Slår på och stänger av poängmeddelanden^
4257 inspelning på/av Slår på och stänger av kommanoinspelning^
4258 uppspelning Spelar upp tidigare inspelade kommandon^
4259 utskrift på/av Slår på och stänger av utskrift till fil^
4260 version Visar fullständig versionsinformation^^";
4261 style roman;
4262
4263
4264
4265 "Kommentarer om den svenska översättningen välkomnas! Gå till http://microheaven.com/swedish/ så
4266 står min aktuella mailadress längst ner på sidan. På sidan finns även, för nedladdning, källkoden
4267 till detta och andra textäventyr på svenska, samt alla verktyg som behövs att skriva egna textäventyr
4268 på svenska.^^ -- Fredrik Ramsberg";
4269 }
4270 print "Visste du att...^^";
4271 print
4272 "De fem dvärgarna har en 96-procentig chans att följa efter dig, förutom om du går
4273 ut i ljus eller ner i hål eller om de beundrar sig själva: och de otäcka små knivarna har en pricksäkerhet på 9.5%.^^";
4274 print "Drakar bränner upp dvärgar (kanske för att dvärgar bara äter kol).^^";
4275 print
4276 "Björnen (som tycker om vulkanen) är för tung för bron...
4277 och du kan gå tillbaka till platsen efter att du blivit återupplivad.^^";
4278 print
4279 "Du kan smita förbi ormen in i den hemliga Ö/V-ravinen, i alla fall 35% av gångerna.
4280 Och att gå runt i mörkret är inte fullt så farligt som det verkar:
4281 det är bara 25% risk att man ramlar ner i ett hål.^^";
4282 print "Vasen tycker inte om att doppas.^^";
4283 print "Mystiska figurer kan vinka till varandra.^^";
4284 print "Vattnar man på dörrens gångjärn så rostar de ihop igen.^^";
4285 print
4286 "När grottsystemet stänger, låses gallret och nycklarna kastas bort,
4287 djur springer sin väg och kristallbron försvinner...^^";
4288 print
4289 "...och en helt oanvändbar ledtråd står skriven på jätteostronets skal i slutspelet.
4290 (För att göra denna ledtråd en aning mer rättvis, har jag ändrat ett ord och placerat antydningar på andra ställen i spelet.)^^";
4291 "Den sista nedrans poängen kan man få genom att...men nej. Det vore att skvallra.";
4292 ];
4293
4294 [ HelpSub;
4295 if (deadflag ~= 2)
4296 DoMenu(
4297 "Det finns information om följande ämnen:^
4298 ^ Instruktioner för att spela
4299 ^ En historisk bakgrund
4300 ^ Hur autentisk är den här versionen?
4301 ^ Den svenska översättningen^", HelpMenu, HelpInfo);
4302 else
4303 DoMenu(
4304 "Det finns information om följande ämnen:^
4305 ^ Instruktioner för att spela
4306 ^ En historisk bakgrund
4307 ^ Hur autentisk är den här versionen?
4308 ^ Den svenska översättningen
4309 ^ Visste du att...^", HelpMenu, HelpInfo);
4310 ];
4311
4312 [ Amusing; HelpSub(); ];
4313
4314 Verb 'hjälp' 'h'
4315 * -> Help;
4316
4317 ! ------------------------------------------------------------------------------
4318 ! Grammatik: the usual grammar and some extensions
4319 ! ------------------------------------------------------------------------------
4320
4321 Include "SwedishG";
4322
4323 ! ------------------------------------------------------------------------------
4324
4325 [ OffSub;
4326 if (brass_lantern notin player) "Du har ingen lampa.";
4327 <<SwitchOff brass_lantern>>;
4328 ];
4329
4330 [ OnSub;
4331 if (brass_lantern notin player) "Du har ingen lampa.";
4332 <<SwitchOn brass_lantern>>;
4333 ];
4334
4335 Verb 'av'
4336 * -> Off;
4337
4338 Verb 'på'
4339 * -> On;
4340
4341 ! ------------------------------------------------------------------------------
4342
4343 [ CatchSub; "Du kan inte fånga ", (the) noun, "."; ];
4344
4345 [ ReleaseSub; "Du kan inte släppa lös ", (the) noun, "."; ];
4346
4347 Verb 'fånga'
4348 * creature -> Catch
4349 * 'in' creature -> Catch
4350 * creature 'med' held -> Catch
4351 * 'in' creature 'med' held -> Catch;
4352
4353 Extend 'håll'
4354 * 'fast' creature -> Catch
4355 * 'fast' creature 'med' held -> Catch;
4356
4357 Extend 'ta'
4358 * 'fast' creature -> Catch
4359 * 'fast' creature 'med' held -> Catch;
4360
4361 Extend 'släpp'
4362 * 'lös'/'loss'/'ut' creature -> Release
4363 * creature 'lös' -> Release;
4364
4365 Verb 'befria' 'frige'
4366 * creature -> Release;
4367
4368 ! ------------------------------------------------------------------------------
4369
4370 [ WaterSub;
4371 if (bottle in player) <<Empty bottle>>;
4372 "Vatten? Vilket vatten?";
4373 ];
4374
4375 [ OilSub;
4376 if (bottle in player) <<Empty bottle>>;
4377 "Olja? Vilken oilja?";
4378 ];
4379
4380 Verb 'vattna' 'skölj'
4381 * 'på' noun -> Water
4382 * noun -> Water;
4383
4384 Verb 'olja' 'smörj'
4385 * 'in'/'upp' noun -> Oil
4386 * noun -> Oil;
4387
4388 Verb 'häll' 'duscha'
4389 * 'vatten' 'på' noun -> Water
4390 * 'olja' 'på' noun -> Oil
4391 * noun -> Empty;
4392
4393 ! ------------------------------------------------------------------------------
4394
4395 [ BlastSub;
4396 if (location ~= At_Sw_End or At_Ne_End) "Frustrerande, eller hur?";
4397 if (location == At_Sw_End && parent(black_mark_rod) == At_Ne_End) {
4398 score = score + 35;
4399 deadflag = 2;
4400 "En kraftig explosion hörs, och ett fem-meters hål slås upp i bortre väggen,
4401 samtidigt som dvärgarna begravs i sten och grus.
4402 Du går igenom hålet och hamnar på huvudkontoret,
4403 där ett glatt gäng vänliga alver bär iväg den segrande äventyraren in i solnedgången.";
4404 }
4405 if (location == At_Ne_End && parent(black_mark_rod) == At_Sw_End) {
4406 score = score + 20;
4407 deadflag = 1;
4408 "En kraftig explosion hörs, och ett fem-meters hål slås upp i bortre väggen,
4409 samtidigt som ormarna begravs i sten och grus.
4410 En flod av smält lava väller in genom hålet och förstör allt i sin väg, inklusive dig!";
4411 }
4412 deadflag = 1;
4413 "En kraftig explosion hörs, och du stänks plötsligt ut på rummets alla väggar.";
4414 ];
4415
4416 [ BlastWithSub;
4417 if (second ~= black_mark_rod) "Att spränga kräver dynamit.";
4418 "Har du ätit de där konstiga kakorna igen?";
4419 ];
4420
4421 Verb 'spräng'
4422 * -> Blast
4423 * noun 'med' held -> BlastWith;
4424
4425 ! ------------------------------------------------------------------------------
4426
4427 [ XyzzySub; "Inget händer."; ];
4428
4429 [ PlughSub; "Inget händer."; ];
4430
4431 [ PloverSub; "Inget händer."; ];
4432
4433 [ FeeSub; FthingSub(0); ];
4434
4435 [ FieSub; FthingSub(1); ];
4436
4437 [ FoeSub; FthingSub(2); ];
4438
4439 [ FooSub; FthingSub(3); ];
4440
4441 [ FthingSub i;
4442 if (feefie_count ~= i) {
4443 feefie_count = 0;
4444 "Gör om, gör rätt, din tok!";
4445 }
4446 if (feefie_count++ == 3) {
4447 feefie_count = 0;
4448 if (golden_eggs in In_Giant_Room) "Inget händer.";
4449 if ((golden_eggs in player) || (golden_eggs in location))
4450 print "Boet med de gyllene äggen har försvunnit!^";
4451 else
4452 print "Klart!";
4453 if (golden_eggs in player) score = score - 5;
4454 if (golden_eggs in Inside_Building)
4455 score = score - golden_eggs.depositpoints;
4456 move golden_eggs to In_Giant_Room;
4457 if (location == In_Giant_Room)
4458 "^^Ett stort bo fullt med gyllene ägg dyker plötsligt upp från ingenstans!";
4459 }
4460 else
4461 "Okej.";
4462 ];
4463
4464 [ OldMagicSub; "Bra försök, men det där är ett gammalt utslitet magiskt ord."; ];
4465
4466 Verb 'xyzzy'
4467 * -> Xyzzy;
4468
4469 Verb 'plugh'
4470 * -> Plugh;
4471
4472 Verb 'spov'
4473 * -> Plover;
4474
4475 Verb 'fee'
4476 * -> Fee;
4477
4478 Verb 'fie'
4479 * -> Fie;
4480
4481 Verb 'foe'
4482 * -> Foe;
4483
4484 Verb 'foo'
4485 * -> Foo;
4486
4487 Verb 'sesam' 'shazam' 'hokus' 'abrakadabra' 'abra' 'foobar' 'frotz'
4488 * -> OldMagic;
4489
4490 Extend 'säg' first
4491 * 'spräng' -> Blast
4492 * 'xyzzy' -> Xyzzy
4493 * 'plugh' -> Plugh
4494 * 'spov' -> Plover
4495 * 'fee' -> Fee
4496 * 'fie' -> Fie
4497 * 'foe' -> Foe
4498 * 'foo' -> Foo
4499 * 'sesam'/'shazam'/'hokus'/'abrakadabra'/'abra'/'foobar'/'frotz'
4500 -> OldMagic;
4501
4502 ! ------------------------------------------------------------------------------
4503
4504 [ CountSub;
4505 if (noun has multitude or pluralname) "Det finns ett flertal.";
4506 SetGender(noun);
4507 print "Jag ser ";
4508 if(noun has neuter)
4509 print "ett";
4510 else
4511 print "en";
4512 " (1) ", (name) noun, ".";
4513 ];
4514
4515 [ KickSub; <<Attack noun>>; ]; ! For kicking dwarves
4516
4517 [ UseSub; "Du måste vara lite tydligare än så."; ];
4518
4519 Verb 'räkna'
4520 * noun -> Count;
4521
4522 Verb 'sparka' 'kicka' 'känga' 'tåa'
4523 * noun -> Kick
4524 * 'till'/'på' noun -> Kick;
4525
4526 Verb 'släck'
4527 * noun -> SwitchOff;
4528
4529 Extend 'kasta'
4530 * held 'till' creature -> ThrowAt;
4531
4532 !Extend 'kasta'
4533 ! * held 'till' creature -> ThrowAt;
4534
4535 Verb 'höj'
4536 * held -> Wave;
4537
4538 Verb 'svinga'
4539 * 'med' held -> Wave
4540 * held -> Wave;
4541
4542 Verb 'gestikulera' = 'vifta';
4543
4544 Verb 'använd'
4545 * -> Use
4546 * topic -> Use;
4547
4548 ! ------------------------------------------------------------------------------
4549 ! Teleportering (använder även bibliotekets anropspunkt UnknownVerb)
4550 ! ------------------------------------------------------------------------------
4551
4552 [ TeleportSub;
4553 if (noun == location) "Men du är redan där!";
4554 PlayerTo(noun);
4555 ];
4556
4557 [TeleportMatch w i loc dest scan_dest;
4558
4559 ! Algoritm:
4560 ! Om location har en property teleport_to, anta att den innehåller
4561 ! en array, och sök igenom den baklänges. När vi hittar ett rums-id
4562 ! kommer vi ihåg det. När vi hittar första ordet som spelaren skrivit,
4563 ! flytta honom till detta rum. Om vi aldrig hittar spelarens första ord,
4564 ! leta efter andra, tredje ordet osv. Hittar vi inget av spelarens ord
4565 ! i arrayen, signalera att det inte känns igen med GPR_FAIL.
4566
4567 loc=location;
4568 if(loc provides teleport_to) {
4569 while(w~=-1) {
4570 w=NextWordStopped();
4571 if(w==-1) {
4572 if(dest~=0)
4573 return dest;
4574 else
4575 return GPR_FAIL;
4576 }
4577 if(dest==0) {
4578 scan_dest=0;
4579 for(i=((loc.#teleport_to)/WORDSIZE)-1: i>=0: i--) {
4580 if((loc.&teleport_to-->i) ofclass Room)
4581 scan_dest=loc.&teleport_to-->i;
4582 else if((loc.&teleport_to-->i)==w)
4583 dest=scan_dest;
4584 }
4585 }
4586 }
4587 }
4588 return GPR_FAIL;
4589 ];
4590
4591 Verb 'gå till'
4592 * TeleportMatch -> Teleport;
4593
4594 Extend 'gå' first
4595 * 'till' TeleportMatch -> Teleport
4596 * 'över' noun -> Enter;
4597
4598 Extend 'hoppa'
4599 * 'till' TeleportMatch -> Teleport;
4600
4601
4602
4603 #Ifdef TEST_VERSION;
4604
4605 ! ------------------------------------------------------------------------------------
4606 ! I testversionen: inga dvärgar eller pirater, och magiska ord funkar från början.
4607 ! Installera även en alternativ slumptalsgenerator som kan fås att ge förutsägbara
4608 ! resultat, så att man kan använda en steg-för-steg-lösning (faller annars på att
4609 ! vissa utgångar leder till slumpade rum och på att det kan komma olika
4610 ! slumptalssekvenser i olika tolkar).
4611 ! ------------------------------------------------------------------------------------
4612
4613 [ XdetermSub;
4614 StopDaemon(dwarf);
4615 StopDaemon(pirate);
4616 give In_Debris_Room visited;
4617 give At_Y2 visited;
4618 give In_Plover_Room visited;
4619 ];
4620
4621 Verb 'xdeterm'
4622 * -> Xdeterm;
4623
4624 Include ">random.h"; !!!
4625 Message "Installerade random.h förutsägbar slumptalsgenerator";
4626
4627 #Endif;
4628
4629 ! ------------------------------------------------------------------------------